1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
|
------------------------------------------------------------------------------
-- --
-- GNAT RUN-TIME COMPONENTS --
-- --
-- S Y S T E M . E X N _ L L F --
-- --
-- B o d y --
-- --
-- Copyright (C) 1992-2015, Free Software Foundation, Inc. --
-- --
-- GNAT is free software; you can redistribute it and/or modify it under --
-- terms of the GNU General Public License as published by the Free Soft- --
-- ware Foundation; either version 3, or (at your option) any later ver- --
-- sion. GNAT is distributed in the hope that it will be useful, but WITH- --
-- OUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY --
-- or FITNESS FOR A PARTICULAR PURPOSE. --
-- --
-- As a special exception under Section 7 of GPL version 3, you are granted --
-- additional permissions described in the GCC Runtime Library Exception, --
-- version 3.1, as published by the Free Software Foundation. --
-- --
-- You should have received a copy of the GNU General Public License and --
-- a copy of the GCC Runtime Library Exception along with this program; --
-- see the files COPYING3 and COPYING.RUNTIME respectively. If not, see --
-- <http://www.gnu.org/licenses/>. --
-- --
-- GNAT was originally developed by the GNAT team at New York University. --
-- Extensive contributions were provided by Ada Core Technologies Inc. --
-- --
------------------------------------------------------------------------------
-- Note: the reason for treating exponents in the range 0 .. 4 specially is
-- to ensure identical results to the static inline expansion in the case of
-- a compile time known exponent in this range. The use of Float'Machine and
-- Long_Float'Machine is to avoid unwanted extra precision in the results.
package body System.Exn_LLF is
function Exp
(Left : Long_Long_Float;
Right : Integer) return Long_Long_Float;
-- Common routine used if Right not in 0 .. 4
---------------
-- Exn_Float --
---------------
function Exn_Float
(Left : Float;
Right : Integer) return Float
is
Temp : Float;
begin
case Right is
when 0 =>
return 1.0;
when 1 =>
return Left;
when 2 =>
return Float'Machine (Left * Left);
when 3 =>
return Float'Machine (Left * Left * Left);
when 4 =>
Temp := Float'Machine (Left * Left);
return Float'Machine (Temp * Temp);
when others =>
return
Float'Machine
(Float (Exp (Long_Long_Float (Left), Right)));
end case;
end Exn_Float;
--------------------
-- Exn_Long_Float --
--------------------
function Exn_Long_Float
(Left : Long_Float;
Right : Integer) return Long_Float
is
Temp : Long_Float;
begin
case Right is
when 0 =>
return 1.0;
when 1 =>
return Left;
when 2 =>
return Long_Float'Machine (Left * Left);
when 3 =>
return Long_Float'Machine (Left * Left * Left);
when 4 =>
Temp := Long_Float'Machine (Left * Left);
return Long_Float'Machine (Temp * Temp);
when others =>
return
Long_Float'Machine
(Long_Float (Exp (Long_Long_Float (Left), Right)));
end case;
end Exn_Long_Float;
-------------------------
-- Exn_Long_Long_Float --
-------------------------
function Exn_Long_Long_Float
(Left : Long_Long_Float;
Right : Integer) return Long_Long_Float
is
Temp : Long_Long_Float;
begin
case Right is
when 0 =>
return 1.0;
when 1 =>
return Left;
when 2 =>
return Left * Left;
when 3 =>
return Left * Left * Left;
when 4 =>
Temp := Left * Left;
return Temp * Temp;
when others =>
return Exp (Left, Right);
end case;
end Exn_Long_Long_Float;
---------
-- Exp --
---------
function Exp
(Left : Long_Long_Float;
Right : Integer) return Long_Long_Float
is
Result : Long_Long_Float := 1.0;
Factor : Long_Long_Float := Left;
Exp : Integer := Right;
begin
-- We use the standard logarithmic approach, Exp gets shifted right
-- testing successive low order bits and Factor is the value of the
-- base raised to the next power of 2. If the low order bit or Exp is
-- set, multiply the result by this factor. For negative exponents,
-- invert result upon return.
if Exp >= 0 then
loop
if Exp rem 2 /= 0 then
Result := Result * Factor;
end if;
Exp := Exp / 2;
exit when Exp = 0;
Factor := Factor * Factor;
end loop;
return Result;
-- Here we have a negative exponent, and we compute the result as:
-- 1.0 / (Left ** (-Right))
-- Note that the case of Left being zero is not special, it will
-- simply result in a division by zero at the end, yielding a
-- correctly signed infinity, or possibly generating an overflow.
-- Note on overflow: The coding of this routine assumes that the
-- target generates infinities with standard IEEE semantics. If this
-- is not the case, then the code below may raise Constraint_Error.
-- This follows the implementation permission given in RM 4.5.6(12).
else
begin
loop
if Exp rem 2 /= 0 then
Result := Result * Factor;
end if;
Exp := Exp / 2;
exit when Exp = 0;
Factor := Factor * Factor;
end loop;
return 1.0 / Result;
end;
end if;
end Exp;
end System.Exn_LLF;
|
