log-ieee: Work around test failure on NetBSD 5.1 and Solaris 11.

* m4/log-ieee.m4: New file.
* m4/log.m4 (gl_FUNC_LOG): If gl_FUNC_LOG_IEEE is present, test whether
log works with a negative argument. Replace it if not.
* lib/log.c (log): For negative arguments, return NaN.
* modules/log-ieee (Files): Add m4/log-ieee.m4.
(configure.ac): Invoke gl_FUNC_LOG_IEEE.
* doc/posix-functions/log.texi: Mention the log-ieee module.

6 files changed, 93 insertions, 7 deletions

diff --git a/ChangeLog b/ChangeLog
index 5c63ca32ae..c165c20dbe 100644
--- a/ChangeLog
+++ b/ChangeLog
@@ -1,5 +1,14 @@
 2012-03-10  Bruno Haible  <bruno@clisp.org>
 
+	log-ieee: Work around test failure on NetBSD 5.1 and Solaris 11.
+	* m4/log-ieee.m4: New file.
+	* m4/log.m4 (gl_FUNC_LOG): If gl_FUNC_LOG_IEEE is present, test whether
+	log works with a negative argument. Replace it if not.
+	* lib/log.c (log): For negative arguments, return NaN.
+	* modules/log-ieee (Files): Add m4/log-ieee.m4.
+	(configure.ac): Invoke gl_FUNC_LOG_IEEE.
+	* doc/posix-functions/log.texi: Mention the log-ieee module.
+
 	Tests for module 'logl-ieee'.
 	* modules/logl-ieee-tests: New file.
 	* tests/test-logl-ieee.c: New file.
diff --git a/doc/posix-functions/log.texi b/doc/posix-functions/log.texi
index 2e67cedbc0..24c88b9ecf 100644
--- a/doc/posix-functions/log.texi
+++ b/doc/posix-functions/log.texi
@@ -4,15 +4,22 @@
 
 POSIX specification:@* @url{http://www.opengroup.org/onlinepubs/9699919799/functions/log.html}
 
-Gnulib module: log
+Gnulib module: log or log-ieee
 
-Portability problems fixed by Gnulib:
+Portability problems fixed by either Gnulib module @code{log} or @code{log-ieee}:
 @itemize
 @item
 This function returns a wrong value for a minus zero argument on some platforms:
 OSF/1 5.1.
 @end itemize
 
+Portability problems fixed by Gnulib module @code{log-ieee}:
+@itemize
+@item
+This function returns a wrong value for a negative argument on some platforms:
+NetBSD 5.1, Solaris 11 2011-11.
+@end itemize
+
 Portability problems not fixed by Gnulib:
 @itemize
 @end itemize
diff --git a/lib/log.c b/lib/log.c
index 960ec82b5c..4c824d4c37 100644
--- a/lib/log.c
+++ b/lib/log.c
@@ -23,9 +23,16 @@ double
 log (double x)
 #undef log
 {
-  /* Work around the OSF/1 5.1 bug.  */
-  if (x == 0.0)
-    /* Return -Infinity.  */
-    return -1.0 / 0.0;
+  if (x <= 0.0)
+    {
+      /* Work around the OSF/1 5.1 bug.  */
+      if (x == 0.0)
+        /* Return -Infinity.  */
+        return -1.0 / 0.0;
+      /* Work around the NetBSD 5.1, Solaris 11 2011-11 bug.  */
+      else /* x < 0.0 */
+        /* Return NaN.  */
+        return 0.0 / 0.0;
+    }
   return log (x);
 }
diff --git a/m4/log-ieee.m4 b/m4/log-ieee.m4
new file mode 100644
index 0000000000..2a448ba9c7
--- /dev/null
+++ b/m4/log-ieee.m4
@@ -0,0 +1,15 @@
+# log-ieee.m4 serial 1
+dnl Copyright (C) 2012 Free Software Foundation, Inc.
+dnl This file is free software; the Free Software Foundation
+dnl gives unlimited permission to copy and/or distribute it,
+dnl with or without modifications, as long as this notice is preserved.
+
+dnl This macro is in a separate file (not in remainder.m4 and not inlined in the
+dnl module description), so that gl_FUNC_LOG can test whether 'aclocal' has
+dnl found uses of this macro.
+
+AC_DEFUN([gl_FUNC_LOG_IEEE],
+[
+  m4_divert_text([INIT_PREPARE], [gl_log_required=ieee])
+  AC_REQUIRE([gl_FUNC_LOG])
+])
diff --git a/m4/log.m4 b/m4/log.m4
index d217b8202a..d5d5664621 100644
--- a/m4/log.m4
+++ b/m4/log.m4
@@ -1,4 +1,4 @@
-# log.m4 serial 2
+# log.m4 serial 3
 dnl Copyright (C) 2011-2012 Free Software Foundation, Inc.
 dnl This file is free software; the Free Software Foundation
 dnl gives unlimited permission to copy and/or distribute it,
@@ -6,6 +6,7 @@ dnl with or without modifications, as long as this notice is preserved.
 
 AC_DEFUN([gl_FUNC_LOG],
 [
+  m4_divert_text([DEFAULTS], [gl_log_required=plain])
   AC_REQUIRE([gl_MATH_H_DEFAULTS])
 
   dnl Determine LOG_LIBM.
@@ -19,6 +20,51 @@ AC_DEFUN([gl_FUNC_LOG],
     *yes) ;;
     *) REPLACE_LOG=1 ;;
   esac
+
+  m4_ifdef([gl_FUNC_LOG_IEEE], [
+    if test $gl_log_required = ieee && test $REPLACE_LOG = 0; then
+      AC_CACHE_CHECK([whether log works according to ISO C 99 with IEC 60559],
+        [gl_cv_func_log_ieee],
+        [
+          save_LIBS="$LIBS"
+          LIBS="$LIBS $LOG_LIBM"
+          AC_RUN_IFELSE(
+            [AC_LANG_SOURCE([[
+#ifndef __NO_MATH_INLINES
+# define __NO_MATH_INLINES 1 /* for glibc */
+#endif
+#include <math.h>
+/* Compare two numbers with ==.
+   This is a separate function because IRIX 6.5 "cc -O" miscompiles an
+   'x == x' test.  */
+static int
+numeric_equal (double x, double y)
+{
+  return x == y;
+}
+static double dummy (double x) { return 0; }
+int main (int argc, char *argv[])
+{
+  double (*my_log) (double) = argc ? log : dummy;
+  /* Test log(negative).
+     This test fails on NetBSD 5.1, Solaris 11 2011-11.  */
+  double y = my_log (-1.0);
+  if (numeric_equal (y, y))
+    return 1;
+  return 0;
+}
+            ]])],
+            [gl_cv_func_log_ieee=yes],
+            [gl_cv_func_log_ieee=no],
+            [gl_cv_func_log_ieee="guessing no"])
+          LIBS="$save_LIBS"
+        ])
+      case "$gl_cv_func_log_ieee" in
+        *yes) ;;
+        *) REPLACE_LOG=1 ;;
+      esac
+    fi
+  ])
 ])
 
 dnl Test whether log() works.
diff --git a/modules/log-ieee b/modules/log-ieee
index ad62788ea2..5ce841cf62 100644
--- a/modules/log-ieee
+++ b/modules/log-ieee
@@ -2,12 +2,14 @@ Description:
 log() function according to ISO C 99 with IEC 60559.
 
 Files:
+m4/log-ieee.m4
 
 Depends-on:
 log
 fpieee
 
 configure.ac:
+gl_FUNC_LOG_IEEE
 
 Makefile.am: