avfilter/vf_maskedclamp: add x86 SIMD

3 files changed, 144 insertions, 0 deletions

diff --git a/libavfilter/x86/Makefile b/libavfilter/x86/Makefile
index 8d97e46c3f..016a5b3511 100644
--- a/libavfilter/x86/Makefile
+++ b/libavfilter/x86/Makefile
@@ -17,6 +17,7 @@ OBJS-$(CONFIG_HQDN3D_FILTER)                 += x86/vf_hqdn3d_init.o
 OBJS-$(CONFIG_IDET_FILTER)                   += x86/vf_idet_init.o
 OBJS-$(CONFIG_INTERLACE_FILTER)              += x86/vf_tinterlace_init.o
 OBJS-$(CONFIG_LIMITER_FILTER)                += x86/vf_limiter_init.o
+OBJS-$(CONFIG_MASKEDCLAMP_FILTER)            += x86/vf_maskedclamp_init.o
 OBJS-$(CONFIG_MASKEDMERGE_FILTER)            += x86/vf_maskedmerge_init.o
 OBJS-$(CONFIG_NOISE_FILTER)                  += x86/vf_noise.o
 OBJS-$(CONFIG_OVERLAY_FILTER)                += x86/vf_overlay_init.o
@@ -56,6 +57,7 @@ X86ASM-OBJS-$(CONFIG_HQDN3D_FILTER)          += x86/vf_hqdn3d.o
 X86ASM-OBJS-$(CONFIG_IDET_FILTER)            += x86/vf_idet.o
 X86ASM-OBJS-$(CONFIG_INTERLACE_FILTER)       += x86/vf_interlace.o
 X86ASM-OBJS-$(CONFIG_LIMITER_FILTER)         += x86/vf_limiter.o
+X86ASM-OBJS-$(CONFIG_MASKEDCLAMP_FILTER)     += x86/vf_maskedclamp.o
 X86ASM-OBJS-$(CONFIG_MASKEDMERGE_FILTER)     += x86/vf_maskedmerge.o
 X86ASM-OBJS-$(CONFIG_OVERLAY_FILTER)         += x86/vf_overlay.o
 X86ASM-OBJS-$(CONFIG_PP7_FILTER)             += x86/vf_pp7.o
