log10-ieee: Work around test failure on NetBSD 5.1 and Solaris 11.

* m4/log10-ieee.m4: New file.
* m4/log10.m4 (gl_FUNC_LOG10): If gl_FUNC_LOG10_IEEE is present, test
whether log10 works with a negative argument. Replace it if not.
* lib/log10.c (log10): For negative arguments, return NaN.
* modules/log10-ieee (Files): Add m4/log10-ieee.m4.
(configure.ac): Invoke gl_FUNC_LOG10_IEEE.
* doc/posix-functions/log10.texi: Mention the log10-ieee module.

1 files changed, 47 insertions, 1 deletions

diff --git a/m4/log10.m4 b/m4/log10.m4
index ab066cc071..08122ca80f 100644
--- a/m4/log10.m4
+++ b/m4/log10.m4
@@ -1,4 +1,4 @@
-# log10.m4 serial 2
+# log10.m4 serial 3
 dnl Copyright (C) 2011-2012 Free Software Foundation, Inc.
 dnl This file is free software; the Free Software Foundation
 dnl gives unlimited permission to copy and/or distribute it,
@@ -6,6 +6,7 @@ dnl with or without modifications, as long as this notice is preserved.
 
 AC_DEFUN([gl_FUNC_LOG10],
 [
+  m4_divert_text([DEFAULTS], [gl_log10_required=plain])
   AC_REQUIRE([gl_MATH_H_DEFAULTS])
 
   dnl Determine LOG10_LIBM.
@@ -19,6 +20,51 @@ AC_DEFUN([gl_FUNC_LOG10],
     *yes) ;;
     *) REPLACE_LOG10=1 ;;
   esac
+
+  m4_ifdef([gl_FUNC_LOG10_IEEE], [
+    if test $gl_log10_required = ieee && test $REPLACE_LOG10 = 0; then
+      AC_CACHE_CHECK([whether log10 works according to ISO C 99 with IEC 60559],
+        [gl_cv_func_log10_ieee],
+        [
+          save_LIBS="$LIBS"
+          LIBS="$LIBS $LOG10_LIBM"
+          AC_RUN_IFELSE(
+            [AC_LANG_SOURCE([[
+#ifndef __NO_MATH_INLINES
+# define __NO_MATH_INLINES 1 /* for glibc */
+#endif
+#include <math.h>
+/* Compare two numbers with ==.
+   This is a separate function because IRIX 6.5 "cc -O" miscompiles an
+   'x == x' test.  */
+static int
+numeric_equal (double x, double y)
+{
+  return x == y;
+}
+static double dummy (double x) { return 0; }
+int main (int argc, char *argv[])
+{
+  double (*my_log10) (double) = argc ? log10 : dummy;
+  /* Test log10(negative).
+     This test fails on NetBSD 5.1, Solaris 11 2011-11.  */
+  double y = my_log10 (-1.0);
+  if (numeric_equal (y, y))
+    return 1;
+  return 0;
+}
+            ]])],
+            [gl_cv_func_log10_ieee=yes],
+            [gl_cv_func_log10_ieee=no],
+            [gl_cv_func_log10_ieee="guessing no"])
+          LIBS="$save_LIBS"
+        ])
+      case "$gl_cv_func_log10_ieee" in
+        *yes) ;;
+        *) REPLACE_LOG10=1 ;;
+      esac
+    fi
+  ])
 ])
 
 dnl Test whether log10() works.