1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
|
{
This file is part of the Free Pascal run time library.
Copyright (c) 2005 by Michael Van Canneyt, Peter Vreman,
& Daniel Mantione, members of the Free Pascal development team.
See the file COPYING.FPC, included in this distribution,
for details about the copyright.
This program is distributed in the hope that it will be useful,
but WITHOUT ANY WARRANTY; without even the implied warranty of
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
**********************************************************************}
{$asmmode att}
{
Linux ELF startup code for Free Pascal
Stack layout at program start:
nil
envn
....
.... ENVIRONMENT VARIABLES
env1
env0
nil
argn
....
.... COMMAND LINE OPTIONS
arg1
arg0
argc <--- esp
}
procedure PASCALMAIN; external name 'PASCALMAIN';
{******************************************************************************
Process start/halt
******************************************************************************}
var
dlexitproc : pointer;
{$ifdef FPC_PIC}
function fpc_geteipasebxlocal : pointer; [external name 'fpc_geteipasebx'];
{$endif}
procedure _FPC_proc_start; assembler; nostackframe; public name '_start';
asm
{ First locate the start of the environment variables }
popl %ecx { Get argc in ecx }
movl %esp,%ebx { Esp now points to the arguments }
leal 4(%esp,%ecx,4),%eax { The start of the environment is: esp+4*eax+4 }
andl $0xfffffff0,%esp { Align stack to 16 bytes }
{$ifdef FPC_PIC}
pushl %ebx
pushl %ecx
call fpc_geteipasebxlocal
addl $_GLOBAL_OFFSET_TABLE_,%ebx
movl operatingsystem_parameter_envp@GOT(%ebx),%ecx
movl %eax,(%ecx)
movl operatingsystem_parameter_argc@GOT(%ebx),%edx
popl %ecx
movl %ecx,(%edx)
movl operatingsystem_parameter_argv@GOT(%ebx),%edx
popl %ebx
movl %ebx,(%edx)
{$else FPC_PIC}
movl %eax,operatingsystem_parameter_envp
movl %ecx,operatingsystem_parameter_argc
movl %ebx,operatingsystem_parameter_argv
{$endif FPC_PIC}
{ Initialize FPU }
call SysResetFPU
{ Save initial stackpointer }
{$ifdef FPC_PIC}
pushl %ebx
call fpc_geteipasebxlocal
addl $_GLOBAL_OFFSET_TABLE_,%ebx
movl initialstkptr@GOT(%ebx),%ebx
movl %esp,(%ebx)
popl %ebx
{$else FPC_PIC}
movl %esp,initialstkptr
{$endif FPC_PIC}
xorl %ebp,%ebp
call PASCALMAIN
end;
procedure _FPC_dynamic_proc_start; assembler; nostackframe; public name '_dynamic_start';
asm
{$ifdef FPC_PIC}
pushl %ebx
call fpc_geteipasebxlocal
addl $_GLOBAL_OFFSET_TABLE_,%ebx
movl dlexitproc@GOT(%ebx),%ebx
movl %edx,(%ebx)
popl %ebx
{$else}
movl %edx, dlexitproc
{$endif}
jmp _FPC_proc_start
end;
procedure _FPC_proc_haltproc; assembler; nostackframe; public name '_haltproc';
asm
addl $12, %esp { align stack back to 16 bytes }
.Lhaltproc:
{$ifdef FPC_PIC}
call fpc_geteipasebxlocal
addl $_GLOBAL_OFFSET_TABLE_,%ebx
movl dlexitproc@GOT(%ebx),%eax
movl (%eax),%eax
{$else FPC_PIC}
movl dlexitproc,%eax
{$endif FPC_PIC}
testl %eax,%eax
je .Lnodlexitproc
call *%eax
.Lnodlexitproc:
movl syscall_nr_exit_group,%eax
{$ifdef FPC_PIC}
call fpc_geteipasebxlocal
addl $_GLOBAL_OFFSET_TABLE_,%ebx
movl ExitCode@GOT(%ebx),%ebx
{$if sizeof(ExitCode)=2}
movzwl (%ebx),%ebx
{$else}
mov (%ebx),%ebx
{$endif}
{$else FPC_PIC}
{$if sizeof(ExitCode)=2}
movzwl ExitCode,%ebx
{$else}
mov ExitCode,%ebx
{$endif}
{$endif FPC_PIC}
int $0x80
movl syscall_nr_exit,%eax
{$ifdef FPC_PIC}
call fpc_geteipasebxlocal
addl $_GLOBAL_OFFSET_TABLE_,%ebx
movl ExitCode@GOT(%ebx),%ebx
{$if sizeof(ExitCode)=2}
movzwl (%ebx),%ebx
{$else}
mov (%ebx),%ebx
{$endif}
{$else FPC_PIC}
{$if sizeof(ExitCode)=2}
movzwl ExitCode,%ebx
{$else}
mov ExitCode,%ebx
{$endif}
{$endif FPC_PIC}
int $0x80
jmp .Lhaltproc
end;
|
