summaryrefslogtreecommitdiff
path: root/src/vala/CMakeLists.txt
blob: 8cc698ac3852f8a93fc68fa5f64040cc45bd4757 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
# Filled by the _build_vala_files macro below
set(valafiles)

add_custom_target(vala ALL)

# ***********************************
# Helper macro
# ***********************************

macro(_build_vala_files _lib_name _gir_fullname_var _gir_deps_var _gir_dirs_var _vala_deps_var _extra_vapigen_files_var)
	list(APPEND valafiles
		${CMAKE_CURRENT_BINARY_DIR}/${_lib_name}.deps
		${CMAKE_CURRENT_BINARY_DIR}/${_lib_name}.vapi
	)

	add_dependencies(vala ${${_gir_deps_var}})

	set(gir_dirs_param)
	set(vala_deps_param)
	set(vala_deps_content "")
	set(vapi_deps)

	foreach(_item IN LISTS ${_gir_dirs_var})
		list(APPEND gir_dirs_param --girdir=${_item})
	endforeach()

	foreach(_item IN LISTS ${_vala_deps_var})
		# those beginning with '*' are built here, thus
		# skip them from the vapigen arguments
		string(SUBSTRING "${_item}" 0 1 _item_prefix)
		if("${_item_prefix}" STREQUAL "*")
			string(SUBSTRING "${_item}" 1, -1, _item)
			list(APPEND vapi_deps ${CMAKE_CURRENT_BINARY_DIR}/${_item}.vapi)
		endif("${_item_prefix}" STREQUAL "*")

		list(APPEND vala_deps_param --pkg ${_item})
		string(CONCAT vala_deps_content "${vala_deps_content}" "${_item}\n")
	endforeach()

	file(GENERATE
		OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${_lib_name}.deps
		CONTENT "${vala_deps_content}"
	)

	add_custom_command(OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${_lib_name}.vapi
		COMMAND ${VAPIGEN}
			--vapidir=${CMAKE_CURRENT_SOURCE_DIR}
			--vapidir=${CMAKE_CURRENT_BINARY_DIR}
			${gir_dirs_param}
			--girdir=${SHARE_INSTALL_PREFIX}/gir-1.0
			${vala_deps_param}
			--library ${_lib_name}
			--metadatadir=${CMAKE_CURRENT_SOURCE_DIR}
			${${_gir_fullname_var}}
			${${_extra_vapigen_files_var}}
		DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${_lib_name}.deps
			${vapi_deps}
			${${_extra_vapigen_files_var}}
			${${_gir_deps_var}}
			${${_gir_fullname_var}}
	)
endmacro(_build_vala_files)

# ***********************************
# camel
# ***********************************

set(gir_fullname ${CMAKE_BINARY_DIR}/src/camel/Camel-${API_VERSION}.gir)
gir_girfilename_to_target(gir_deps Camel-${API_VERSION}.gir)

set(gir_dirs
	${CMAKE_BINARY_DIR}/src/camel
)

set(vala_deps
	gio-2.0
	libxml-2.0
	posix
)

set(extra_vapigen_files
	${CMAKE_CURRENT_SOURCE_DIR}/camel-${API_VERSION}-custom.vala
)

_build_vala_files(camel-${API_VERSION}
	gir_fullname
	gir_deps
	gir_dirs
	vala_deps
	extra_vapigen_files
)

# ***********************************
# libedataserver
# ***********************************

set(gir_fullname ${CMAKE_BINARY_DIR}/src/libedataserver/EDataServer-${API_VERSION}.gir)
gir_girfilename_to_target(gir_deps EDataServer-${API_VERSION}.gir)

set(gir_dirs
	${CMAKE_BINARY_DIR}/src/camel
	${CMAKE_BINARY_DIR}/src/libedataserver
)

set(vala_deps
	*camel-${API_VERSION}
	gio-2.0
	libsoup-3.0
	libxml-2.0
	json-glib-1.0
	posix
)

set(extra_vapigen_files)

_build_vala_files(libedataserver-${API_VERSION}
	gir_fullname
	gir_deps
	gir_dirs
	vala_deps
	extra_vapigen_files
)

