Replace AC_TRY_COMPILE and AC_LANG_

Autoconf 2.50 in 2001 made several macros obsolete. These include macros
for temporary changing the language - AC_LANG_SAVE, AC_LANG_CPLUSPLUS,
AC_LANG_C, and AC_LANG_RESTORE. Instead of these the AC_LANG_PUSH and
AC_LANG_POP macros should be used with later Autoconf versions.

AC_TRY_COMPILE macros should be replaced with AC_COMPILE_IFELSE.

Refs:
- http://git.savannah.gnu.org/cgit/autoconf.git/tree/NEWS
- https://www.gnu.org/software/autoconf/manual/autoconf-2.69/html_node/Language-Choice.html
- https://www.gnu.org/software/autoconf/manual/autoconf-2.69/html_node/Obsolete-Macros.html

1 files changed, 7 insertions, 8 deletions

diff --git a/m4/ax_cxx_dynamic_cast.m4 b/m4/ax_cxx_dynamic_cast.m4
index 86c0c82..3f1d5af 100644
--- a/m4/ax_cxx_dynamic_cast.m4
+++ b/m4/ax_cxx_dynamic_cast.m4
@@ -20,20 +20,19 @@
 #   and this notice are preserved. This file is offered as-is, without any
 #   warranty.
 
-#serial 7
+#serial 8
 
 AU_ALIAS([AC_CXX_DYNAMIC_CAST], [AX_CXX_DYNAMIC_CAST])
 AC_DEFUN([AX_CXX_DYNAMIC_CAST],
 [AC_CACHE_CHECK(whether the compiler supports dynamic_cast<>,
 ax_cv_cxx_dynamic_cast,
-[AC_LANG_SAVE
- AC_LANG_CPLUSPLUS
- AC_TRY_COMPILE([#include <typeinfo>
+[AC_LANG_PUSH([C++])
+ AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <typeinfo>
 class Base { public : Base () {} virtual void f () = 0;};
-class Derived : public Base { public : Derived () {} virtual void f () {} };],[
-Derived d; Base& b=d; return dynamic_cast<Derived*>(&b) ? 0 : 1;],
- ax_cv_cxx_dynamic_cast=yes, ax_cv_cxx_dynamic_cast=no)
- AC_LANG_RESTORE
+class Derived : public Base { public : Derived () {} virtual void f () {} };]], [[
+Derived d; Base& b=d; return dynamic_cast<Derived*>(&b) ? 0 : 1;]])],
+ [ax_cv_cxx_dynamic_cast=yes], [ax_cv_cxx_dynamic_cast=no])
+ AC_LANG_POP([C++])
 ])
 if test "$ax_cv_cxx_dynamic_cast" = yes; then
   AC_DEFINE(HAVE_DYNAMIC_CAST,,[define if the compiler supports dynamic_cast<>])