data: switch gdm.service.in to use cmake format

We're going to be switching to meson, and meson doesn't
deal too well with an @ in the configuration file that's not
part of a substitution variable.

This commit switches the gdm service over to use a cmake style
of substitution variables, so we can later tell meson to use
configure in cmake mode and workaround the @ confusion.

1 files changed, 43 insertions, 0 deletions

diff --git a/common/meson.build b/common/meson.build
new file mode 100644
index 00000000..074dd92e
--- /dev/null
+++ b/common/meson.build
@@ -0,0 +1,43 @@
+libgdmcommon_src = files(
+  'gdm-address.c',
+  'gdm-common.c',
+  'gdm-log.c',
+  'gdm-profile.c',
+  'gdm-settings-backend.c',
+  'gdm-settings-desktop-backend.c',
+  'gdm-settings-direct.c',
+  'gdm-settings-utils.c',
+  'gdm-settings.c',
+)
+
+libgdmcommon_deps = [
+  libsystemd_dep,
+  gobject_dep,
+  gio_dep,
+  gio_unix_dep,
+]
+
+if libselinux_dep.found()
+  libgdmcommon_deps += libselinux_dep
+endif
+
+libgdmcommon_lib = static_library('gdmcommon',
+  libgdmcommon_src,
+  dependencies: libgdmcommon_deps,
+  include_directories: config_h_dir,
+)
+
+libgdmcommon_dep = declare_dependency(
+  link_with: libgdmcommon_lib,
+  dependencies: libgdmcommon_deps,
+  include_directories: include_directories('.'),
+)
+
+install_data('gdb-cmd')
+
+# test-log exectuable
+test_log = executable('test-log',
+  'test-log.c',
+  dependencies: libgdmcommon_dep,
+  include_directories: config_h_dir,
+)