# ***********************************
# libebackend
# ***********************************

set(gir_fullname ${CMAKE_BINARY_DIR}/src/libebackend/EBackend-${API_VERSION}.gir)
gir_girfilename_to_target(gir_deps EBackend-${API_VERSION}.gir)

set(gir_dirs
	${CMAKE_BINARY_DIR}/src/camel
	${CMAKE_BINARY_DIR}/src/libedataserver
	${CMAKE_BINARY_DIR}/src/libebackend
)

set(vala_deps
	*libedataserver-${API_VERSION}
	gio-2.0
	libsoup-3.0
	libxml-2.0
	posix
)

set(extra_vapigen_files)

_build_vala_files(libebackend-${API_VERSION}
	gir_fullname
	gir_deps
	gir_dirs
	vala_deps
	extra_vapigen_files
)

# ***********************************
# libebook-contacts
# ***********************************

set(gir_fullname ${CMAKE_BINARY_DIR}/src/addressbook/libebook-contacts/EBookContacts-${API_VERSION}.gir)
gir_girfilename_to_target(gir_deps EBookContacts-${API_VERSION}.gir)

set(gir_dirs
	${CMAKE_BINARY_DIR}/src/camel
	${CMAKE_BINARY_DIR}/src/libedataserver
)

set(vala_deps
	*camel-${API_VERSION}
	*libedataserver-${API_VERSION}
	gio-2.0
	libsoup-3.0
	libxml-2.0
	posix
)

set(extra_vapigen_files
	${CMAKE_CURRENT_SOURCE_DIR}/libebook-contacts-${API_VERSION}-custom.vala
)

_build_vala_files(libebook-contacts-${API_VERSION}
	gir_fullname
	gir_deps
	gir_dirs
	vala_deps
	extra_vapigen_files
)

# ***********************************
# libebook
# ***********************************

set(gir_fullname ${CMAKE_BINARY_DIR}/src/addressbook/libebook/EBook-${API_VERSION}.gir)
gir_girfilename_to_target(gir_deps EBook-${API_VERSION}.gir)

set(gir_dirs
	${CMAKE_BINARY_DIR}/src/camel
	${CMAKE_BINARY_DIR}/src/libedataserver
	${CMAKE_BINARY_DIR}/src/addressbook/libebook-contacts
)

set(vala_deps
	*camel-${API_VERSION}
	*libedataserver-${API_VERSION}
	*libebook-contacts-${API_VERSION}
	gio-2.0
	libsoup-3.0
	libxml-2.0
	posix
)

set(extra_vapigen_files)

_build_vala_files(libebook-${API_VERSION}
	gir_fullname
	gir_deps
	gir_dirs
	vala_deps
	extra_vapigen_files
)

# ***********************************
# libedata-book
# ***********************************

set(gir_fullname ${CMAKE_BINARY_DIR}/src/addressbook/libedata-book/EDataBook-${API_VERSION}.gir)
gir_girfilename_to_target(gir_deps EDataBook-${API_VERSION}.gir)

set(gir_dirs
	${CMAKE_BINARY_DIR}/src/camel
	${CMAKE_BINARY_DIR}/src/libebackend
	${CMAKE_BINARY_DIR}/src/libedataserver
	${CMAKE_BINARY_DIR}/src/addressbook/libebook-contacts
)

set(vala_deps
	*camel-${API_VERSION}
	*libedataserver-${API_VERSION}
	*libebackend-${API_VERSION}
	*libebook-contacts-${API_VERSION}
	gio-2.0
	libsoup-3.0
	libxml-2.0
	posix
)

set(extra_vapigen_files)

_build_vala_files(libedata-book-${API_VERSION}
	gir_fullname
	gir_deps
	gir_dirs
	vala_deps
	extra_vapigen_files
)

# ***********************************
# libecal
# ***********************************

set(gir_fullname ${CMAKE_BINARY_DIR}/src/calendar/libecal/ECal-${CAL_API_VERSION}.gir)
gir_girfilename_to_target(gir_deps ECal-${CAL_API_VERSION}.gir)

