Add a configure variable for the location of the dbus-daemonAT_SPI2_CORE_0_1_4

in the at-spi-dbus-bus script.

3 files changed, 61 insertions, 1 deletions

diff --git a/bus/at-spi-dbus-bus.in b/bus/at-spi-dbus-bus.in
index d3d434ca..2c4f1807 100644
--- a/bus/at-spi-dbus-bus.in
+++ b/bus/at-spi-dbus-bus.in
@@ -2,6 +2,7 @@
 
 prefix=@prefix@
 sysconfdir=@sysconfdir@
+daemondir=@DBUS_DAEMONDIR@
 
-address=`dbus-daemon --config-file=${sysconfdir}/at-spi2/accessibility.conf --print-address`
+address=`${daemondir}/dbus-daemon --config-file=${sysconfdir}/at-spi2/accessibility.conf --print-address`
 xprop -root -f AT_SPI_BUS 8s -set AT_SPI_BUS ${address}
diff --git a/configure.ac b/configure.ac
index 681abf29..ca1075a3 100644
--- a/configure.ac
+++ b/configure.ac
@@ -110,6 +110,16 @@ if test -z "$DEFAULT_ATSPI_INTROSPECTION_PATH"; then
 	  DEFAULT_ATSPI_INTROSPECTION_PATH=at-spi2/dbus
 fi
 
+AS_AC_EXPAND(EXPANDED_BINDIR, "$bindir")
+AC_ARG_WITH(dbus_daemondir, AS_HELP_STRING([--with-dbus-daemondir=[dirname]],[Directory where the DBUS daemon is installed]))
+if test -z "$with_dbus_daemondir" ; then
+    DBUS_DAEMONDIR=$EXPANDED_BINDIR
+else
+    DBUS_DAEMONDIR=$with_dbus_daemondir
+fi
+AC_SUBST(DBUS_DAEMONDIR)
+AC_DEFINE_UNQUOTED(DBUS_DAEMONDIR,"$DBUS_DAEMONDIR", [Directory for installing the DBUS daemon])
+
 AC_ARG_WITH(dbus-services,
            [AC_HELP_STRING([--with-dbus-services=<dir>],
            [where D-BUS services directory is])])
diff --git a/m4/as-ac-expend.m4 b/m4/as-ac-expend.m4
new file mode 100644
index 00000000..deebd2bf
--- /dev/null
+++ b/m4/as-ac-expend.m4
@@ -0,0 +1,49 @@
+dnl as-ac-expand.m4 0.2.0                                   -*- autoconf -*-
+dnl autostars m4 macro for expanding directories using configure's prefix
+
+dnl (C) 2003, 2004, 2005 Thomas Vander Stichele <thomas at apestaart dot org>
+
+dnl Copying and distribution of this file, with or without modification,
+dnl are permitted in any medium without royalty provided the copyright
+dnl notice and this notice are preserved.
+
+dnl AS_AC_EXPAND(VAR, CONFIGURE_VAR)
+
+dnl example:
+dnl AS_AC_EXPAND(SYSCONFDIR, $sysconfdir)
+dnl will set SYSCONFDIR to /usr/local/etc if prefix=/usr/local
+
+AC_DEFUN([AS_AC_EXPAND],
+[
+  EXP_VAR=[$1]
+  FROM_VAR=[$2]
+
+  dnl first expand prefix and exec_prefix if necessary
+  prefix_save=$prefix
+  exec_prefix_save=$exec_prefix
+
+  dnl if no prefix given, then use /usr/local, the default prefix
+  if test "x$prefix" = "xNONE"; then
+    prefix="$ac_default_prefix"
+  fi
+  dnl if no exec_prefix given, then use prefix
+  if test "x$exec_prefix" = "xNONE"; then
+    exec_prefix=$prefix
+  fi
+
+  full_var="$FROM_VAR"
+  dnl loop until it doesn't change anymore
+  while true; do
+    new_full_var="`eval echo $full_var`"
+    if test "x$new_full_var" = "x$full_var"; then break; fi
+    full_var=$new_full_var
+  done
+
+  dnl clean up
+  full_var=$new_full_var
+  AC_SUBST([$1], "$full_var")
+
+  dnl restore prefix and exec_prefix
+  prefix=$prefix_save
+  exec_prefix=$exec_prefix_save
+])