Port to meson build system

The meson build system focuses on speed an ease of use,
which helps speeding up the software development.

https://bugzilla.gnome.org/show_bug.cgi?id=794324
https://gitlab.gnome.org/GNOME/libchamplain/issues/37

Closes #37

2 files changed, 84 insertions, 0 deletions

diff --git a/demos/icons/meson.build b/demos/icons/meson.build
new file mode 100644
index 0000000..a59921b
--- /dev/null
+++ b/demos/icons/meson.build
@@ -0,0 +1,14 @@
+libchamplain_demo_data = [
+  'emblem-favorite.png',
+  'emblem-generic.png',
+  'emblem-important.png',
+  'emblem-new.png',
+]
+
+custom_target(
+  'libchamplain-demo-data',
+  input: libchamplain_demo_data,
+  output: libchamplain_demo_data,
+  command: ['cp', '@INPUT@', '@OUTDIR@'],
+  build_by_default: true,
+)
\ No newline at end of file
diff --git a/demos/meson.build b/demos/meson.build
new file mode 100644
index 0000000..e8bcff1
--- /dev/null
+++ b/demos/meson.build
@@ -0,0 +1,70 @@
+libchamplain_demos = [
+  ['minimal', 'minimal.c'],
+  ['launcher', ['launcher.c', 'markers.c']],
+  ['animated-marker', 'animated-marker.c'],
+  ['polygons', 'polygons.c'],
+  ['url-marker', 'url-marker.c'],
+  ['create_destroy_test', 'create-destroy-test.c'],
+]
+
+foreach demo: libchamplain_demos
+  demo_name = demo.get(0)
+  demo_sources = demo.get(1)
+
+  executable(
+    demo_name,
+    demo_sources,
+    install: false,
+    dependencies: [
+      libchamplain_dep,
+    ]
+  )
+endforeach
+
+subdir('icons')
+
+if build_gtk_widgetry == true
+  libchamplain_gtk_demos = [
+    ['minimal-gtk', 'minimal-gtk.c'],
+    ['launcher-gtk', ['launcher-gtk.c', 'markers.c']],
+  ]
+
+  foreach demo: libchamplain_gtk_demos
+    demo_name = demo.get(0)
+    demo_sources = demo.get(1)
+
+    executable(
+      demo_name,
+      demo_sources,
+      install: false,
+      dependencies: [
+        libchamplain_dep,
+        libchamplain_gtk_dep,
+      ]
+    )
+  endforeach
+endif
+
+if generate_vapi == true
+  libchamplain_vala_demos = [
+    ['launcher-vala', ['launcher-vala.vala', 'markers-vala.vala']],
+  ]
+
+  add_languages('vala')
+
+  foreach demo: libchamplain_vala_demos
+    demo_name = demo.get(0)
+    demo_sources = demo.get(1)
+
+    executable(
+      demo_name,
+      demo_sources,
+      install: false,
+      dependencies: [
+        libchamplain_dep,
+        libchamplain_gtk_dep,
+        libchamplain_vapi,
+      ]
+    )
+  endforeach
+endif
\ No newline at end of file