2006-10-31 Hristian Kirtchev <kirtchev@adacore.com>

	    Jose Ruiz  <ruiz@adacore.com>

	* a-calend-vms.adb (Leap_Sec_Ops): Temp body for package in private
	part of Ada.Calendar: all subprogram raise Unimplemented.
	(Split_W_Offset): Temp function body, raising Unimplemented

	* a-calend.ads, a-calend-vms.ads: 
	Add imported variable Invalid_TZ_Offset used to designate targets unable
	to support time zones.
	(Unimplemented): Temporary function raised by the body of new
	subprograms below.
	(Leap_Sec_Ops): New package in the private part of Ada.Calendar. This
	unit provides handling of leap seconds and is used by the new Ada 2005
	packages Ada.Calendar.Arithmetic and Ada.Calendar.Formatting.
	(Split_W_Offset): Identical spec to that of Ada.Calendar.Split. This
	version returns an extra value which is the offset to UTC.

	* a-calend.adb (Split_W_Offset): Add call to localtime_tzoff.
	(Leap_Sec_Ops): New body for package in private part of Ada.Calendar.
	(Split_W_Offset): New function body.
	(Time_Of): When a date is close to UNIX epoch, compute the time for
	that date plus one day (that amount is later substracted after
	executing mktime) so there are no problems with time zone adjustments.

	* a-calend-mingw.adb: Remove Windows specific version no longer needed.

	* a-calari.ads, a-calari.adb, a-calfor.ads, a-calfor.adb,
	a-catizo.ads, a-catizo.adb: New files.

        * impunit.adb: Add new Ada 2005 entries

	* sysdep.c: Add external variable __gnat_invalid_tz_offset.
	Rename all occurences of "__gnat_localtime_r" to
	"__gnat_localtime_tzoff".
	(__gnat_localtime_tzoff for Windows): Add logic to retrieve the time
	zone data and calculate the GMT offset.
	(__gnat_localtime_tzoff for Darwin, Free BSD, Linux, Lynx and Tru64):
	Use the field "tm_gmtoff" to extract the GMT offset.
	(__gnat_localtime_tzoff for AIX, HPUX, SGI Irix and Sun Solaris): Use
	the external variable "timezone" to calculate the GMT offset.



git-svn-id: svn+ssh://gcc.gnu.org/svn/gcc/trunk@118234 138bc75d-0d04-0410-961f-82ee72b054a4

1 files changed, 142 insertions, 0 deletions

diff --git a/gcc/ada/a-calari.adb b/gcc/ada/a-calari.adb
new file mode 100644
index 00000000000..de02a90ce6d
--- /dev/null
+++ b/gcc/ada/a-calari.adb
@@ -0,0 +1,142 @@
+------------------------------------------------------------------------------
+--                                                                          --
+--                         GNAT RUN-TIME COMPONENTS                         --
+--                                                                          --
+--              A D A . C A L E N D A R . A R I T H M E T I C               --
+--                                                                          --
+--                                 B o d y                                  --
+--                                                                          --
+--            Copyright (C) 2006, Free Software Foundation, Inc.            --
+--                                                                          --
+-- GNAT is free software;  you can  redistribute it  and/or modify it under --
+-- terms of the  GNU General Public License as published  by the Free Soft- --
+-- ware  Foundation;  either version 2,  or (at your option) any later ver- --
+-- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
+-- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
+-- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
+-- for  more details.  You should have  received  a copy of the GNU General --
+-- Public License  distributed with GNAT;  see file COPYING.  If not, write --
+-- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
+-- MA 02111-1307, USA.                                                      --
+--                                                                          --
+-- As a special exception,  if other files  instantiate  generics from this --
+-- unit, or you link  this unit with other files  to produce an executable, --
+-- this  unit  does not  by itself cause  the resulting  executable  to  be --
+-- covered  by the  GNU  General  Public  License.  This exception does not --
+-- however invalidate  any other reasons why  the executable file  might be --
+-- covered by the  GNU Public License.                                      --
+--                                                                          --
+-- GNAT was originally developed  by the GNAT team at  New York University. --
+-- Extensive contributions were provided by Ada Core Technologies Inc.      --
+--                                                                          --
+------------------------------------------------------------------------------
+
+with Unchecked_Conversion;
+
+package body Ada.Calendar.Arithmetic is
+
+   use Leap_Sec_Ops;
+
+   Day_Duration : constant Duration := 86_400.0;
+
+   ---------
+   -- "+" --
+   ---------
+
+   function "+" (Left : Time; Right : Day_Count) return Time is
+   begin
+      return Left + Integer (Right) * Day_Duration;
+   end "+";
+
+   function "+" (Left : Day_Count; Right : Time) return Time is
+   begin
+      return Integer (Left) * Day_Duration + Right;
+   end "+";
+
+   ---------
+   -- "-" --
+   ---------
+
+   function "-" (Left : Time; Right : Day_Count) return Time is
+   begin
+      return Left - Integer (Right) * Day_Duration;
+   end "-";
+
+   function "-" (Left, Right : Time) return Day_Count is
+      Days         : Day_Count;
+      Seconds      : Duration;
+      Leap_Seconds : Leap_Seconds_Count;
+
+   begin
+      Difference (Left, Right, Days, Seconds, Leap_Seconds);
+      return Days;
+   end "-";
+
+   ----------------
+   -- Difference --
+   ----------------
+
+   procedure Difference
+     (Left, Right  : Time;
+      Days         : out Day_Count;
+      Seconds      : out Duration;
+      Leap_Seconds : out Leap_Seconds_Count)
+   is
+      Diff        : Duration;
+      Earlier     : Time;
+      Later       : Time;
+      Leaps_Dur   : Duration;
+      Negate      : Boolean;
+      Next_Leap   : Time;
+      Secs_Diff   : Long_Integer;
+      Sub_Seconds : Duration;
+
+   begin
+      if Left >= Right then
+         Later   := Left;
+         Earlier := Right;
+         Negate  := False;
+      else
+         Later   := Right;
+         Earlier := Left;
+         Negate  := True;
+      end if;
+
+      Diff := Later - Earlier;
+
+      Cumulative_Leap_Secs (Earlier, Later, Leaps_Dur, Next_Leap);
+
+      if Later >= Next_Leap then
+         Leaps_Dur := Leaps_Dur + 1.0;
+      end if;
+
+      Diff := Diff - Leaps_Dur;
+
+      declare
+         type D_Int is range 0 .. 2 ** (Duration'Size - 1) - 1;
+         for D_Int'Size use Duration'Size;
+
+         Small_Div : constant D_Int := D_Int (1.0 / Duration'Small);
+         D_As_Int  : D_Int;
+
+         function To_D_As_Int is new Unchecked_Conversion (Duration, D_Int);
+         function To_Duration is new Unchecked_Conversion (D_Int, Duration);
+
+      begin
+         D_As_Int    := To_D_As_Int (Diff);
+         Secs_Diff   := Long_Integer (D_As_Int / Small_Div);
+         Sub_Seconds := To_Duration (D_As_Int rem Small_Div);
+      end;
+
+      Days    := Day_Count (Secs_Diff / 86_400);
+      Seconds := Duration (Secs_Diff mod 86_400) + Sub_Seconds;
+      Leap_Seconds := Leap_Seconds_Count (Leaps_Dur);
+
+      if Negate then
+         Days         := -Days;
+         Seconds      := -Seconds;
+         Leap_Seconds := -Leap_Seconds;
+      end if;
+   end Difference;
+
+end Ada.Calendar.Arithmetic;