cbrtl-ieee: Work around test failure on IRIX 6.5.

* m4/cbrtl-ieee.m4: New file.
* m4/cbrtl.m4 (gl_FUNC_CBRTL): If gl_FUNC_CBRTL_IEEE is present,
test whether cbrtl works with a minus zero argument. Replace it if not.
* lib/math.in.h (cbrtl): Override if REPLACE_CBRTL is 1.
* m4/math_h.m4 (gl_MATH_H_DEFAULTS): Initialize REPLACE_CBRTL.
* modules/math (Makefile.am): Substitute REPLACE_CBRTL.
* modules/cbrtl (configure.ac): Consider REPLACE_CBRTL.
(Depends-on): Update conditions.
* modules/cbrtl-ieee (Files): Add m4/cbrtl-ieee.m4, m4/minus-zero.m4,
m4/signbit.m4.
(configure.ac): Invoke gl_FUNC_CBRTL_IEEE.
* lib/cbrtl.c (cbrtl) [IRIX]: Avoid an unnecessary addition.
* doc/posix-functions/cbrtl.texi: Mention the cbrtl-ieee module.

10 files changed, 118 insertions, 12 deletions

diff --git a/ChangeLog b/ChangeLog
index 52db360527..da817e8863 100644
--- a/ChangeLog
+++ b/ChangeLog
@@ -1,5 +1,20 @@
 2012-02-29  Bruno Haible  <bruno@clisp.org>
 
+	cbrtl-ieee: Work around test failure on IRIX 6.5.
+	* m4/cbrtl-ieee.m4: New file.
+	* m4/cbrtl.m4 (gl_FUNC_CBRTL): If gl_FUNC_CBRTL_IEEE is present,
+	test whether cbrtl works with a minus zero argument. Replace it if not.
+	* lib/math.in.h (cbrtl): Override if REPLACE_CBRTL is 1.
+	* m4/math_h.m4 (gl_MATH_H_DEFAULTS): Initialize REPLACE_CBRTL.
+	* modules/math (Makefile.am): Substitute REPLACE_CBRTL.
+	* modules/cbrtl (configure.ac): Consider REPLACE_CBRTL.
+	(Depends-on): Update conditions.
+	* modules/cbrtl-ieee (Files): Add m4/cbrtl-ieee.m4, m4/minus-zero.m4,
+	m4/signbit.m4.
+	(configure.ac): Invoke gl_FUNC_CBRTL_IEEE.
+	* lib/cbrtl.c (cbrtl) [IRIX]: Avoid an unnecessary addition.
+	* doc/posix-functions/cbrtl.texi: Mention the cbrtl-ieee module.
+
 	Tests for module 'cbrtl-ieee'.
 	* modules/cbrtl-ieee-tests: New file.
 	* tests/test-cbrtl-ieee.c: New file.
diff --git a/doc/posix-functions/cbrtl.texi b/doc/posix-functions/cbrtl.texi
index 35ab013e67..a97c58507e 100644
--- a/doc/posix-functions/cbrtl.texi
+++ b/doc/posix-functions/cbrtl.texi
@@ -4,9 +4,9 @@
 
 POSIX specification:@* @url{http://www.opengroup.org/onlinepubs/9699919799/functions/cbrtl.html}
 
-Gnulib module: cbrtl
+Gnulib module: cbrtl or cbrtl-ieee
 
-Portability problems fixed by Gnulib:
+Portability problems fixed by either Gnulib module @code{cbrtl} or @code{cbrtl-ieee}
 @itemize
 @item
 This function is missing on some platforms:
@@ -16,6 +16,14 @@ This function is not declared on some platforms:
 IRIX 6.5.
 @end itemize
 
+Portability problems fixed by Gnulib module @code{cbrtl-ieee}:
+@itemize
+@item
+This function returns a positive zero for a minus zero argument
+on some platforms:
+IRIX 6.5.
+@end itemize
+
 Portability problems not fixed by Gnulib:
 @itemize
 @end itemize
diff --git a/lib/cbrtl.c b/lib/cbrtl.c
index fe635f8824..616c27fb5e 100644
--- a/lib/cbrtl.c
+++ b/lib/cbrtl.c
@@ -140,7 +140,13 @@ cbrtl (long double x)
       return x;
     }
   else
-    return x + x;
+    {
+# ifdef __sgi /* so that when x == -0.0L, the result is -0.0L not +0.0L */
+      return x;
+# else
+      return x + x;
+# endif
+    }
 }
 
 #endif
