apply plugin: 'java-library'

group 'com.smartdevicelink'
version '4.7.2'

sourceCompatibility = 1.7

buildscript {
    repositories {
        jcenter()
    }
    dependencies {
        classpath 'com.jfrog.bintray.gradle:gradle-bintray-plugin:1.8.4'
    }
}

repositories {
    google()
    jcenter()
}

// This extraLibs solution is explained here: https://discuss.gradle.org/t/how-to-include-dependencies-in-jar/19571/5
configurations {
    // configuration that holds jars to include in the jar
    extraLibs
}

dependencies {
    extraLibs fileTree(dir: 'libs', include: ['*.jar'])
    extraLibs fileTree(dir: '../javaSE/libs', include: ['*.jar'])  //BSON lib
    extraLibs 'com.android.support:support-annotations:28.0.0'
    extraLibs 'org.java-websocket:Java-WebSocket:1.3.9'
    configurations.api.extendsFrom(configurations.extraLibs)
}

sourceSets {
    main.java.srcDirs += '../base/src/main/java'
    main.java.srcDirs += '../javaSE/src/main/java'
}

jar {
    from {
        configurations.extraLibs.collect { it.isDirectory() ? it : zipTree(it) }
    }
}

apply from: 'bintray.gradle'

// Exclude :javaSE:bintrayUpload from running when we run bintrayUpload in javaEE
def taskRequests = gradle.startParameter.taskRequests
def runTaskRequest = taskRequests.find { it.args.contains('bintrayUpload') }
if (runTaskRequest) {
    gradle.startParameter.excludedTaskNames = [':javaSE:bintrayUpload']
}