blob: 0b2891df9f15f0ce92f4b38eeb927a1b7781951c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
|
<?xml version='1.0' encoding='UTF-8'?><!-- -*- indent-tabs-mode: nil -*- -->
<!--
This program is free software; you can redistribute it and/or modify it under
the terms of the GNU Lesser General Public License as published by the Free
Software Foundation; either version 2 of the License, or (at your option) any
later version.
This program is distributed in the hope that it will be useful, but WITHOUT
ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS
FOR A PARTICULAR PURPOSE. See the GNU Lesser General Public License for more
details.
You should have received a copy of the GNU Lesser General Public License
along with this program; see the file COPYING.LGPL. If not, see <http://www.gnu.org/licenses/>.
-->
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:mal="http://projectmallard.org/1.0/"
xmlns="http://www.w3.org/1999/xhtml"
version="1.0">
<!--!!==========================================================================
Mallard to HTML - Media Elements
REMARK: Describe this module
-->
<!--**==========================================================================
mal2html.media.image
FIXME
FIXME
-->
<xsl:template name="mal2html.media.image">
<xsl:param name="node" select="."/>
<xsl:param name="inline" select="false()"/>
<img src="{$node/@src}">
<xsl:copy-of select="@height"/>
<xsl:copy-of select="@width"/>
<xsl:attribute name="alt">
<xsl:choose>
<xsl:when test="$inline">
<xsl:value-of select="$node"/>
</xsl:when>
<xsl:otherwise>
<!-- FIXME: This is not ideal. Nested block container elements
will introduce lots of garbage whitespace. But then, XML
processors are supposed to normalize whitespace in attribute
values anyway. Ideally, we'd have a set of modes for text
conversion. That'd probably be best handled in a set of
mal2text stylesheets.
-->
<xsl:for-each select="$node/mal:*">
<xsl:if test="position() > 1">
<xsl:text>
</xsl:text>
</xsl:if>
<xsl:value-of select="string(.)"/>
</xsl:for-each>
</xsl:otherwise>
</xsl:choose>
</xsl:attribute>
</img>
</xsl:template>
<!--**==========================================================================
mal2html.media.video
FIXME
FIXME
-->
<xsl:template name="mal2html.media.video">
<xsl:param name="node" select="."/>
<xsl:param name="inline" select="false()"/>
<video src="{$node/@src}" autobuffer="autobuffer" controls="controls">
<xsl:copy-of select="$node/@height"/>
<xsl:copy-of select="$node/@width"/>
<xsl:choose>
<xsl:when test="$inline">
<xsl:apply-templates mode="mal2html.inline.mode" select="$node/node()"/>
</xsl:when>
<xsl:otherwise>
<xsl:apply-templates mode="mal2html.block.mode" select="$node/node()"/>
</xsl:otherwise>
</xsl:choose>
</video>
</xsl:template>
<!--**==========================================================================
mal2html.media.audio
FIXME
FIXME
-->
<xsl:template name="mal2html.media.audio">
<xsl:param name="node" select="."/>
<xsl:param name="inline" select="false()"/>
<audio src="{$node/@src}" autobuffer="autobuffer" controls="controls">
<xsl:choose>
<xsl:when test="$inline">
<xsl:apply-templates mode="mal2html.inline.mode" select="$node/node()"/>
</xsl:when>
<xsl:otherwise>
<xsl:apply-templates mode="mal2html.block.mode" select="$node/node()"/>
</xsl:otherwise>
</xsl:choose>
</audio>
</xsl:template>
<!-- == Matched Templates == -->
<!-- = mal2html.block.mode % media = -->
<xsl:template mode="mal2html.block.mode" match="mal:media">
<xsl:param name="first_child" select="not(preceding-sibling::*)"/>
<xsl:choose>
<xsl:when test="@type = 'image'">
<div>
<xsl:attribute name="class">
<xsl:text>media media-image</xsl:text>
<xsl:if test="$first_child">
<xsl:text> first-child</xsl:text>
</xsl:if>
</xsl:attribute>
<xsl:call-template name="mal2html.media.image"/>
</div>
</xsl:when>
<xsl:when test="@type = 'video'">
<div>
<xsl:attribute name="class">
<xsl:text>media media-video</xsl:text>
<xsl:if test="$first_child">
<xsl:text> first-child</xsl:text>
</xsl:if>
</xsl:attribute>
<xsl:call-template name="mal2html.media.video"/>
</div>
</xsl:when>
<xsl:when test="@type = 'audio'">
<div>
<xsl:attribute name="class">
<xsl:text>media media-audio</xsl:text>
<xsl:if test="$first_child">
<xsl:text> first-child</xsl:text>
</xsl:if>
</xsl:attribute>
<xsl:call-template name="mal2html.media.audio"/>
</div>
</xsl:when>
<xsl:otherwise>
<xsl:for-each select="mal:*">
<xsl:apply-templates mode="mal2html.block.mode" select=".">
<xsl:with-param name="first_child" select="position() = 1 and $first_child"/>
</xsl:apply-templates>
</xsl:for-each>
</xsl:otherwise>
</xsl:choose>
</xsl:template>
<!-- = mal2html.inline.mode % media = -->
<xsl:template mode="mal2html.inline.mode" match="mal:media">
<xsl:choose>
<xsl:when test="@type = 'image'">
<span class="media media-image">
<xsl:call-template name="mal2html.media.image">
<xsl:with-param name="inline" select="true()"/>
</xsl:call-template>
</span>
</xsl:when>
<xsl:when test="@type = 'video'">
<span class="media media-video">
<xsl:call-template name="mal2html.media.video">
<xsl:with-param name="inline" select="true()"/>
</xsl:call-template>
</span>
</xsl:when>
<xsl:when test="@type = 'audio'">
<span class="media media-audio">
<xsl:call-template name="mal2html.media.audio">
<xsl:with-param name="inline" select="true()"/>
</xsl:call-template>
</span>
</xsl:when>
<xsl:otherwise>
<xsl:apply-templates mode="mal2html.inline.mode"/>
</xsl:otherwise>
</xsl:choose>
</xsl:template>
</xsl:stylesheet>
|
