Replace AC_TRY_COMPILE and AC_LANG_

Autoconf 2.50 in 2001 made several macros obsolete. These include macros
for temporary changing the language - AC_LANG_SAVE, AC_LANG_CPLUSPLUS,
AC_LANG_C, and AC_LANG_RESTORE. Instead of these the AC_LANG_PUSH and
AC_LANG_POP macros should be used with later Autoconf versions.

AC_TRY_COMPILE macros should be replaced with AC_COMPILE_IFELSE.

Refs:
- http://git.savannah.gnu.org/cgit/autoconf.git/tree/NEWS
- https://www.gnu.org/software/autoconf/manual/autoconf-2.69/html_node/Language-Choice.html
- https://www.gnu.org/software/autoconf/manual/autoconf-2.69/html_node/Obsolete-Macros.html

1 files changed, 7 insertions, 8 deletions

diff --git a/m4/ax_cxx_gcc_abi_demangle.m4 b/m4/ax_cxx_gcc_abi_demangle.m4
index fff997b..bec8450 100644
--- a/m4/ax_cxx_gcc_abi_demangle.m4
+++ b/m4/ax_cxx_gcc_abi_demangle.m4
@@ -23,20 +23,19 @@
 #   and this notice are preserved. This file is offered as-is, without any
 #   warranty.
 
-#serial 9
+#serial 10
 
 AC_DEFUN([AX_CXX_GCC_ABI_DEMANGLE],
 [AC_CACHE_CHECK(whether the compiler supports GCC C++ ABI name demangling,
 ax_cv_cxx_gcc_abi_demangle,
-[AC_LANG_SAVE
- AC_LANG_CPLUSPLUS
- AC_TRY_COMPILE([#include <typeinfo>
+[AC_LANG_PUSH([C++])
+ AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <typeinfo>
 #include <cxxabi.h>
 #include <string>
 
 template<typename TYPE>
 class A {};
-],[A<int> instance;
+]], [[A<int> instance;
 int status = 0;
 char* c_name = 0;
 
@@ -46,9 +45,9 @@ std::string name(c_name);
 free(c_name);
 
 return name == "A<int>";
-],
- ax_cv_cxx_gcc_abi_demangle=yes, ax_cv_cxx_gcc_abi_demangle=no)
- AC_LANG_RESTORE
+]])],
+ [ax_cv_cxx_gcc_abi_demangle=yes], [ax_cv_cxx_gcc_abi_demangle=no])
+ AC_LANG_POP([C++])
 ])
 if test "$ax_cv_cxx_gcc_abi_demangle" = yes; then
   AC_DEFINE(HAVE_GCC_ABI_DEMANGLE,1,