login_tty: Ensure declaration in <utmp.h>.

* tests/test-utmp-c++.cc: New file.
* modules/utmp-c++-tests: New file.

* tests/test-utmp.c: New file.
* modules/utmp-tests: New file.

* lib/login_tty.c: Include <utmp.h>.
* m4/login_tty.m4: New file.
(gl_FUNC_LOGIN_TTY): Moved here from m4/pty.m4. Set HAVE_LOGIN_TTY.
* m4/pty.m4 (gl_FUNC_LOGIN_TTY): Moved to m4/login_tty.m4.
* modules/login_tty (Files): Add m4/login_tty.m4.
(Depends-on): Add utmp. Remove pty. Update condition.
(configure.ac): Update condition. Invoke gl_UTMP_MODULE_INDICATOR
instead of gl_PTY_MODULE_INDICATOR.
(Include): List <utmp.h>.
* doc/glibc-functions/login_tty.texi: Mark the include file diversity as
fixed.
* tests/test-login_tty.c: Include <utmp.h>. Don't declare login_tty
here.

* lib/utmp.in.h: New file.
* m4/utmp_h.m4: New file.
* modules/utmp: New file.
* doc/glibc-headers/utmp.texi: New file.
* doc/gnulib.texi (Glibc Header File Substitutes): Include it.

1 files changed, 64 insertions, 0 deletions

diff --git a/m4/utmp_h.m4 b/m4/utmp_h.m4
new file mode 100644
index 0000000000..fff6dbdfe7
--- /dev/null
+++ b/m4/utmp_h.m4
@@ -0,0 +1,64 @@
+# Configure a GNU-like replacement for <utmp.h>.
+
+# Copyright (C) 2023 Free Software Foundation, Inc.
+# This file is free software; the Free Software Foundation
+# gives unlimited permission to copy and/or distribute it,
+# with or without modifications, as long as this notice is preserved.
+
+# serial 1
+
+AC_DEFUN_ONCE([gl_UTMP_H],
+[
+  dnl Ensure to expand the default settings once only, before all statements
+  dnl that occur in other macros.
+  AC_REQUIRE([gl_UTMP_H_DEFAULTS])
+
+  gl_CHECK_NEXT_HEADERS([utmp.h])
+  if test $ac_cv_header_utmp_h = yes; then
+    HAVE_UTMP_H=1
+  else
+    HAVE_UTMP_H=0
+  fi
+  AC_SUBST([HAVE_UTMP_H])
+
+  dnl Check for declarations of anything we want to poison if the
+  dnl corresponding gnulib module is not in use, and which is not
+  dnl guaranteed by C89.
+  gl_WARN_ON_USE_PREPARE([[
+      #include <sys/types.h>
+      #include <utmp.h>
+    ]],
+    [login_tty])
+])
+
+# gl_UTMP_MODULE_INDICATOR([modulename])
+# sets the shell variable that indicates the presence of the given module
+# to a C preprocessor expression that will evaluate to 1.
+# This macro invocation must not occur in macros that are AC_REQUIREd.
+AC_DEFUN([gl_UTMP_MODULE_INDICATOR],
+[
+  dnl Ensure to expand the default settings once only.
+  gl_UTMP_H_REQUIRE_DEFAULTS
+  gl_MODULE_INDICATOR_SET_VARIABLE([$1])
+  dnl Define it also as a C macro, for the benefit of the unit tests.
+  gl_MODULE_INDICATOR_FOR_TESTS([$1])
+])
+
+# Initializes the default values for AC_SUBSTed shell variables.
+# This macro must not be AC_REQUIREd.  It must only be invoked, and only
+# outside of macros or in macros that are not AC_REQUIREd.
+AC_DEFUN([gl_UTMP_H_REQUIRE_DEFAULTS],
+[
+  m4_defun(GL_MODULE_INDICATOR_PREFIX[_UTMP_H_MODULE_INDICATOR_DEFAULTS], [
+    gl_MODULE_INDICATOR_INIT_VARIABLE([GNULIB_LOGIN_TTY])
+  ])
+  m4_require(GL_MODULE_INDICATOR_PREFIX[_UTMP_H_MODULE_INDICATOR_DEFAULTS])
+  AC_REQUIRE([gl_UTMP_H_DEFAULTS])
+])
+
+AC_DEFUN([gl_UTMP_H_DEFAULTS],
+[
+  dnl Assume proper GNU behavior unless another module says otherwise.
+  HAVE_LOGIN_TTY=1;             AC_SUBST([HAVE_LOGIN_TTY])
+  REPLACE_LOGIN_TTY=0;          AC_SUBST([REPLACE_LOGIN_TTY])
+])