set(gir_dirs
	${CMAKE_BINARY_DIR}/src/camel
	${CMAKE_BINARY_DIR}/src/libedataserver
	${CMAKE_BINARY_DIR}/src/calendar/libecal
)

set(vala_deps
	*camel-${API_VERSION}
	*libedataserver-${API_VERSION}
	gio-2.0
	libical-glib
	libsoup-3.0
	libxml-2.0
	posix
)

set(extra_vapigen_files)

_build_vala_files(libecal-${CAL_API_VERSION}
	gir_fullname
	gir_deps
	gir_dirs
	vala_deps
	extra_vapigen_files
)

# ***********************************
# libedata-cal
# ***********************************

set(gir_fullname ${CMAKE_BINARY_DIR}/src/calendar/libedata-cal/EDataCal-${CAL_API_VERSION}.gir)
gir_girfilename_to_target(gir_deps EDataCal-${CAL_API_VERSION}.gir)

set(gir_dirs
	${CMAKE_BINARY_DIR}/src/camel
	${CMAKE_BINARY_DIR}/src/libebackend
	${CMAKE_BINARY_DIR}/src/libedataserver
	${CMAKE_BINARY_DIR}/src/calendar/libecal
	${CMAKE_BINARY_DIR}/src/calendar/libedata-cal
)

set(vala_deps
	*camel-${API_VERSION}
	*libedataserver-${API_VERSION}
	*libebackend-${API_VERSION}
	*libecal-${CAL_API_VERSION}
	gio-2.0
	libical-glib
	libsoup-3.0
	libxml-2.0
	posix
)

set(extra_vapigen_files)

_build_vala_files(libedata-cal-${CAL_API_VERSION}
	gir_fullname
	gir_deps
	gir_dirs
	vala_deps
	extra_vapigen_files
)

# ***********************************
# libedataserverui
# ***********************************

if(ENABLE_GTK)
	set(gir_fullname ${CMAKE_BINARY_DIR}/src/libedataserverui/EDataServerUI-${API_VERSION}.gir)
	gir_girfilename_to_target(gir_deps EDataServerUI-${API_VERSION}.gir)

	set(gir_dirs
		${CMAKE_BINARY_DIR}/src/camel
		${CMAKE_BINARY_DIR}/src/libedataserver
		${CMAKE_BINARY_DIR}/src/calendar/libecal
	)

	set(vala_deps
		*libedataserver-${API_VERSION}
		*libecal-${CAL_API_VERSION}
		gio-2.0
		gtk+-3.0
		libsoup-3.0
		libxml-2.0
		posix
	)

	set(extra_vapigen_files)

	_build_vala_files(libedataserverui-${API_VERSION}
		gir_fullname
		gir_deps
		gir_dirs
		vala_deps
		extra_vapigen_files
	)
endif(ENABLE_GTK)

if(ENABLE_GTK4)
	set(gir_fullname ${CMAKE_BINARY_DIR}/src/libedataserverui/EDataServerUI4-${LIBEDATASERVERUI4_API_VERSION}.gir)
	gir_girfilename_to_target(gir_deps EDataServerUI4-${LIBEDATASERVERUI4_API_VERSION}.gir)

	set(gir_dirs
		${CMAKE_BINARY_DIR}/src/camel
		${CMAKE_BINARY_DIR}/src/libedataserver
		${CMAKE_BINARY_DIR}/src/calendar/libecal
	)

	set(vala_deps
		*libedataserver-${API_VERSION}
		*libecal-${CAL_API_VERSION}
		gio-2.0
		gtk4
		libsoup-3.0
		libxml-2.0
		posix
	)

	set(extra_vapigen_files)

	_build_vala_files(libedataserverui4-${LIBEDATASERVERUI4_API_VERSION}
		gir_fullname
		gir_deps
		gir_dirs
		vala_deps
		extra_vapigen_files
	)
endif(ENABLE_GTK4)

# ***********************************
# Install all VAPI files
# ***********************************

add_custom_target(vala-files
	DEPENDS ${valafiles}
)

add_dependencies(vala vala-files)

install(FILES ${valafiles}
	DESTINATION ${SHARE_INSTALL_PREFIX}/vala/vapi
)