d: Import dmd b8384668f, druntime e6caaab9, phobos 5ab9ad256 (v2.098.0-beta.1)

The D front-end is now itself written in D, in order to build GDC, you
will need a working GDC compiler (GCC version 9.1 or later).

GCC changes:

    - Add support for bootstrapping the D front-end.

These add the required components in order to have a D front-end written
in D itself.  Because the compiler front-end only depends on the core
runtime modules, only libdruntime is built for the bootstrap stages.

D front-end changes:

    - Import dmd v2.098.0-beta.1.

Druntime changes:

    - Import druntime v2.098.0-beta.1.

Phobos changes:

    - Import phobos v2.098.0-beta.1.

The jump from v2.076.1 to v2.098.0 covers nearly 4 years worth of
development on the D programming language and run-time libraries.

ChangeLog:

	* Makefile.def: Add bootstrap to libbacktrace, libphobos, zlib, and
	libatomic.
	* Makefile.in: Regenerate.
	* Makefile.tpl (POSTSTAGE1_HOST_EXPORTS): Fix command for GDC.
	(STAGE1_CONFIGURE_FLAGS): Add --with-libphobos-druntime-only if
	target-libphobos-bootstrap.
	(STAGE2_CONFIGURE_FLAGS): Likewise.
	* configure: Regenerate.
	* configure.ac: Add support for bootstrapping D front-end.

config/ChangeLog:

	* acx.m4 (ACX_PROG_GDC): New m4 function.

gcc/ChangeLog:

	* Makefile.in (GDC): New variable.
	(GDCFLAGS): New variable.
	* configure: Regenerate.
	* configure.ac: Add call to ACX_PROG_GDC.  Substitute GDCFLAGS.