diff --git a/lib/math.in.h b/lib/math.in.h
index b359df9bbc..607fa0b1c2 100644
--- a/lib/math.in.h
+++ b/lib/math.in.h
@@ -326,10 +326,19 @@ _GL_WARN_ON_USE (cbrt, "cbrt is unportable - "
 #endif
 
 #if @GNULIB_CBRTL@
-# if !@HAVE_DECL_CBRTL@
+# if @REPLACE_CBRTL@
+#  if !(defined __cplusplus && defined GNULIB_NAMESPACE)
+#   undef cbrtl
+#   define cbrtl rpl_cbrtl
+#  endif
+_GL_FUNCDECL_RPL (cbrtl, long double, (long double x));
+_GL_CXXALIAS_RPL (cbrtl, long double, (long double x));
+# else
+#  if !@HAVE_DECL_CBRTL@
 _GL_FUNCDECL_SYS (cbrtl, long double, (long double x));
-# endif
+#  endif
 _GL_CXXALIAS_SYS (cbrtl, long double, (long double x));
+# endif
 _GL_CXXALIASWARN (cbrtl);
 #elif defined GNULIB_POSIXCHECK
 # undef cbrtl
diff --git a/m4/cbrtl-ieee.m4 b/m4/cbrtl-ieee.m4
new file mode 100644
index 0000000000..c89b4201c6
--- /dev/null
+++ b/m4/cbrtl-ieee.m4
@@ -0,0 +1,15 @@
+# cbrtl-ieee.m4 serial 1
+dnl Copyright (C) 2012 Free Software Foundation, Inc.
+dnl This file is free software; the Free Software Foundation
+dnl gives unlimited permission to copy and/or distribute it,
+dnl with or without modifications, as long as this notice is preserved.
+
+dnl This macro is in a separate file (not in cbrtl.m4 and not inlined in the
+dnl module description), so that gl_FUNC_CBRTL can test whether 'aclocal' has
+dnl found uses of this macro.
+
+AC_DEFUN([gl_FUNC_CBRTL_IEEE],
+[
+  m4_divert_text([INIT_PREPARE], [gl_cbrtl_required=ieee])
+  AC_REQUIRE([gl_FUNC_CBRTL])
+])
diff --git a/m4/cbrtl.m4 b/m4/cbrtl.m4
index 3f02abcc30..f40a1c0d67 100644
--- a/m4/cbrtl.m4
+++ b/m4/cbrtl.m4
@@ -1,4 +1,4 @@
-# cbrtl.m4 serial 1
+# cbrtl.m4 serial 2
 dnl Copyright (C) 2012 Free Software Foundation, Inc.
 dnl This file is free software; the Free Software Foundation
 dnl gives unlimited permission to copy and/or distribute it,
@@ -6,6 +6,7 @@ dnl with or without modifications, as long as this notice is preserved.
 
 AC_DEFUN([gl_FUNC_CBRTL],
 [
+  m4_divert_text([DEFAULTS], [gl_cbrtl_required=plain])
   AC_REQUIRE([gl_MATH_H_DEFAULTS])
   AC_REQUIRE([gl_LONG_DOUBLE_VS_DOUBLE])
   AC_REQUIRE([gl_FUNC_CBRT])
@@ -21,9 +22,55 @@ AC_DEFUN([gl_FUNC_CBRTL],
     dnl Also check whether it's declared.
     dnl IRIX 6.5 has cbrtl() in libm but doesn't declare it in <math.h>.
     AC_CHECK_DECL([cbrtl], , [HAVE_DECL_CBRTL=0], [[#include <math.h>]])
+    m4_ifdef([gl_FUNC_CBRTL_IEEE], [
+      if test $gl_cbrtl_required = ieee && test $REPLACE_CBRTL = 0; then
+        AC_CACHE_CHECK([whether cbrtl works according to ISO C 99 with IEC 60559],
+          [gl_cv_func_cbrtl_ieee],
+          [
+            save_LIBS="$LIBS"
+            LIBS="$LIBS $CBRTL_LIBM"
+            AC_RUN_IFELSE(
+              [AC_LANG_SOURCE([[
+#ifndef __NO_MATH_INLINES
+# define __NO_MATH_INLINES 1 /* for glibc */
+#endif
+#include <math.h>
+]gl_LONG_DOUBLE_MINUS_ZERO_CODE[
+]gl_LONG_DOUBLE_SIGNBIT_CODE[
+static long double dummy (long double x) { return 0; }
+int main (int argc, char *argv[])
+{
+  extern
+  #ifdef __cplusplus
+  "C"
+  #endif
+  long double cbrtl (long double);
+  long double (*my_cbrtl) (long double) = argc ? cbrtl : dummy;
+  long double f;
+  /* Test cbrtl(-0.0).
+     This test fails on IRIX 6.5.  */
+  f = my_cbrtl (minus_zerol);
+  if (!(f == 0.0L) || (signbitl (minus_zerol) && !signbitl (f)))
+    return 1;
+  return 0;
+}
+              ]])],
+              [gl_cv_func_cbrtl_ieee=yes],
+              [gl_cv_func_cbrtl_ieee=no],
+              [gl_cv_func_cbrtl_ieee="guessing no"])
+            LIBS="$save_LIBS"
+          ])
+        case "$gl_cv_func_cbrtl_ieee" in
+          *yes) ;;
+          *) REPLACE_CBRTL=1 ;;
+        esac
+      fi
+    ])
   else
     HAVE_CBRTL=0
     HAVE_DECL_CBRTL=0
+  fi
+  if test $HAVE_CBRTL = 0 || test $REPLACE_CBRTL = 1; then
     dnl Find libraries needed to link lib/cbrtl.c.
     if test $HAVE_SAME_LONG_DOUBLE_AS_DOUBLE = 1; then
       CBRTL_LIBM="$CBRT_LIBM"
diff --git a/m4/math_h.m4 b/m4/math_h.m4
index f329a8aca4..a5a71f2e4b 100644
--- a/m4/math_h.m4
+++ b/m4/math_h.m4
@@ -1,4 +1,4 @@
-# math_h.m4 serial 78
+# math_h.m4 serial 79
 dnl Copyright (C) 2007-2012 Free Software Foundation, Inc.
 dnl This file is free software; the Free Software Foundation
 dnl gives unlimited permission to copy and/or distribute it,
@@ -217,6 +217,7 @@ AC_DEFUN([gl_MATH_H_DEFAULTS],
   HAVE_DECL_TRUNCF=1;          AC_SUBST([HAVE_DECL_TRUNCF])
   HAVE_DECL_TRUNCL=1;          AC_SUBST([HAVE_DECL_TRUNCL])
   REPLACE_CBRTF=0;             AC_SUBST([REPLACE_CBRTF])
+  REPLACE_CBRTL=0;             AC_SUBST([REPLACE_CBRTL])
   REPLACE_CEIL=0;              AC_SUBST([REPLACE_CEIL])
   REPLACE_CEILF=0;             AC_SUBST([REPLACE_CEILF])
   REPLACE_CEILL=0;             AC_SUBST([REPLACE_CEILL])
diff --git a/modules/cbrtl b/modules/cbrtl
index ccde12fa27..aec1cd7327 100644
--- a/modules/cbrtl
+++ b/modules/cbrtl
@@ -9,14 +9,14 @@ m4/mathfunc.m4
 
 Depends-on:
 math
-cbrt            [test $HAVE_CBRTL = 0 && test $HAVE_SAME_LONG_DOUBLE_AS_DOUBLE = 1]
-isfinite        [test $HAVE_CBRTL = 0 && test $HAVE_SAME_LONG_DOUBLE_AS_DOUBLE = 0]
-frexpl          [test $HAVE_CBRTL = 0 && test $HAVE_SAME_LONG_DOUBLE_AS_DOUBLE = 0]
-ldexpl          [test $HAVE_CBRTL = 0 && test $HAVE_SAME_LONG_DOUBLE_AS_DOUBLE = 0]
+cbrt            [{ test $HAVE_CBRTL = 0 || test $REPLACE_CBRTL = 1; } && test $HAVE_SAME_LONG_DOUBLE_AS_DOUBLE = 1]
+isfinite        [{ test $HAVE_CBRTL = 0 || test $REPLACE_CBRTL = 1; } && test $HAVE_SAME_LONG_DOUBLE_AS_DOUBLE = 0]
+frexpl          [{ test $HAVE_CBRTL = 0 || test $REPLACE_CBRTL = 1; } && test $HAVE_SAME_LONG_DOUBLE_AS_DOUBLE = 0]
+ldexpl          [{ test $HAVE_CBRTL = 0 || test $REPLACE_CBRTL = 1; } && test $HAVE_SAME_LONG_DOUBLE_AS_DOUBLE = 0]
 
 configure.ac:
 gl_FUNC_CBRTL
-if test $HAVE_CBRTL = 0; then
+if test $HAVE_CBRTL = 0 || test $REPLACE_CBRTL = 1; then
   AC_LIBOBJ([cbrtl])
 fi
 gl_MATH_MODULE_INDICATOR([cbrtl])
diff --git a/modules/cbrtl-ieee b/modules/cbrtl-ieee
index 9380f329f2..4d16baf1d3 100644
--- a/modules/cbrtl-ieee
+++ b/modules/cbrtl-ieee
@@ -2,12 +2,16 @@ Description:
 cbrtl() function according to ISO C 99 with IEC 60559.
 
 Files:
+m4/cbrtl-ieee.m4
+m4/minus-zero.m4
+m4/signbit.m4
 
 Depends-on:
 cbrtl
 fpieee
 
 configure.ac:
+gl_FUNC_CBRTL_IEEE
 
 Makefile.am:
 
diff --git a/modules/math b/modules/math
index 41505d2f80..bba603196d 100644
--- a/modules/math
+++ b/modules/math
@@ -186,6 +186,7 @@ math.h: math.in.h $(top_builddir)/config.status $(CXXDEFS_H) $(ARG_NONNULL_H) $(
 	      -e 's|@''HAVE_DECL_TRUNCL''@|$(HAVE_DECL_TRUNCL)|g' \
 	  | \
 	  sed -e 's|@''REPLACE_CBRTF''@|$(REPLACE_CBRTF)|g' \
+	      -e 's|@''REPLACE_CBRTL''@|$(REPLACE_CBRTL)|g' \
 	      -e 's|@''REPLACE_CEIL''@|$(REPLACE_CEIL)|g' \
 	      -e 's|@''REPLACE_CEILF''@|$(REPLACE_CEILF)|g' \
 	      -e 's|@''REPLACE_CEILL''@|$(REPLACE_CEILL)|g' \