Test: check that replication partial sync works if we break the link.

The test checks both successful syncs and unsuccessful ones by changing
the backlog size.

2 files changed, 80 insertions, 0 deletions

diff --git a/tests/integration/replication-psync.tcl b/tests/integration/replication-psync.tcl
new file mode 100644
index 000000000..b49ab2519
--- /dev/null
+++ b/tests/integration/replication-psync.tcl
@@ -0,0 +1,79 @@
+proc start_bg_complex_data {host port db ops} {
+    set tclsh [info nameofexecutable]
+    exec $tclsh tests/helpers/bg_complex_data.tcl $host $port $db $ops &
+}
+
+proc stop_bg_complex_data {handle} {
+    catch {exec /bin/kill -9 $handle}
+}
+
+proc test_psync {backlog cond} {
+    start_server {tags {"repl"}} {
+        start_server {} {
+
+            set master [srv -1 client]
+            set master_host [srv -1 host]
+            set master_port [srv -1 port]
+            set slave [srv 0 client]
+
+            $master config set repl-backlog-size $backlog
+
+            set load_handle0 [start_bg_complex_data $master_host $master_port 9 100000]
+            set load_handle1 [start_bg_complex_data $master_host $master_port 11 100000]
+            set load_handle2 [start_bg_complex_data $master_host $master_port 12 100000]
+
+            test {First server should have role slave after SLAVEOF} {
+                $slave slaveof $master_host $master_port
+                after 1000
+                s 0 role
+            } {slave}
+
+            test "Test replication partial resync with backlog $backlog" {
+                # Now while the clients are writing data, break the maste-slave
+                # link multiple times.
+                for {set j 0} {$j < 100} {incr j} {
+                    after 100 ;# 100 times 100 milliseconds = 10 seconds total test
+                    # catch {puts "MASTER [$master dbsize] keys, SLAVE [$slave dbsize] keys"}
+
+                    if {($j % 20) == 0} {
+                        catch {
+                            $slave client kill $master_host:$master_port
+                        }
+                    }
+                }
+                stop_bg_complex_data $load_handle0
+                stop_bg_complex_data $load_handle1
+                stop_bg_complex_data $load_handle2
+                set retry 10
+                while {$retry && ([$master debug digest] ne [$slave debug digest])}\
+                {
+                    after 1000
+                    incr retry -1
+                }
+                assert {[$master dbsize] > 0}
+
+                if {[$master debug digest] ne [$slave debug digest]} {
+                    set csv1 [csvdump r]
+                    set csv2 [csvdump {r -1}]
+                    set fd [open /tmp/repldump1.txt w]
+                    puts -nonewline $fd $csv1
+                    close $fd
+                    set fd [open /tmp/repldump2.txt w]
+                    puts -nonewline $fd $csv2
+                    close $fd
+                    puts "Master - Slave inconsistency"
+                    puts "Run diff -u against /tmp/repldump*.txt for more info"
+                }
+                assert_equal [r debug digest] [r -1 debug digest]
+                eval $cond
+            }
+        }
+    }
+}
+
+test_psync 1000000 {
+    assert {[s -1 sync_partial_ok] > 0}
+}
+test_psync 100 {
+    assert {[s -1 sync_partial_err] > 0}
+}
diff --git a/tests/test_helper.tcl b/tests/test_helper.tcl
index 6aeff6ac2..8d34a0783 100644
--- a/tests/test_helper.tcl
+++ b/tests/test_helper.tcl
@@ -32,6 +32,7 @@ set ::all_tests {
     integration/replication-2
     integration/replication-3
     integration/replication-4
+    integration/replication-psync
     integration/aof
     integration/rdb
     integration/convert-zipmap-hash-on-load