gcc/d/ChangeLog:

	* dmd/MERGE: Merge upstream dmd b8384668f.
	* Make-lang.in (d-warn): Use strict warnings.
	(DMD_WARN_CXXFLAGS): Remove.
	(DMD_COMPILE): Remove.
	(CHECKING_DFLAGS): Define.
	(WARN_DFLAGS): Define.
	(ALL_DFLAGS): Define.
	(DCOMPILE.base): Define.
	(DCOMPILE): Define.
	(DPOSTCOMPILE): Define.
	(DLINKER): Define.
	(DLLINKER): Define.
	(D_FRONTEND_OBJS): Add new dmd front-end objects.
	(D_GENERATED_SRCS): Remove.
	(D_GENERATED_OBJS): Remove.
	(D_ALL_OBJS): Remove D_GENERATED_OBJS.
	(d21$(exeext)): Build using DLLINKER and -static-libphobos.
	(d.tags): Remove dmd/*.c and dmd/root/*.c.
	(d.mostlyclean): Remove D_GENERATED_SRCS, d/idgen$(build_exeext),
	d/impcnvgen$(build_exeext).
	(D_INCLUDES): Include $(srcdir)/d/dmd/res.
	(CFLAGS-d/id.o): Remove.
	(CFLAGS-d/impcnvtab.o): Remove.
	(d/%.o): Build using DCOMPILE and DPOSTCOMPILE.  Update dependencies
	from d/dmd/%.c to d/dmd/%.d.
	(d/idgen$(build_exeext)): Remove.
	(d/impcnvgen$(build_exeext)): Remove.
	(d/id.c): Remove.
	(d/id.h): Remove.
	(d/impcnvtab.c): Remove.
	(d/%.dmdgen.o): Remove.
	(D_SYSTEM_H): Remove.
	(d/idgen.dmdgen.o): Remove.
	(d/impcnvgen.dmdgen.o): Remove.
	* config-lang.in (boot_language): New variable.
	* d-attribs.cc: Include dmd/expression.h.
	* d-builtins.cc: Include d-frontend.h.
	(build_frontend_type): Update for new front-end interface.
	(d_eval_constant_expression): Likewise.
	(d_build_builtins_module): Likewise.
	(maybe_set_builtin_1): Likewise.
	(d_build_d_type_nodes): Likewise.
	* d-codegen.cc (d_decl_context): Likewise.
	(declaration_reference_p): Likewise.
	(declaration_type): Likewise.
	(parameter_reference_p): Likewise.
	(parameter_type): Likewise.
	(get_array_length): Likewise.
	(build_delegate_cst): Likewise.
	(build_typeof_null_value): Likewise.
	(identity_compare_p): Likewise.
	(lower_struct_comparison): Likewise.
	(build_filename_from_loc): Likewise.
	(build_assert_call): Remove LIBCALL_SWITCH_ERROR.
	(build_bounds_index_condition): Call LIBCALL_ARRAYBOUNDS_INDEXP on
	bounds error.
	(build_bounds_slice_condition): Call LIBCALL_ARRAYBOUNDS_SLICEP on
	bounds error.
	(array_bounds_check): Update for new front-end interface.
	(checkaction_trap_p): Handle CHECKACTION_context.
	(get_function_type): Update for new front-end interface.
	(d_build_call): Likewise.
	* d-compiler.cc: Remove include of dmd/scope.h.
	(Compiler::genCmain): Remove.
	(Compiler::paintAsType): Update for new front-end interface.
	(Compiler::onParseModule): Likewise.
	* d-convert.cc (convert_expr): Remove call to LIBCALL_ARRAYCAST.
	(convert_for_rvalue): Update for new front-end interface.
	(convert_for_assignment): Likewise.
	(convert_for_condition): Likewise.
	(d_array_convert): Likewise.
	* d-diagnostic.cc (error): Remove.
	(errorSupplemental): Remove.
	(warning): Remove.
	(warningSupplemental): Remove.
	(deprecation): Remove.
	(deprecationSupplemental): Remove.
	(message): Remove.
	(vtip): New.
	* d-frontend.cc (global): Remove.
	(Global::_init): Remove.
	(Global::startGagging): Remove.
	(Global::endGagging): Remove.
	(Global::increaseErrorCount): Remove.
	(Loc::Loc): Remove.
	(Loc::toChars): Remove.
	(Loc::equals): Remove.
	(isBuiltin): Update for new front-end interface.
	(eval_builtin): Likewise.
	(getTypeInfoType): Likewise.
	(inlineCopy): Remove.
	* d-incpath.cc: Include d-frontend.h.
	(add_globalpaths): Call d_gc_malloc to allocate Strings.
	(add_filepaths): Likewise.
	* d-lang.cc: Include dmd/id.h, dmd/root/file.h, d-frontend.h.  Remove
	include of dmd/mars.h, id.h.
	(entrypoint_module): Remove.
	(entrypoint_root_module): Remove.
	(deps_write_string): Update for new front-end interface.
	(deps_write): Likewise.
	(d_init_options): Call rt_init.  Remove setting global params that are
	default initialized by the front-end.
	(d_handle_option): Handle OPT_fcheckaction_, OPT_fdump_c___spec_,
	OPT_fdump_c___spec_verbose, OPT_fextern_std_, OPT_fpreview,
	OPT_revert, OPT_fsave_mixins_, and OPT_ftransition.
	(d_post_options): Propagate dip1021 and dip1000 preview flags to
	dip25, and flag_diagnostics_show_caret to printErrorContext.
	(d_add_entrypoint_module): Remove.
	(d_parse_file): Update for new front-end interface.
	(d_type_promotes_to): Likewise.
	(d_types_compatible_p): Likewise.
	* d-longdouble.cc (CTFloat::zero): Remove.
	(CTFloat::one): Remove.
	(CTFloat::minusone): Remove.
	(CTFloat::half): Remove.
	* d-system.h (POSIX): Remove.
	(realpath): Remove.
	(isalpha): Remove.
	(isalnum): Remove.
	(isdigit): Remove.
	(islower): Remove.
	(isprint): Remove.
	(isspace): Remove.
	(isupper): Remove.
	(isxdigit): Remove.
	(tolower): Remove.
	(_mkdir): Remove.
	(INT32_MAX): Remove.
	(INT32_MIN): Remove.
	(INT64_MIN): Remove.
	(UINT32_MAX): Remove.
	(UINT64_MAX): Remove.
	* d-target.cc: Include calls.h.
	(target): Remove.
	(define_float_constants): Remove initialization of snan.
	(Target::_init): Update for new front-end interface.
	(Target::isVectorTypeSupported): Likewise.
	(Target::isVectorOpSupported): Remove cases for unordered operators.
	(TargetCPP::typeMangle): Update for new front-end interface.
	(TargetCPP::parameterType): Likewise.
	(Target::systemLinkage): Likewise.
	(Target::isReturnOnStack): Likewise.
	(Target::isCalleeDestroyingArgs): Define.
	(Target::preferPassByRef): Define.
	* d-tree.h (d_add_entrypoint_module): Remove.
	* decl.cc (gcc_attribute_p): Update for new front-end interface.
	(apply_pragma_crt): Define.
	(DeclVisitor::visit(PragmaDeclaration *)): Handle pragmas
	crt_constructor and crt_destructor.
	(DeclVisitor::visit(TemplateDeclaration *)): Update for new front-end
	interface.
	(DeclVisitor::visit): Likewise.
	(DeclVisitor::finish_vtable): Likewise.
	(get_symbol_decl): Error if template has more than one nesting
	context.  Update for new front-end interface.
	(make_thunk): Update for new front-end interface.
	(get_vtable_decl): Likewise.
	* expr.cc (ExprVisitor::visit): Likewise.
	(build_return_dtor): Likewise.
	* imports.cc (ImportVisitor::visit): Likewise.
	* intrinsics.cc: Include dmd/expression.h.  Remove include of
	dmd/mangle.h.
	(maybe_set_intrinsic): Update for new front-end interface.
	* intrinsics.def (INTRINSIC_ROL): Update intrinsic signature.
	(INTRINSIC_ROR): Likewise.
	(INTRINSIC_ROR_TIARG): Likewise.
	(INTRINSIC_TOPREC): Likewise.
	(INTRINSIC_TOPRECL): Likewise.
	(INTRINSIC_TAN): Update intrinsic module and signature.
	(INTRINSIC_ISNAN): Likewise.
	(INTRINSIC_ISFINITE): Likewise.
	(INTRINSIC_COPYSIGN): Define intrinsic.
	(INTRINSIC_COPYSIGNI): Define intrinsic.
	(INTRINSIC_EXP): Update intrinsic module.
	(INTRINSIC_EXPM1): Likewise.
	(INTRINSIC_EXP2): Likewise.
	(INTRINSIC_LOG): Likewise.
	(INTRINSIC_LOG2): Likewise.
	(INTRINSIC_LOG10): Likewise.
	(INTRINSIC_POW): Likewise.
	(INTRINSIC_ROUND): Likewise.
	(INTRINSIC_FLOORF): Likewise.
	(INTRINSIC_FLOOR): Likewise.
	(INTRINSIC_FLOORL): Likewise.
	(INTRINSIC_CEILF): Likewise.
	(INTRINSIC_CEIL): Likewise.
	(INTRINSIC_CEILL): Likewise.
	(INTRINSIC_TRUNC): Likewise.
	(INTRINSIC_FMIN): Likewise.
	(INTRINSIC_FMAX): Likewise.
	(INTRINSIC_FMA): Likewise.
	(INTRINSIC_VA_ARG): Update intrinsic signature.
	(INTRINSIC_VASTART): Likewise.
	* lang.opt (fcheck=): Add alternate aliases for contract switches.
	(fcheckaction=): New option.
	(check_action): New Enum and EnumValue entries.
	(fdump-c++-spec-verbose): New option.
	(fdump-c++-spec=): New option.
	(fextern-std=): New option.
	(extern_stdcpp): New Enum and EnumValue entries
	(fpreview=): New options.
	(frevert=): New options.
	(fsave-mixins): New option.
	(ftransition=): Update options.
	* modules.cc (get_internal_fn): Replace Prot with Visibility.
	(build_internal_fn): Likewise.
	(build_dso_cdtor_fn): Likewise.
	(build_module_tree): Remove check for __entrypoint module.
	* runtime.def (P5): Define.
	(ARRAYBOUNDS_SLICEP): Define.
	(ARRAYBOUNDS_INDEXP): Define.
	(NEWTHROW): Define.
	(ADCMP2): Remove.
	(ARRAYCAST): Remove.
	(SWITCH_STRING): Remove.
	(SWITCH_USTRING): Remove.
	(SWITCH_DSTRING): Remove.
	(SWITCH_ERROR): Remove.
	* toir.cc (IRVisitor::visit): Update for new front-end interface.
	(IRVisitor::check_previous_goto): Remove checks for case and default
	statements.
	(IRVisitor::visit(SwitchStatement *)): Remove handling of string
	switch conditions.
	* typeinfo.cc: Include d-frontend.h.
	(get_typeinfo_kind): Update for new front-end interface.
	(make_frontend_typeinfo): Likewise.
	(TypeInfoVisitor::visit): Likewise.
	(builtin_typeinfo_p): Likewise.
	(get_typeinfo_decl): Likewise.
	(build_typeinfo): Likewise.
	* types.cc (valist_array_p): Likewise.
	(make_array_type): Likewise.
	(merge_aggregate_types): Likewise.
	(TypeVisitor::visit(TypeBasic *)): Likewise.
	(TypeVisitor::visit(TypeFunction *)): Likewise.
	(TypeVisitor::visit(TypeStruct *)): Update comment.
	* verstr.h: Removed.
	* d-frontend.h: New file.

gcc/po/ChangeLog:

	* EXCLUDES: Remove d/dmd sources from list.

gcc/testsuite/ChangeLog:

	* gdc.dg/Wcastresult2.d: Update test.
	* gdc.dg/asm1.d: Likewise.
	* gdc.dg/asm2.d: Likewise.
	* gdc.dg/asm3.d: Likewise.
	* gdc.dg/gdc282.d: Likewise.
	* gdc.dg/imports/gdc170.d: Likewise.
	* gdc.dg/intrinsics.d: Likewise.
	* gdc.dg/pr101672.d: Likewise.
	* gdc.dg/pr90650a.d: Likewise.
	* gdc.dg/pr90650b.d: Likewise.
	* gdc.dg/pr94777a.d: Likewise.
	* gdc.dg/pr95250.d: Likewise.
	* gdc.dg/pr96869.d: Likewise.
	* gdc.dg/pr98277.d: Likewise.
	* gdc.dg/pr98457.d: Likewise.
	* gdc.dg/simd1.d: Likewise.
	* gdc.dg/simd2a.d: Likewise.
	* gdc.dg/simd2b.d: Likewise.
	* gdc.dg/simd2c.d: Likewise.
	* gdc.dg/simd2d.d: Likewise.
	* gdc.dg/simd2e.d: Likewise.
	* gdc.dg/simd2f.d: Likewise.
	* gdc.dg/simd2g.d: Likewise.
	* gdc.dg/simd2h.d: Likewise.
	* gdc.dg/simd2i.d: Likewise.
	* gdc.dg/simd2j.d: Likewise.
	* gdc.dg/simd7951.d: Likewise.
	* gdc.dg/torture/gdc309.d: Likewise.
	* gdc.dg/torture/pr94424.d: Likewise.
	* gdc.dg/torture/pr94777b.d: Likewise.
	* lib/gdc-utils.exp (gdc-convert-args): Handle new compiler options.
	(gdc-convert-test): Handle CXXFLAGS, EXTRA_OBJC_SOURCES, and ARG_SETS
	test directives.
	(gdc-do-test): Only import modules in the test run directory.
	* gdc.dg/pr94777c.d: New test.
	* gdc.dg/pr96156b.d: New test.
	* gdc.dg/pr96157c.d: New test.
	* gdc.dg/simd_ctfe.d: New test.
	* gdc.dg/torture/simd17344.d: New test.
	* gdc.dg/torture/simd20052.d: New test.
	* gdc.dg/torture/simd6.d: New test.
	* gdc.dg/torture/simd7.d: New test.

libphobos/ChangeLog:

	* libdruntime/MERGE: Merge upstream druntime e6caaab9.
	* libdruntime/Makefile.am (D_EXTRA_FLAGS): Build libdruntime with
	-fpreview=dip1000, -fpreview=fieldwise, and -fpreview=dtorfields.
	(ALL_DRUNTIME_SOURCES): Add DRUNTIME_DSOURCES_STDCXX.
	(DRUNTIME_DSOURCES): Update list of C binding modules.
	(DRUNTIME_DSOURCES_STDCXX): Likewise.
	(DRUNTIME_DSOURCES_LINUX): Likewise.
	(DRUNTIME_DSOURCES_OPENBSD): Likewise.
	(DRUNTIME_DISOURCES): Remove __entrypoint.di.
	* libdruntime/Makefile.in: Regenerated.
	* libdruntime/__entrypoint.di: Removed.
	* libdruntime/gcc/deh.d (_d_isbaseof): Update signature.
	(_d_createTrace): Likewise.
	(__gdc_begin_catch): Remove reference to the exception.
	(_d_throw): Increment reference count of thrown object before unwind.
	(__gdc_personality): Chain exceptions with  Throwable.chainTogether.
	* libdruntime/gcc/emutls.d: Update imports.
	* libdruntime/gcc/sections/elf.d: Update imports.
	(DSO.moduleGroup): Update signature.
	* libdruntime/gcc/sections/macho.d: Update imports.
	(DSO.moduleGroup): Update signature.
	* libdruntime/gcc/sections/pecoff.d: Update imports.
	(DSO.moduleGroup): Update signature.
	* src/MERGE: Merge upstream phobos 5ab9ad256.
	* src/Makefile.am (D_EXTRA_DFLAGS): Add -fpreview=dip1000 and
	-fpreview=dtorfields flags.
	(PHOBOS_DSOURCES): Update list of std modules.
	* src/Makefile.in: Regenerate.
	* testsuite/lib/libphobos.exp (libphobos-dg-test): Handle assembly
	compile types.
	(dg-test): Override.
	(additional_prunes): Define.
	(libphobos-dg-prune): Filter any additional_prunes set by tests.
	* testsuite/libphobos.aa/test_aa.d: Update test.
	* testsuite/libphobos.druntime/druntime.exp (version_flags): Add
	-fversion=CoreUnittest.
	* testsuite/libphobos.druntime_shared/druntime_shared.exp
	(version_flags): Add -fversion=CoreUnittest -fversion=Shared.
	* testsuite/libphobos.exceptions/unknown_gc.d: Update test.
	* testsuite/libphobos.hash/test_hash.d: Update test.
	* testsuite/libphobos.phobos/phobos.exp (version_flags): Add
	-fversion=StdUnittest
	* testsuite/libphobos.phobos_shared/phobos_shared.exp (version_flags):
	Likewise.
	* testsuite/libphobos.shared/host.c: Update test.
	* testsuite/libphobos.shared/load.d: Update test.
	* testsuite/libphobos.shared/load_13414.d: Update test.
	* testsuite/libphobos.thread/fiber_guard_page.d: Update test.
	* testsuite/libphobos.thread/tlsgc_sections.d: Update test.
	* testsuite/testsuite_flags.in: Add -fpreview=dip1000 to --gdcflags.
	* testsuite/libphobos.shared/link_mod_collision.d: Removed.
	* testsuite/libphobos.shared/load_mod_collision.d: Removed.
	* testsuite/libphobos.betterc/betterc.exp: New test.
	* testsuite/libphobos.config/config.exp: New test.
	* testsuite/libphobos.gc/gc.exp: New test.
	* testsuite/libphobos.imports/imports.exp: New test.
	* testsuite/libphobos.lifetime/lifetime.exp: New test.
	* testsuite/libphobos.unittest/unittest.exp: New test.

1 files changed, 537 insertions, 0 deletions

diff --git a/gcc/d/dmd/blockexit.d b/gcc/d/dmd/blockexit.d
new file mode 100644
index 00000000000..1fd90051830
--- /dev/null
+++ b/gcc/d/dmd/blockexit.d
@@ -0,0 +1,537 @@
+/**
+ * Find out in what ways control flow can exit a statement block.
+ *
+ * Copyright:   Copyright (C) 1999-2021 by The D Language Foundation, All Rights Reserved
+ * Authors:     $(LINK2 http://www.digitalmars.com, Walter Bright)
+ * License:     $(LINK2 http://www.boost.org/LICENSE_1_0.txt, Boost License 1.0)
+ * Source:      $(LINK2 https://github.com/dlang/dmd/blob/master/src/dmd/blockexit.d, _blockexit.d)
+ * Documentation:  https://dlang.org/phobos/dmd_blockexit.html
+ * Coverage:    https://codecov.io/gh/dlang/dmd/src/master/src/dmd/blockexit.d
+ */
+
+module dmd.blockexit;
+
+import core.stdc.stdio;
+
+import dmd.arraytypes;
+import dmd.astenums;
+import dmd.canthrow;
+import dmd.dclass;
+import dmd.declaration;
+import dmd.expression;
+import dmd.func;
+import dmd.globals;
+import dmd.id;
+import dmd.identifier;
+import dmd.mtype;
+import dmd.statement;
+import dmd.tokens;
+import dmd.visitor;
+
+/**
+ * BE stands for BlockExit.
+ *
+ * It indicates if a statement does transfer control to another block.
+ * A block is a sequence of statements enclosed in { }
+ */
+enum BE : int
+{
+    none      = 0,
+    fallthru  = 1,
+    throw_    = 2,
+    return_   = 4,
+    goto_     = 8,
+    halt      = 0x10,
+    break_    = 0x20,
+    continue_ = 0x40,
+    errthrow  = 0x80,
+    any       = (fallthru | throw_ | return_ | goto_ | halt),
+}
+
+
+/*********************************************
+ * Determine mask of ways that a statement can exit.
+ *
+ * Only valid after semantic analysis.
+ * Params:
+ *   s = statement to check for block exit status
+ *   func = function that statement s is in
+ *   mustNotThrow = generate an error if it throws
+ * Returns:
+ *   BE.xxxx
+ */
+int blockExit(Statement s, FuncDeclaration func, bool mustNotThrow)
+{
+    extern (C++) final class BlockExit : Visitor
+    {
+        alias visit = Visitor.visit;
+    public:
+        FuncDeclaration func;
+        bool mustNotThrow;
+        int result;
+
+        extern (D) this(FuncDeclaration func, bool mustNotThrow)
+        {
+            this.func = func;
+            this.mustNotThrow = mustNotThrow;
+            result = BE.none;
+        }
+
+        override void visit(Statement s)
+        {
+            printf("Statement::blockExit(%p)\n", s);
+            printf("%s\n", s.toChars());
+            assert(0);
+        }
+
+        override void visit(ErrorStatement s)
+        {
+            result = BE.none;
+        }
+
+        override void visit(ExpStatement s)
+        {
+            result = BE.fallthru;
+            if (s.exp)
+            {
+                if (s.exp.op == TOK.halt)
+                {
+                    result = BE.halt;
+                    return;
+                }
+                if (s.exp.op == TOK.assert_)
+                {
+                    AssertExp a = cast(AssertExp)s.exp;
+                    if (a.e1.isBool(false)) // if it's an assert(0)
+                    {
+                        result = BE.halt;
+                        return;
+                    }
+                }
+                if (s.exp.type.toBasetype().isTypeNoreturn())
+                    result = BE.halt;
+                if (canThrow(s.exp, func, mustNotThrow))
+                    result |= BE.throw_;
+            }
+        }
+
+        override void visit(CompileStatement s)
+        {
+            assert(global.errors);
+            result = BE.fallthru;
+        }
+
+        override void visit(CompoundStatement cs)
+        {
+            //printf("CompoundStatement.blockExit(%p) %d result = x%X\n", cs, cs.statements.dim, result);
+            result = BE.fallthru;
+            Statement slast = null;
+            foreach (s; *cs.statements)
+            {
+                if (s)
+                {
+                    //printf("result = x%x\n", result);
+                    //printf("s: %s\n", s.toChars());
+                    if (result & BE.fallthru && slast)
+                    {
+                        slast = slast.last();
+                        if (slast && (slast.isCaseStatement() || slast.isDefaultStatement()) && (s.isCaseStatement() || s.isDefaultStatement()))
+                        {
+                            // Allow if last case/default was empty
+                            CaseStatement sc = slast.isCaseStatement();
+                            DefaultStatement sd = slast.isDefaultStatement();
+                            if (sc && (!sc.statement.hasCode() || sc.statement.isCaseStatement() || sc.statement.isErrorStatement()))
+                            {
+                            }
+                            else if (sd && (!sd.statement.hasCode() || sd.statement.isCaseStatement() || sd.statement.isErrorStatement()))
+                            {
+                            }
+                            else
+                            {
+                                const(char)* gototype = s.isCaseStatement() ? "case" : "default";
+                                s.deprecation("switch case fallthrough - use 'goto %s;' if intended", gototype);
+                            }
+                        }
+                    }
+
+                    if (!(result & BE.fallthru) && !s.comeFrom())
+                    {
+                        if (blockExit(s, func, mustNotThrow) != BE.halt && s.hasCode() &&
+                            s.loc != Loc.initial) // don't emit warning for generated code
+                            s.warning("statement is not reachable");
+                    }
+                    else
+                    {
+                        result &= ~BE.fallthru;
+                        result |= blockExit(s, func, mustNotThrow);
+                    }
+                    slast = s;
+                }
+            }
+        }
+
+        override void visit(UnrolledLoopStatement uls)
+        {
+            result = BE.fallthru;
+            foreach (s; *uls.statements)
+            {
+                if (s)
+                {
+                    int r = blockExit(s, func, mustNotThrow);
+                    result |= r & ~(BE.break_ | BE.continue_ | BE.fallthru);
+                    if ((r & (BE.fallthru | BE.continue_ | BE.break_)) == 0)
+                        result &= ~BE.fallthru;
+                }
+            }
+        }
+
+        override void visit(ScopeStatement s)
+        {
+            //printf("ScopeStatement::blockExit(%p)\n", s.statement);
+            result = blockExit(s.statement, func, mustNotThrow);
+        }
+
+        override void visit(WhileStatement s)
+        {
+            assert(global.errors);
+            result = BE.fallthru;
+        }
+
+        override void visit(DoStatement s)
+        {
+            if (s._body)
+            {
+                result = blockExit(s._body, func, mustNotThrow);
+                if (result == BE.break_)
+                {
+                    result = BE.fallthru;
+                    return;
+                }
+                if (result & BE.continue_)
+                    result |= BE.fallthru;
+            }
+            else
+                result = BE.fallthru;
+            if (result & BE.fallthru)
+            {
+                if (canThrow(s.condition, func, mustNotThrow))
+                    result |= BE.throw_;
+                if (!(result & BE.break_) && s.condition.isBool(true))
+                    result &= ~BE.fallthru;
+            }
+            result &= ~(BE.break_ | BE.continue_);
+        }
+
+        override void visit(ForStatement s)
+        {
+            result = BE.fallthru;
+            if (s._init)
+            {
+                result = blockExit(s._init, func, mustNotThrow);
+                if (!(result & BE.fallthru))
+                    return;
+            }
+            if (s.condition)
+            {
+                if (canThrow(s.condition, func, mustNotThrow))
+                    result |= BE.throw_;
+                if (s.condition.isBool(true))
+                    result &= ~BE.fallthru;
+                else if (s.condition.isBool(false))
+                    return;
+            }
+            else
+                result &= ~BE.fallthru; // the body must do the exiting
+            if (s._body)
+            {
+                int r = blockExit(s._body, func, mustNotThrow);
+                if (r & (BE.break_ | BE.goto_))
+                    result |= BE.fallthru;
+                result |= r & ~(BE.fallthru | BE.break_ | BE.continue_);
+            }
+            if (s.increment && canThrow(s.increment, func, mustNotThrow))
+                result |= BE.throw_;
+        }
+
+        override void visit(ForeachStatement s)
+        {
+            result = BE.fallthru;
+            if (canThrow(s.aggr, func, mustNotThrow))
+                result |= BE.throw_;
+            if (s._body)
+                result |= blockExit(s._body, func, mustNotThrow) & ~(BE.break_ | BE.continue_);
+        }
+
+        override void visit(ForeachRangeStatement s)
+        {
+            assert(global.errors);
+            result = BE.fallthru;
+        }
+
+        override void visit(IfStatement s)
+        {
+            //printf("IfStatement::blockExit(%p)\n", s);
+            result = BE.none;
+            if (canThrow(s.condition, func, mustNotThrow))
+                result |= BE.throw_;
+            if (s.condition.isBool(true))
+            {
+                result |= blockExit(s.ifbody, func, mustNotThrow);
+            }
+            else if (s.condition.isBool(false))
+            {
+                result |= blockExit(s.elsebody, func, mustNotThrow);
+            }
+            else
+            {
+                result |= blockExit(s.ifbody, func, mustNotThrow);
+                result |= blockExit(s.elsebody, func, mustNotThrow);
+            }
+            //printf("IfStatement::blockExit(%p) = x%x\n", s, result);
+        }
+
+        override void visit(ConditionalStatement s)
+        {
+            result = blockExit(s.ifbody, func, mustNotThrow);
+            if (s.elsebody)
+                result |= blockExit(s.elsebody, func, mustNotThrow);
+        }
+
+        override void visit(PragmaStatement s)
+        {
+            result = BE.fallthru;
+        }
+
+        override void visit(StaticAssertStatement s)
+        {
+            result = BE.fallthru;
+        }
+
+        override void visit(SwitchStatement s)
+        {
+            result = BE.none;
+            if (canThrow(s.condition, func, mustNotThrow))
+                result |= BE.throw_;
+            if (s._body)
+            {
+                result |= blockExit(s._body, func, mustNotThrow);
+                if (result & BE.break_)
+                {
+                    result |= BE.fallthru;
+                    result &= ~BE.break_;
+                }
+            }
+            else
+                result |= BE.fallthru;
+        }
+
+        override void visit(CaseStatement s)
+        {
+            result = blockExit(s.statement, func, mustNotThrow);
+        }
+
+        override void visit(DefaultStatement s)
+        {
+            result = blockExit(s.statement, func, mustNotThrow);
+        }
+
+        override void visit(GotoDefaultStatement s)
+        {
+            result = BE.goto_;
+        }
+
+        override void visit(GotoCaseStatement s)
+        {
+            result = BE.goto_;
+        }
+
+        override void visit(SwitchErrorStatement s)
+        {
+            // Switch errors are non-recoverable
+            result = BE.halt;
+        }
+
+        override void visit(ReturnStatement s)
+        {
+            result = BE.return_;
+            if (s.exp && canThrow(s.exp, func, mustNotThrow))
+                result |= BE.throw_;
+        }
+
+        override void visit(BreakStatement s)
+        {
+            //printf("BreakStatement::blockExit(%p) = x%x\n", s, s.ident ? BE.goto_ : BE.break_);
+            result = s.ident ? BE.goto_ : BE.break_;
+        }
+
+        override void visit(ContinueStatement s)
+        {
+            result = s.ident ? BE.continue_ | BE.goto_ : BE.continue_;
+        }
+
+        override void visit(SynchronizedStatement s)
+        {
+            result = blockExit(s._body, func, mustNotThrow);
+        }
+
+        override void visit(WithStatement s)
+        {
+            result = BE.none;
+            if (canThrow(s.exp, func, mustNotThrow))
+                result = BE.throw_;
+            result |= blockExit(s._body, func, mustNotThrow);
+        }
+
+        override void visit(TryCatchStatement s)
+        {
+            assert(s._body);
+            result = blockExit(s._body, func, false);
+
+            int catchresult = 0;
+            foreach (c; *s.catches)
+            {
+                if (c.type == Type.terror)
+                    continue;
+
+                int cresult = blockExit(c.handler, func, mustNotThrow);
+
+                /* If we're catching Object, then there is no throwing
+                 */
+                Identifier id = c.type.toBasetype().isClassHandle().ident;
+                if (c.internalCatch && (cresult & BE.fallthru))
+                {
+                    // https://issues.dlang.org/show_bug.cgi?id=11542
+                    // leave blockExit flags of the body
+                    cresult &= ~BE.fallthru;
+                }
+                else if (id == Id.Object || id == Id.Throwable)
+                {
+                    result &= ~(BE.throw_ | BE.errthrow);
+                }
+                else if (id == Id.Exception)
+                {
+                    result &= ~BE.throw_;
+                }
+                catchresult |= cresult;
+            }
+            if (mustNotThrow && (result & BE.throw_))
+            {
+                // now explain why this is nothrow
+                blockExit(s._body, func, mustNotThrow);
+            }
+            result |= catchresult;
+        }
+
+        override void visit(TryFinallyStatement s)
+        {
+            result = BE.fallthru;
+            if (s._body)
+                result = blockExit(s._body, func, false);
+
+            // check finally body as well, it may throw (bug #4082)
+            int finalresult = BE.fallthru;
+            if (s.finalbody)
+                finalresult = blockExit(s.finalbody, func, false);
+
+            // If either body or finalbody halts
+            if (result == BE.halt)
+                finalresult = BE.none;
+            if (finalresult == BE.halt)
+                result = BE.none;
+
+            if (mustNotThrow)
+            {
+                // now explain why this is nothrow
+                if (s._body && (result & BE.throw_))
+                    blockExit(s._body, func, mustNotThrow);
+                if (s.finalbody && (finalresult & BE.throw_))
+                    blockExit(s.finalbody, func, mustNotThrow);
+            }
+
+            version (none)
+            {
+                // https://issues.dlang.org/show_bug.cgi?id=13201
+                // Mask to prevent spurious warnings for
+                // destructor call, exit of synchronized statement, etc.
+                if (result == BE.halt && finalresult != BE.halt && s.finalbody && s.finalbody.hasCode())
+                {
+                    s.finalbody.warning("statement is not reachable");
+                }
+            }
+
+            if (!(finalresult & BE.fallthru))
+                result &= ~BE.fallthru;
+            result |= finalresult & ~BE.fallthru;
+        }
+
+        override void visit(ScopeGuardStatement s)
+        {
+            // At this point, this statement is just an empty placeholder
+            result = BE.fallthru;
+        }
+
+        override void visit(ThrowStatement s)
+        {
+            if (s.internalThrow)
+            {
+                // https://issues.dlang.org/show_bug.cgi?id=8675
+                // Allow throwing 'Throwable' object even if mustNotThrow.
+                result = BE.fallthru;
+                return;
+            }
+
+            Type t = s.exp.type.toBasetype();
+            ClassDeclaration cd = t.isClassHandle();
+            assert(cd);
+
+            if (cd == ClassDeclaration.errorException || ClassDeclaration.errorException.isBaseOf(cd, null))
+            {
+                result = BE.errthrow;
+                return;
+            }
+            if (mustNotThrow)
+                s.error("`%s` is thrown but not caught", s.exp.type.toChars());
+
+            result = BE.throw_;
+        }
+
+        override void visit(GotoStatement s)
+        {
+            //printf("GotoStatement::blockExit(%p)\n", s);
+            result = BE.goto_;
+        }
+
+        override void visit(LabelStatement s)
+        {
+            //printf("LabelStatement::blockExit(%p)\n", s);
+            result = blockExit(s.statement, func, mustNotThrow);
+            if (s.breaks)
+                result |= BE.fallthru;
+        }
+
+        override void visit(CompoundAsmStatement s)
+        {
+            // Assume the worst
+            result = BE.fallthru | BE.return_ | BE.goto_ | BE.halt;
+            if (!(s.stc & STC.nothrow_))
+            {
+                if (mustNotThrow && !(s.stc & STC.nothrow_))
+                    s.deprecation("`asm` statement is assumed to throw - mark it with `nothrow` if it does not");
+                else
+                    result |= BE.throw_;
+            }
+        }
+
+        override void visit(ImportStatement s)
+        {
+            result = BE.fallthru;
+        }
+    }
+
+    if (!s)
+        return BE.fallthru;
+    scope BlockExit be = new BlockExit(func, mustNotThrow);
+    s.accept(be);
+    return be.result;
+}
+