diff --git a/libavfilter/x86/vf_maskedclamp.asm b/libavfilter/x86/vf_maskedclamp.asm
new file mode 100644
index 0000000000..d586610c92
--- /dev/null
+++ b/libavfilter/x86/vf_maskedclamp.asm
@@ -0,0 +1,95 @@
+;*****************************************************************************
+;* x86-optimized functions for maskedclamp filter
+;*
+;* Copyright (c) 2019 Paul B Mahol
+;*
+;* This file is part of FFmpeg.
+;*
+;* FFmpeg is free software; you can redistribute it and/or
+;* modify it under the terms of the GNU Lesser General Public
+;* License as published by the Free Software Foundation; either
+;* version 2.1 of the License, or (at your option) any later version.
+;*
+;* FFmpeg is distributed in the hope that it will be useful,
+;* but WITHOUT ANY WARRANTY; without even the implied warranty of
+;* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
+;* Lesser General Public License for more details.
+;*
+;* You should have received a copy of the GNU Lesser General Public
+;* License along with FFmpeg; if not, write to the Free Software
+;* Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA
+;******************************************************************************
+
+%include "libavutil/x86/x86util.asm"
+
+SECTION .text
+
+;------------------------------------------------------------------------------
+; void ff_maskedclamp(const uint8_t *src, uint8_t *dst,
+;                     const uint8_t *darksrc,
+;                     const uint8_t *brightsrc,
+;                     int w, int undershoot, int overshoot)
+;------------------------------------------------------------------------------
+
+INIT_XMM sse2
+cglobal maskedclamp8, 5,5,5, src, dst, dark, bright, w, undershoot, overshoot
+    movsxdifnidn wq, wd
+
+    add        srcq, wq
+    add       darkq, wq
+    add     brightq, wq
+    add        dstq, wq
+    neg          wq
+
+    movd         m3, r5m
+    punpcklbw    m3, m3
+    SPLATW       m3, m3
+
+    movd         m4, r6m
+    punpcklbw    m4, m4
+    SPLATW       m4, m4
+
+    .loop:
+        movu                  m0, [srcq + wq]
+        movu                  m1, [darkq + wq]
+        movu                  m2, [brightq + wq]
+
+        psubusb               m1, m3
+        paddusb               m2, m4
+        CLIPUB                m0, m1, m2
+        mova         [dstq + wq], m0
+
+        add                   wq, mmsize
+        jl .loop
+    RET
+
+INIT_XMM sse4
+cglobal maskedclamp16, 5,5,5, src, dst, dark, bright, w, undershoot, overshoot
+    shl          wd, 1
+
+    add        srcq, wq
+    add       darkq, wq
+    add     brightq, wq
+    add        dstq, wq
+    neg          wq
+
+    movd         m3, r5m
+    SPLATW       m3, m3
+
+    movd         m4, r6m
+    SPLATW       m4, m4
+
+    .loop:
+        movu                  m0, [srcq + wq]
+        movu                  m1, [darkq + wq]
+        movu                  m2, [brightq + wq]
+
+        psubusw               m1, m3
+        paddusw               m2, m4
+        pmaxuw                m0, m1
+        pminuw                m0, m2
+        mova         [dstq + wq], m0
+
+        add                   wq, mmsize
+        jl .loop
+    RET
diff --git a/libavfilter/x86/vf_maskedclamp_init.c b/libavfilter/x86/vf_maskedclamp_init.c
new file mode 100644
index 0000000000..53153f80ea
--- /dev/null
+++ b/libavfilter/x86/vf_maskedclamp_init.c
@@ -0,0 +1,47 @@
+/*
+ * Copyright (c) 2019 Paul B Mahol
+ *
+ * This file is part of FFmpeg.
+ *
+ * FFmpeg is free software; you can redistribute it and/or
+ * modify it under the terms of the GNU Lesser General Public
+ * License as published by the Free Software Foundation; either
+ * version 2.1 of the License, or (at your option) any later version.
+ *
+ * FFmpeg is distributed in the hope that it will be useful,
+ * but WITHOUT ANY WARRANTY; without even the implied warranty of
+ * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
+ * Lesser General Public License for more details.
+ *
+ * You should have received a copy of the GNU Lesser General Public
+ * License along with FFmpeg; if not, write to the Free Software
+ * Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA
+ */
+
+#include "libavutil/attributes.h"
+#include "libavutil/cpu.h"
+#include "libavutil/mem.h"
+#include "libavutil/x86/asm.h"
+#include "libavutil/x86/cpu.h"
+#include "libavfilter/maskedclamp.h"
+
+void ff_maskedclamp8_sse2(const uint8_t *bsrc, uint8_t *dst,
+                          const uint8_t *darksrc, const uint8_t *brightsrc,
+                          int w, int undershoot, int overshoot);
+
+void ff_maskedclamp16_sse4(const uint8_t *bsrc, uint8_t *dst,
+                           const uint8_t *darksrc, const uint8_t *brightsrc,
+                           int w, int undershoot, int overshoot);
+
+av_cold void ff_maskedclamp_init_x86(MaskedClampDSPContext *dsp, int depth)
+{
+    int cpu_flags = av_get_cpu_flags();
+
+    if (EXTERNAL_SSE2(cpu_flags) && depth <= 8) {
+        dsp->maskedclamp = ff_maskedclamp8_sse2;
+    }
+
+    if (EXTERNAL_SSE4(cpu_flags) && depth > 8) {
+        dsp->maskedclamp = ff_maskedclamp16_sse4;
+    }
+}