1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
|
%% The contents of this file are subject to the Mozilla Public License
%% Version 1.1 (the "License"); you may not use this file except in
%% compliance with the License. You may obtain a copy of the License
%% at http://www.mozilla.org/MPL/
%%
%% Software distributed under the License is distributed on an "AS IS"
%% basis, WITHOUT WARRANTY OF ANY KIND, either express or implied. See
%% the License for the specific language governing rights and
%% limitations under the License.
%%
%% The Original Code is RabbitMQ.
%%
%% The Initial Developer of the Original Code is VMware, Inc.
%% Copyright (c) 2007-2013 VMware, Inc. All rights reserved.
%%
-module(rabbit_runtime_parameters).
-include("rabbit.hrl").
-export([parse_set/4, set/4, set_any/4, clear/3, clear_any/3, list/0, list/1,
list_strict/1, list/2, list_strict/2, list_formatted/1, lookup/3,
value/3, value/4, info_keys/0]).
%%----------------------------------------------------------------------------
-ifdef(use_specs).
-type(ok_or_error_string() :: 'ok' | {'error_string', string()}).
-spec(parse_set/4 :: (rabbit_types:vhost(), binary(), binary(), string())
-> ok_or_error_string()).
-spec(set/4 :: (rabbit_types:vhost(), binary(), binary(), term())
-> ok_or_error_string()).
-spec(set_any/4 :: (rabbit_types:vhost(), binary(), binary(), term())
-> ok_or_error_string()).
-spec(clear/3 :: (rabbit_types:vhost(), binary(), binary())
-> ok_or_error_string()).
-spec(clear_any/3 :: (rabbit_types:vhost(), binary(), binary())
-> ok_or_error_string()).
-spec(list/0 :: () -> [rabbit_types:infos()]).
-spec(list/1 :: (rabbit_types:vhost() | '_') -> [rabbit_types:infos()]).
-spec(list_strict/1 :: (binary() | '_')
-> [rabbit_types:infos()] | 'not_found').
-spec(list/2 :: (rabbit_types:vhost() | '_', binary() | '_')
-> [rabbit_types:infos()]).
-spec(list_strict/2 :: (rabbit_types:vhost() | '_', binary() | '_')
-> [rabbit_types:infos()] | 'not_found').
-spec(list_formatted/1 :: (rabbit_types:vhost()) -> [rabbit_types:infos()]).
-spec(lookup/3 :: (rabbit_types:vhost(), binary(), binary())
-> rabbit_types:infos() | 'not_found').
-spec(value/3 :: (rabbit_types:vhost(), binary(), binary()) -> term()).
-spec(value/4 :: (rabbit_types:vhost(), binary(), binary(), term()) -> term()).
-spec(info_keys/0 :: () -> rabbit_types:info_keys()).
-endif.
%%---------------------------------------------------------------------------
-import(rabbit_misc, [pget/2, pset/3]).
-define(TABLE, rabbit_runtime_parameters).
%%---------------------------------------------------------------------------
parse_set(_, <<"policy">>, _, _) ->
{error_string, "policies may not be set using this method"};
parse_set(VHost, Component, Name, String) ->
case rabbit_misc:json_decode(String) of
{ok, JSON} -> set(VHost, Component, Name,
rabbit_misc:json_to_term(JSON));
error -> {error_string, "JSON decoding error"}
end.
set(_, <<"policy">>, _, _) ->
{error_string, "policies may not be set using this method"};
set(VHost, Component, Name, Term) ->
set_any(VHost, Component, Name, Term).
format_error(L) ->
{error_string, rabbit_misc:format_many([{"Validation failed~n", []} | L])}.
set_any(VHost, Component, Name, Term) ->
case set_any0(VHost, Component, Name, Term) of
ok -> ok;
{errors, L} -> format_error(L)
end.
set_any0(VHost, Component, Name, Term) ->
case lookup_component(Component) of
{ok, Mod} ->
case flatten_errors(Mod:validate(VHost, Component, Name, Term)) of
ok ->
case mnesia_update(VHost, Component, Name, Term) of
{old, Term} -> ok;
_ -> Mod:notify(VHost, Component, Name, Term)
end,
ok;
E ->
E
end;
E ->
E
end.
mnesia_update(VHost, Component, Name, Term) ->
rabbit_misc:execute_mnesia_transaction(
fun () ->
Res = case mnesia:read(?TABLE, {VHost, Component, Name}, read) of
[] -> new;
[Params] -> {old, Params#runtime_parameters.value}
end,
ok = mnesia:write(?TABLE, c(VHost, Component, Name, Term), write),
Res
end).
clear(_, <<"policy">> , _) ->
{error_string, "policies may not be cleared using this method"};
clear(VHost, Component, Name) ->
clear_any(VHost, Component, Name).
clear_any(VHost, Component, Name) ->
case clear_any0(VHost, Component, Name) of
ok -> ok;
{errors, L} -> format_error(L)
end.
clear_any0(VHost, Component, Name) ->
case lookup_component(Component) of
{ok, Mod} -> case flatten_errors(
Mod:validate_clear(VHost, Component, Name)) of
ok -> mnesia_clear(VHost, Component, Name),
Mod:notify_clear(VHost, Component, Name),
ok;
E -> E
end;
E -> E
end.
mnesia_clear(VHost, Component, Name) ->
ok = rabbit_misc:execute_mnesia_transaction(
fun () ->
ok = mnesia:delete(?TABLE, {VHost, Component, Name}, write)
end).
list() ->
[p(P) || #runtime_parameters{ key = {_VHost, Comp, _Name}} = P <-
rabbit_misc:dirty_read_all(?TABLE), Comp /= <<"policy">>].
list(VHost) -> list(VHost, '_', []).
list_strict(Component) -> list('_', Component, not_found).
list(VHost, Component) -> list(VHost, Component, []).
list_strict(VHost, Component) -> list(VHost, Component, not_found).
list(VHost, Component, Default) ->
case component_good(Component) of
true -> Match = #runtime_parameters{key = {VHost, Component, '_'},
_ = '_'},
[p(P) || #runtime_parameters{ key = {_VHost, Comp, _Name}} = P <-
mnesia:dirty_match_object(?TABLE, Match),
Comp =/= <<"policy">> orelse
Component =:= <<"policy">>];
_ -> Default
end.
list_formatted(VHost) ->
[pset(value, format(pget(value, P)), P) || P <- list(VHost)].
lookup(VHost, Component, Name) ->
case lookup0(VHost, Component, Name, rabbit_misc:const(not_found)) of
not_found -> not_found;
Params -> p(Params)
end.
value(VHost, Component, Name) ->
case lookup0(VHost, Component, Name, rabbit_misc:const(not_found)) of
not_found -> not_found;
Params -> Params#runtime_parameters.value
end.
value(VHost, Component, Name, Default) ->
Params = lookup0(VHost, Component, Name,
fun () ->
lookup_missing(VHost, Component, Name, Default)
end),
Params#runtime_parameters.value.
lookup0(VHost, Component, Name, DefaultFun) ->
case mnesia:dirty_read(?TABLE, {VHost, Component, Name}) of
[] -> DefaultFun();
[R] -> R
end.
lookup_missing(VHost, Component, Name, Default) ->
rabbit_misc:execute_mnesia_transaction(
fun () ->
case mnesia:read(?TABLE, {VHost, Component, Name}, read) of
[] -> Record = c(VHost, Component, Name, Default),
mnesia:write(?TABLE, Record, write),
Record;
[R] -> R
end
end).
c(VHost, Component, Name, Default) ->
#runtime_parameters{key = {VHost, Component, Name},
value = Default}.
p(#runtime_parameters{key = {VHost, Component, Name}, value = Value}) ->
[{vhost, VHost},
{component, Component},
{name, Name},
{value, Value}].
info_keys() -> [component, name, value].
%%---------------------------------------------------------------------------
component_good('_') -> true;
component_good(Component) -> case lookup_component(Component) of
{ok, _} -> true;
_ -> false
end.
lookup_component(Component) ->
case rabbit_registry:lookup_module(
runtime_parameter, list_to_atom(binary_to_list(Component))) of
{error, not_found} -> {errors,
[{"component ~s not found", [Component]}]};
{ok, Module} -> {ok, Module}
end.
format(Term) ->
{ok, JSON} = rabbit_misc:json_encode(rabbit_misc:term_to_json(Term)),
list_to_binary(JSON).
flatten_errors(L) ->
case [{F, A} || I <- lists:flatten([L]), {error, F, A} <- [I]] of
[] -> ok;
E -> {errors, E}
end.
|
