1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
|
%% The contents of this file are subject to the Mozilla Public License
%% Version 1.1 (the "License"); you may not use this file except in
%% compliance with the License. You may obtain a copy of the License at
%% http://www.mozilla.org/MPL/
%%
%% Software distributed under the License is distributed on an "AS IS"
%% basis, WITHOUT WARRANTY OF ANY KIND, either express or implied. See the
%% License for the specific language governing rights and limitations
%% under the License.
%%
%% The Original Code is RabbitMQ.
%%
%% The Initial Developers of the Original Code are LShift Ltd,
%% Cohesive Financial Technologies LLC, and Rabbit Technologies Ltd.
%%
%% Portions created before 22-Nov-2008 00:00:00 GMT by LShift Ltd,
%% Cohesive Financial Technologies LLC, or Rabbit Technologies Ltd
%% are Copyright (C) 2007-2008 LShift Ltd, Cohesive Financial
%% Technologies LLC, and Rabbit Technologies Ltd.
%%
%% Portions created by LShift Ltd are Copyright (C) 2007-2010 LShift
%% Ltd. Portions created by Cohesive Financial Technologies LLC are
%% Copyright (C) 2007-2010 Cohesive Financial Technologies
%% LLC. Portions created by Rabbit Technologies Ltd are Copyright
%% (C) 2007-2010 Rabbit Technologies Ltd.
%%
%% All Rights Reserved.
%%
%% Contributor(s): ______________________________________.
%%
-module(rabbit_heartbeat).
-export([start_heartbeat/2]).
%%----------------------------------------------------------------------------
-ifdef(use_specs).
-spec(start_heartbeat/2 :: (rabbit_net:socket(), non_neg_integer()) ->
rabbit_types:maybe({pid(), pid()})).
-endif.
%%----------------------------------------------------------------------------
start_heartbeat(_Sock, 0) ->
none;
start_heartbeat(Sock, TimeoutSec) ->
Parent = self(),
%% the 'div 2' is there so that we don't end up waiting for nearly
%% 2 * TimeoutSec before sending a heartbeat in the boundary case
%% where the last message was sent just after a heartbeat.
Sender =
spawn_link(fun () -> heartbeater({Sock, TimeoutSec * 1000 div 2,
send_oct, 0,
fun () ->
catch rabbit_net:send(Sock, rabbit_binary_generator:build_heartbeat_frame()),
continue
end}, Parent) end),
%% we check for incoming data every interval, and time out after
%% two checks with no change. As a result we will time out between
%% 2 and 3 intervals after the last data has been received.
Receiver =
spawn_link(fun () -> heartbeater({Sock, TimeoutSec * 1000,
recv_oct, 1,
fun () ->
Parent ! timeout,
stop
end}, Parent) end),
{Sender, Receiver}.
heartbeater(Params, Parent) ->
heartbeater(Params, erlang:monitor(process, Parent), {0, 0}).
heartbeater({Sock, TimeoutMillisec, StatName, Threshold, Handler} = Params,
MonitorRef, {StatVal, SameCount}) ->
receive
{'DOWN', MonitorRef, process, _Object, _Info} ->
ok;
Other ->
exit({unexpected_message, Other})
after TimeoutMillisec ->
case rabbit_net:getstat(Sock, [StatName]) of
{ok, [{StatName, NewStatVal}]} ->
Recurse = fun (V) -> heartbeater(Params, MonitorRef, V) end,
if NewStatVal =/= StatVal ->
Recurse({NewStatVal, 0});
SameCount < Threshold ->
Recurse({NewStatVal, SameCount + 1});
true ->
case Handler() of
stop -> ok;
continue -> Recurse({NewStatVal, 0})
end
end;
{error, einval} ->
%% the socket is dead, most likely because the
%% connection is being shut down -> terminate
ok;
{error, Reason} ->
exit({cannot_get_socket_stats, Reason})
end
end.
|
