Fix the meson build

I merged two MRs and broke the build:

- One MR added perf/ to the meson build
- The second MR changed lots of meson code to just dependency objects
  instead of just "messing" with include directories and library objects

The result was that perf/meson.build now referred to include objects and
library objects that no longer exist.

Fix this by also using dependency objects in perf/.

Signed-off-by: Uli Schlachter <psychon@znc.in>

2 files changed, 29 insertions, 25 deletions

diff --git a/perf/meson.build b/perf/meson.build
index 40ebeea05..d26dd6923 100644
--- a/perf/meson.build
+++ b/perf/meson.build
@@ -13,9 +13,11 @@ libcairoperf = static_library('cairoperf',
     'cairo-perf.h',
     'cairo-stats.h',
   ],
-  include_directories: [incbase, incsrc, incboilerplate, inccairomissing],
-  link_with: [libcairomissing, libcairoboilerplate],
-  dependencies: [pixman_dep],
+  include_directories: [incbase, incsrc],
+  dependencies: [pixman_dep, libcairomissing_dep, cairoboilerplate_dep],
+)
+libcairoperf_dep = declare_dependency(
+  link_with: libcairoperf,
 )
 
 
@@ -24,9 +26,9 @@ analyse_trace = executable('cairo-analyse-trace',
     'cairo-analyse-trace.c',
     '../src/cairo-error.c',
   ],
-  include_directories: [incbase, incsrc, incboilerplate, inccairoscript, inccairomissing],
-  link_with: [libcairo, libcairoboilerplate, libcairoscript, libcairomissing],
-  dependencies: [pixman_dep, fontconfig_dep],
+  include_directories: [incbase],
+  dependencies: [pixman_dep, fontconfig_dep, libcairo_dep, cairoboilerplate_dep,
+    libcairoscript_dep, libcairomissing_dep],
 )
 
 perf_trace = executable('cairo-perf-trace',
@@ -35,48 +37,48 @@ perf_trace = executable('cairo-perf-trace',
     '../src/cairo-error.c',
     '../src/cairo-hash.c',
   ],
-  include_directories: [incbase, incsrc, incboilerplate, inccairoscript, inccairomissing],
-  link_with: [libcairoperf, libcairoscript],
-  dependencies: [pixman_dep, fontconfig_dep],
+  include_directories: [incbase, incsrc],
+  dependencies: [pixman_dep, fontconfig_dep, libcairoperf_dep, libcairoscript_dep,
+    cairoboilerplate_dep, libcairomissing_dep],
 )
 
 micro = executable('cairo-perf-micro',
   [ 'cairo-perf-micro.c', ],
-  include_directories: [incbase, incsrc, incboilerplate, inccairomissing],
-  link_with: [libcairoperf, libcairoperfmicro],
-  dependencies: [fontconfig_dep],
+  include_directories: [incbase, incsrc],
+  dependencies: [fontconfig_dep, libcairoperf_dep, libcairoperfmicro_dep,
+    cairoboilerplate_dep, libcairomissing_dep],
 )
 
 diff_files = executable('cairo-perf-diff-files',
   [
     'cairo-perf-diff-files.c',
   ],
-  include_directories: [incbase, incsrc, incboilerplate],
-  link_with: [libcairoperf],
+  include_directories: [incbase, incsrc],
+  dependencies: [libcairoperf_dep, cairoboilerplate_dep],
 )
 
 print = executable('cairo-perf-print',
   [
     'cairo-perf-print.c',
   ],
-  include_directories: [incbase, incsrc, incboilerplate],
-  link_with: [libcairoperf],
+  include_directories: [incbase, incsrc],
+  dependencies: [libcairoperf_dep, cairoboilerplate_dep],
 )
 
 chart = executable('cairo-perf-chart',
   [
     'cairo-perf-chart.c',
   ],
-  include_directories: [incbase, incsrc, incboilerplate],
-  link_with: [libcairoperf],
+  include_directories: [incbase, incsrc],
+  dependencies: [libcairoperf_dep, cairoboilerplate_dep],
 )
 
 compare_backends = executable('cairo-perf-compare-backends',
   [
     'cairo-perf-compare-backends.c',
   ],
-  include_directories: [incbase, incsrc, incboilerplate],
-  link_with: [libcairoperf],
+  include_directories: [incbase, incsrc],
+  dependencies: [libcairoperf_dep, cairoboilerplate_dep],
 )
 
 if gtk2_dep.found()
@@ -86,8 +88,7 @@ if gtk2_dep.found()
       'cairo-perf-graph-widget.c',
       'cairo-perf-graph.h',
     ],
-    include_directories: [incbase, incsrc, incboilerplate],
-    link_with: [libcairo, libcairoboilerplate, libcairoperf],
-    dependencies: [gtk2_dep],
+    include_directories: [incbase, incsrc],
+    dependencies: [gtk2_dep, libcairo_dep, cairoboilerplate_dep, libcairoperf_dep],
   )
 endif
diff --git a/perf/micro/meson.build b/perf/micro/meson.build
index 5ee45b5ce..8802f4c45 100644
--- a/perf/micro/meson.build
+++ b/perf/micro/meson.build
@@ -52,6 +52,9 @@ perf_micro_headers = [
 
 libcairoperfmicro = static_library('cairo-perf-micro',
   perf_micro_sources + perf_micro_headers,
-  include_directories: [incbase, incsrc, incboilerplate, incmicro],
-  dependencies: [pixman_dep],
+  include_directories: [incbase, incsrc, incmicro],
+  dependencies: [pixman_dep, cairoboilerplate_dep],
+)
+libcairoperfmicro_dep = declare_dependency(
+  link_with: libcairoperfmicro,
 )