1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
|
dnl AMD64 logops.
dnl Copyright 2004, 2005, 2006, 2011, 2012 Free Software Foundation, Inc.
dnl This file is part of the GNU MP Library.
dnl The GNU MP Library is free software; you can redistribute it and/or modify
dnl it under the terms of the GNU Lesser General Public License as published
dnl by the Free Software Foundation; either version 3 of the License, or (at
dnl your option) any later version.
dnl The GNU MP Library is distributed in the hope that it will be useful, but
dnl WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
dnl or FITNESS FOR A PARTICULAR PURPOSE. See the GNU Lesser General Public
dnl License for more details.
dnl You should have received a copy of the GNU Lesser General Public License
dnl along with the GNU MP Library. If not, see http://www.gnu.org/licenses/.
include(`../config.m4')
C cycles/limb
C AMD K8,K9 1.5 with fluctuations for variant 2 and 3
C AMD K10 1.5 with fluctuations for all variants
C Intel P4 2.8/3.35/3.60 (variant1/variant2/variant3)
C Intel core2 2
C Intel NHM 2
C Intel SBR 1.5/1.75/1.75
C Intel atom 3.75
C VIA nano 3.25
ifdef(`OPERATION_and_n',`
define(`func',`mpn_and_n')
define(`VARIANT_1')
define(`LOGOP',`andq')')
ifdef(`OPERATION_andn_n',`
define(`func',`mpn_andn_n')
define(`VARIANT_2')
define(`LOGOP',`andq')')
ifdef(`OPERATION_nand_n',`
define(`func',`mpn_nand_n')
define(`VARIANT_3')
define(`LOGOP',`andq')')
ifdef(`OPERATION_ior_n',`
define(`func',`mpn_ior_n')
define(`VARIANT_1')
define(`LOGOP',`orq')')
ifdef(`OPERATION_iorn_n',`
define(`func',`mpn_iorn_n')
define(`VARIANT_2')
define(`LOGOP',`orq')')
ifdef(`OPERATION_nior_n',`
define(`func',`mpn_nior_n')
define(`VARIANT_3')
define(`LOGOP',`orq')')
ifdef(`OPERATION_xor_n',`
define(`func',`mpn_xor_n')
define(`VARIANT_1')
define(`LOGOP',`xorq')')
ifdef(`OPERATION_xnor_n',`
define(`func',`mpn_xnor_n')
define(`VARIANT_2')
define(`LOGOP',`xorq')')
MULFUNC_PROLOGUE(mpn_and_n mpn_andn_n mpn_nand_n mpn_ior_n mpn_iorn_n mpn_nior_n mpn_xor_n mpn_xnor_n)
C INPUT PARAMETERS
define(`rp',`%rdi')
define(`up',`%rsi')
define(`vp',`%rdx')
define(`n',`%rcx')
ABI_SUPPORT(DOS64)
ABI_SUPPORT(STD64)
ASM_START()
ifdef(`VARIANT_1',`
TEXT
ALIGN(32)
PROLOGUE(func)
FUNC_ENTRY(4)
movq (vp), %r8
movl R32(%rcx), R32(%rax)
leaq (vp,n,8), vp
leaq (up,n,8), up
leaq (rp,n,8), rp
negq n
andl $3, R32(%rax)
je L(b00)
cmpl $2, R32(%rax)
jc L(b01)
je L(b10)
L(b11): LOGOP (up,n,8), %r8
movq %r8, (rp,n,8)
decq n
jmp L(e11)
L(b10): addq $-2, n
jmp L(e10)
L(b01): LOGOP (up,n,8), %r8
movq %r8, (rp,n,8)
incq n
jz L(ret)
L(oop): movq (vp,n,8), %r8
L(b00): movq 8(vp,n,8), %r9
LOGOP (up,n,8), %r8
LOGOP 8(up,n,8), %r9
nop
movq %r8, (rp,n,8)
movq %r9, 8(rp,n,8)
L(e11): movq 16(vp,n,8), %r8
L(e10): movq 24(vp,n,8), %r9
LOGOP 16(up,n,8), %r8
LOGOP 24(up,n,8), %r9
movq %r8, 16(rp,n,8)
movq %r9, 24(rp,n,8)
addq $4, n
jnc L(oop)
L(ret): FUNC_EXIT()
ret
EPILOGUE()
')
ifdef(`VARIANT_2',`
TEXT
ALIGN(32)
PROLOGUE(func)
FUNC_ENTRY(4)
movq (vp), %r8
notq %r8
movl R32(%rcx), R32(%rax)
leaq (vp,n,8), vp
leaq (up,n,8), up
leaq (rp,n,8), rp
negq n
andl $3, R32(%rax)
je L(b00)
cmpl $2, R32(%rax)
jc L(b01)
je L(b10)
L(b11): LOGOP (up,n,8), %r8
movq %r8, (rp,n,8)
decq n
jmp L(e11)
L(b10): addq $-2, n
jmp L(e10)
.byte 0x90,0x90,0x90,0x90,0x90,0x90,0x90,0x90,0x90,0x90,0x90,0x90,0x90
L(b01): LOGOP (up,n,8), %r8
movq %r8, (rp,n,8)
incq n
jz L(ret)
L(oop): movq (vp,n,8), %r8
notq %r8
L(b00): movq 8(vp,n,8), %r9
notq %r9
LOGOP (up,n,8), %r8
LOGOP 8(up,n,8), %r9
movq %r8, (rp,n,8)
movq %r9, 8(rp,n,8)
L(e11): movq 16(vp,n,8), %r8
notq %r8
L(e10): movq 24(vp,n,8), %r9
notq %r9
LOGOP 16(up,n,8), %r8
LOGOP 24(up,n,8), %r9
movq %r8, 16(rp,n,8)
movq %r9, 24(rp,n,8)
addq $4, n
jnc L(oop)
L(ret): FUNC_EXIT()
ret
EPILOGUE()
')
ifdef(`VARIANT_3',`
TEXT
ALIGN(32)
PROLOGUE(func)
FUNC_ENTRY(4)
movq (vp), %r8
movl R32(%rcx), R32(%rax)
leaq (vp,n,8), vp
leaq (up,n,8), up
leaq (rp,n,8), rp
negq n
andl $3, R32(%rax)
je L(b00)
cmpl $2, R32(%rax)
jc L(b01)
je L(b10)
L(b11): LOGOP (up,n,8), %r8
notq %r8
movq %r8, (rp,n,8)
decq n
jmp L(e11)
L(b10): addq $-2, n
jmp L(e10)
.byte 0x90,0x90,0x90,0x90,0x90,0x90,0x90,0x90,0x90,0x90
L(b01): LOGOP (up,n,8), %r8
notq %r8
movq %r8, (rp,n,8)
incq n
jz L(ret)
L(oop): movq (vp,n,8), %r8
L(b00): movq 8(vp,n,8), %r9
LOGOP (up,n,8), %r8
notq %r8
LOGOP 8(up,n,8), %r9
notq %r9
movq %r8, (rp,n,8)
movq %r9, 8(rp,n,8)
L(e11): movq 16(vp,n,8), %r8
L(e10): movq 24(vp,n,8), %r9
LOGOP 16(up,n,8), %r8
notq %r8
LOGOP 24(up,n,8), %r9
notq %r9
movq %r8, 16(rp,n,8)
movq %r9, 24(rp,n,8)
addq $4, n
jnc L(oop)
L(ret): FUNC_EXIT()
ret
EPILOGUE()
')
|
