blob: 0825f2af491937b672e72cf25df30aaf8d2fd773 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
|
cmake_minimum_required(VERSION 3.4.3)
project(ccache LANGUAGES C CXX)
if(MSVC)
enable_language(ASM_MASM)
else()
enable_language(ASM)
endif()
set(CMAKE_PROJECT_DESCRIPTION "a fast C/C++ compiler cache")
if(NOT "${CMAKE_CXX_STANDARD}")
set(CMAKE_CXX_STANDARD 11)
endif()
set(CMAKE_CXX_STANDARD_REQUIRED YES)
set(CMAKE_CXX_EXTENSIONS NO)
set(CMAKE_C_STANDARD 99)
set(CMAKE_C_STANDARD_REQUIRED YES)
set(CMAKE_C_EXTENSIONS NO)
# Always export compile_commands.json since it's useful for many tools.
set(CMAKE_EXPORT_COMPILE_COMMANDS TRUE)
list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/cmake")
#
# Minimum compiler requirements (fail gracefully instead of producing cryptic
# C++ error messages)
#
# Clang 3.4 and AppleClang 6.0 fail to compile doctest.
# GCC 4.8.4 is known to work OK but give warnings.
if((CMAKE_CXX_COMPILER_ID STREQUAL "Clang" AND CMAKE_CXX_COMPILER_VERSION VERSION_LESS 3.5)
OR (CMAKE_CXX_COMPILER_ID STREQUAL "GNU" AND CMAKE_CXX_COMPILER_VERSION VERSION_LESS 4.8.4)
OR (CMAKE_CXX_COMPILER_ID STREQUAL "AppleClang" AND CMAKE_CXX_COMPILER_VERSION VERSION_LESS 7.0))
message(
FATAL_ERROR
"The compiler you are using is too old, sorry.\n"
"You need one listed here: https://ccache.dev/platform-compiler-language-support.html")
endif()
# All Clang problems / special handling ccache has are because of version 3.5.
# All GCC problems / special handling ccache has are because of version 4.8.4.
if((CMAKE_CXX_COMPILER_ID STREQUAL "Clang" AND CMAKE_CXX_COMPILER_VERSION VERSION_LESS 3.6)
OR (CMAKE_CXX_COMPILER_ID STREQUAL "GNU" AND CMAKE_CXX_COMPILER_VERSION VERSION_LESS 5.0))
message(
WARNING
"The compiler you are using is rather old.\n"
"If anything goes wrong you might be better off with one listed here:"
" https://ccache.dev/platform-compiler-language-support.html")
# Warnings from old compilers are probably useless anyway.
option(WARNINGS_AS_ERRORS "Treat compiler warnings as errors" FALSE)
endif()
#
# Settings
#
include(CcacheVersion)
if("${CCACHE_VERSION_ORIGIN}" STREQUAL git OR DEFINED ENV{CI})
set(CCACHE_DEV_MODE ON)
else()
set(CCACHE_DEV_MODE OFF)
endif()
message(STATUS "Ccache dev mode: ${CCACHE_DEV_MODE}")
include(UseCcache)
if(NOT MSVC)
include(UseFastestLinker)
endif()
include(StandardSettings)
include(StandardWarnings)
include(CIBuildType)
include(DefaultBuildType)
if(NOT ${CMAKE_VERSION} VERSION_LESS "3.9")
cmake_policy(SET CMP0069 NEW)
option(ENABLE_IPO "Enable interprocedural (link time, LTO) optimization" OFF)
if(ENABLE_IPO)
set(CMAKE_INTERPROCEDURAL_OPTIMIZATION ON)
endif()
endif()
#
# Configuration
#
include(GNUInstallDirs)
include(GenerateConfigurationFile)
include(GenerateVersionFile)
if(HAVE_SYS_MMAN_H AND HAVE_PTHREAD_MUTEXATTR_SETPSHARED)
set(INODE_CACHE_SUPPORTED 1)
endif()
#
# Third party
#
set(ZSTD_FROM_INTERNET_DEFAULT OFF)
# Default to downloading deps for Visual Studio, unless using a package manager.
if(MSVC AND NOT CMAKE_TOOLCHAIN_FILE MATCHES "vcpkg|conan")
set(ZSTD_FROM_INTERNET_DEFAULT ON)
endif()
option(ZSTD_FROM_INTERNET "Download and use libzstd from the Internet" ${ZSTD_FROM_INTERNET_DEFAULT})
find_package(zstd 1.1.2 REQUIRED)
#
# Special flags
#
# Note: Cppcheck will scan everything after this point. zstd is above so it
# doesn't get scanned.
#
include(CodeAnalysis)
option(ENABLE_TRACING "Enable possibility to use internal ccache tracing" OFF)
if(WIN32 AND CMAKE_CXX_COMPILER_ID MATCHES "GNU")
option(STATIC_LINK "Link statically with system libraries" ON)
endif()
#
# Source code
#
add_subdirectory(src)
#
# ccache executable
#
add_executable(ccache src/main.cpp)
target_link_libraries(ccache PRIVATE standard_settings standard_warnings ccache_lib)
#
# Documentation
#
add_subdirectory(doc)
#
# Installation
#
install(TARGETS ccache DESTINATION ${CMAKE_INSTALL_BINDIR})
#
# Packaging
#
include(CcachePackConfig)
#
# Tests
#
option(ENABLE_TESTING "Enable tests" ON)
if(ENABLE_TESTING)
enable_testing()
add_subdirectory(unittest)
add_subdirectory(test)
# Note: VERSION_GREATER_EQUAL requires CMake 3.17
if(NOT ${CMAKE_VERSION} VERSION_LESS "3.17")
list(APPEND CMAKE_CTEST_ARGUMENTS "--output-on-failure")
endif()
# Add "check" target which compiles and runs tests.
set(
check_command
${CMAKE_CTEST_COMMAND} --force-new-ctest-process --output-on-failure)
if(CMAKE_CONFIGURATION_TYPES)
list(APPEND check_command --build-config "$<CONFIGURATION>")
endif()
add_custom_target(
check
COMMAND ${check_command}
WORKING_DIRECTORY ${CMAKE_BINARY_DIR}
DEPENDS ccache unittest)
endif()
#
# Special formatting targets
#
add_custom_target(
format
COMMAND misc/format-files --all
COMMENT "Formatting code"
USES_TERMINAL
WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR})
add_custom_target(
check_format
COMMAND misc/format-files --all --check
COMMENT "Checking code formatting"
USES_TERMINAL
WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR})
|
