1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
|
%% The contents of this file are subject to the Mozilla Public License
%% Version 1.1 (the "License"); you may not use this file except in
%% compliance with the License. You may obtain a copy of the License at
%% http://www.mozilla.org/MPL/
%%
%% Software distributed under the License is distributed on an "AS IS"
%% basis, WITHOUT WARRANTY OF ANY KIND, either express or implied. See the
%% License for the specific language governing rights and limitations
%% under the License.
%%
%% The Original Code is RabbitMQ.
%%
%% The Initial Developers of the Original Code are LShift Ltd,
%% Cohesive Financial Technologies LLC, and Rabbit Technologies Ltd.
%%
%% Portions created before 22-Nov-2008 00:00:00 GMT by LShift Ltd,
%% Cohesive Financial Technologies LLC, or Rabbit Technologies Ltd
%% are Copyright (C) 2007-2008 LShift Ltd, Cohesive Financial
%% Technologies LLC, and Rabbit Technologies Ltd.
%%
%% Portions created by LShift Ltd are Copyright (C) 2007-2010 LShift
%% Ltd. Portions created by Cohesive Financial Technologies LLC are
%% Copyright (C) 2007-2010 Cohesive Financial Technologies
%% LLC. Portions created by Rabbit Technologies Ltd are Copyright
%% (C) 2007-2010 Rabbit Technologies Ltd.
%%
%% All Rights Reserved.
%%
%% Contributor(s): ______________________________________.
%%
-module(rabbit_writer).
-include("rabbit.hrl").
-include("rabbit_framing.hrl").
-export([start/3, start_link/3, shutdown/1, mainloop/1]).
-export([send_command/2, send_command/3, send_command_and_signal_back/3,
send_command_and_signal_back/4, send_command_and_notify/5]).
-export([internal_send_command/3, internal_send_command/5]).
-import(gen_tcp).
-record(wstate, {sock, channel, frame_max}).
-define(HIBERNATE_AFTER, 5000).
%%----------------------------------------------------------------------------
-ifdef(use_specs).
-spec(start/3 ::
(rabbit_net:socket(), rabbit_channel:channel_number(),
non_neg_integer())
-> pid()).
-spec(start_link/3 ::
(rabbit_net:socket(), rabbit_channel:channel_number(),
non_neg_integer())
-> pid()).
-spec(send_command/2 ::
(pid(), rabbit_framing:amqp_method_record()) -> 'ok').
-spec(send_command/3 ::
(pid(), rabbit_framing:amqp_method_record(), rabbit_types:content())
-> 'ok').
-spec(send_command_and_signal_back/3 ::
(pid(), rabbit_framing:amqp_method(), pid()) -> 'ok').
-spec(send_command_and_signal_back/4 ::
(pid(), rabbit_framing:amqp_method(), rabbit_types:content(), pid())
-> 'ok').
-spec(send_command_and_notify/5 ::
(pid(), pid(), pid(), rabbit_framing:amqp_method_record(),
rabbit_types:content())
-> 'ok').
-spec(internal_send_command/3 ::
(rabbit_net:socket(), rabbit_channel:channel_number(),
rabbit_framing:amqp_method_record())
-> 'ok').
-spec(internal_send_command/5 ::
(rabbit_net:socket(), rabbit_channel:channel_number(),
rabbit_framing:amqp_method_record(), rabbit_types:content(),
non_neg_integer())
-> 'ok').
-endif.
%%----------------------------------------------------------------------------
start(Sock, Channel, FrameMax) ->
spawn(?MODULE, mainloop, [#wstate{sock = Sock,
channel = Channel,
frame_max = FrameMax}]).
start_link(Sock, Channel, FrameMax) ->
spawn_link(?MODULE, mainloop, [#wstate{sock = Sock,
channel = Channel,
frame_max = FrameMax}]).
mainloop(State) ->
receive
Message -> ?MODULE:mainloop(handle_message(Message, State))
after ?HIBERNATE_AFTER ->
erlang:hibernate(?MODULE, mainloop, [State])
end.
handle_message({send_command, MethodRecord},
State = #wstate{sock = Sock, channel = Channel}) ->
ok = internal_send_command_async(Sock, Channel, MethodRecord),
State;
handle_message({send_command, MethodRecord, Content},
State = #wstate{sock = Sock,
channel = Channel,
frame_max = FrameMax}) ->
ok = internal_send_command_async(Sock, Channel, MethodRecord,
Content, FrameMax),
State;
handle_message({send_command_and_signal_back, MethodRecord, Parent},
State = #wstate{sock = Sock, channel = Channel}) ->
ok = internal_send_command_async(Sock, Channel, MethodRecord),
Parent ! rabbit_writer_send_command_signal,
State;
handle_message({send_command_and_signal_back, MethodRecord, Content, Parent},
State = #wstate{sock = Sock,
channel = Channel,
frame_max = FrameMax}) ->
ok = internal_send_command_async(Sock, Channel, MethodRecord,
Content, FrameMax),
Parent ! rabbit_writer_send_command_signal,
State;
handle_message({send_command_and_notify, QPid, ChPid, MethodRecord, Content},
State = #wstate{sock = Sock,
channel = Channel,
frame_max = FrameMax}) ->
ok = internal_send_command_async(Sock, Channel, MethodRecord,
Content, FrameMax),
rabbit_amqqueue:notify_sent(QPid, ChPid),
State;
handle_message({inet_reply, _, ok}, State) ->
State;
handle_message({inet_reply, _, Status}, _State) ->
exit({writer, send_failed, Status});
handle_message(shutdown, _State) ->
exit(normal);
handle_message(Message, _State) ->
exit({writer, message_not_understood, Message}).
%---------------------------------------------------------------------------
send_command(W, MethodRecord) ->
W ! {send_command, MethodRecord},
ok.
send_command(W, MethodRecord, Content) ->
W ! {send_command, MethodRecord, Content},
ok.
send_command_and_signal_back(W, MethodRecord, Parent) ->
W ! {send_command_and_signal_back, MethodRecord, Parent},
ok.
send_command_and_signal_back(W, MethodRecord, Content, Parent) ->
W ! {send_command_and_signal_back, MethodRecord, Content, Parent},
ok.
send_command_and_notify(W, Q, ChPid, MethodRecord, Content) ->
W ! {send_command_and_notify, Q, ChPid, MethodRecord, Content},
ok.
shutdown(W) ->
W ! shutdown,
rabbit_misc:unlink_and_capture_exit(W),
ok.
%---------------------------------------------------------------------------
assemble_frames(Channel, MethodRecord) ->
?LOGMESSAGE(out, Channel, MethodRecord, none),
rabbit_binary_generator:build_simple_method_frame(Channel, MethodRecord).
assemble_frames(Channel, MethodRecord, Content, FrameMax) ->
?LOGMESSAGE(out, Channel, MethodRecord, Content),
MethodName = rabbit_misc:method_record_type(MethodRecord),
true = rabbit_framing:method_has_content(MethodName), % assertion
MethodFrame = rabbit_binary_generator:build_simple_method_frame(
Channel, MethodRecord),
ContentFrames = rabbit_binary_generator:build_simple_content_frames(
Channel, Content, FrameMax),
[MethodFrame | ContentFrames].
tcp_send(Sock, Data) ->
rabbit_misc:throw_on_error(inet_error,
fun () -> rabbit_net:send(Sock, Data) end).
internal_send_command(Sock, Channel, MethodRecord) ->
ok = tcp_send(Sock, assemble_frames(Channel, MethodRecord)).
internal_send_command(Sock, Channel, MethodRecord, Content, FrameMax) ->
ok = tcp_send(Sock, assemble_frames(Channel, MethodRecord,
Content, FrameMax)).
%% gen_tcp:send/2 does a selective receive of {inet_reply, Sock,
%% Status} to obtain the result. That is bad when it is called from
%% the writer since it requires scanning of the writers possibly quite
%% large message queue.
%%
%% So instead we lift the code from prim_inet:send/2, which is what
%% gen_tcp:send/2 calls, do the first half here and then just process
%% the result code in handle_message/2 as and when it arrives.
%%
%% This means we may end up happily sending data down a closed/broken
%% socket, but that's ok since a) data in the buffers will be lost in
%% any case (so qualitatively we are no worse off than if we used
%% gen_tcp:send/2), and b) we do detect the changed socket status
%% eventually, i.e. when we get round to handling the result code.
%%
%% Also note that the port has bounded buffers and port_command blocks
%% when these are full. So the fact that we process the result
%% asynchronously does not impact flow control.
internal_send_command_async(Sock, Channel, MethodRecord) ->
true = port_cmd(Sock, assemble_frames(Channel, MethodRecord)),
ok.
internal_send_command_async(Sock, Channel, MethodRecord, Content, FrameMax) ->
true = port_cmd(Sock, assemble_frames(Channel, MethodRecord,
Content, FrameMax)),
ok.
port_cmd(Sock, Data) ->
try rabbit_net:port_command(Sock, Data)
catch error:Error -> exit({writer, send_failed, Error})
end.
|
