1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
|
# Checks for stat-related time functions.
# Copyright (C) 1998, 1999, 2001, 2003, 2005, 2006, 2007 Free Software
# Foundation, Inc.
# This file is free software; the Free Software Foundation
# gives unlimited permission to copy and/or distribute it,
# with or without modifications, as long as this notice is preserved.
dnl From Paul Eggert.
# st_atim.tv_nsec - Linux, Solaris
# st_atimespec.tv_nsec - FreeBSD, NetBSD, if ! defined _POSIX_SOURCE
# st_atimensec - FreeBSD, NetBSD, if defined _POSIX_SOURCE
# st_atim.st__tim.tv_nsec - UnixWare (at least 2.1.2 through 7.1)
# st_spare1 - Cygwin?
# st_birthtimespec present on NetBSD (probably also FreBSD, OpenBSD)
AC_DEFUN([gl_STAT_TIME],
[
AC_REQUIRE([AC_C_INLINE])
AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
AC_CHECK_HEADERS_ONCE([sys/time.h])
AC_CHECK_MEMBERS([struct stat.st_atim.tv_nsec],
[AC_CACHE_CHECK([whether struct stat.st_atim is of type struct timespec],
[ac_cv_typeof_struct_stat_st_atim_is_struct_timespec],
[AC_TRY_COMPILE(
[
#include <sys/types.h>
#include <sys/stat.h>
#if HAVE_SYS_TIME_H
# include <sys/time.h>
#endif
#include <time.h>
struct timespec ts;
struct stat st;
],
[
st.st_atim = ts;
],
[ac_cv_typeof_struct_stat_st_atim_is_struct_timespec=yes],
[ac_cv_typeof_struct_stat_st_atim_is_struct_timespec=no])])
if test $ac_cv_typeof_struct_stat_st_atim_is_struct_timespec = yes; then
AC_DEFINE([TYPEOF_STRUCT_STAT_ST_ATIM_IS_STRUCT_TIMESPEC], 1,
[Define to 1 if the type of the st_atim member of a struct stat is
struct timespec.])
fi],
[AC_CHECK_MEMBERS([struct stat.st_atimespec.tv_nsec], [],
[AC_CHECK_MEMBERS([struct stat.st_atimensec], [],
[AC_CHECK_MEMBERS([struct stat.st_atim.st__tim.tv_nsec], [],
[AC_CHECK_MEMBERS([struct stat.st_spare1], [],
[],
[#include <sys/types.h>
#include <sys/stat.h>])],
[#include <sys/types.h>
#include <sys/stat.h>])],
[#include <sys/types.h>
#include <sys/stat.h>])],
[#include <sys/types.h>
#include <sys/stat.h>])],
[#include <sys/types.h>
#include <sys/stat.h>])
])
# Checks for st_birthtime, which is a feature from UFS2 (FreeBSD, NetBSD, OpenBSD, etc.)
# There was a time when this field was named st_createtime (21 June 2002 to 16 July 2002)
# But that window is very small and applied only to development code, so systems still
# using that configuration are not a realistic development target.
# See revisions 1.10 and 1.11 of FreeBSD's src/sys/ufs/ufs/dinode.h.
#
AC_DEFUN([gl_STAT_BIRTHTIME],
[
AC_REQUIRE([AC_C_INLINE])
AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
AC_CHECK_HEADERS_ONCE([sys/time.h])
AC_CHECK_MEMBERS([struct stat.st_birthtimespec.tv_sec, struct stat.st_birthtimespec.tv_nsec], [],
[AC_CHECK_MEMBERS([struct stat.st_birthtime, struct stat.st_birthtimensec], [],
[AC_CHECK_MEMBERS([struct stat.st_spare4], [],
[],
[#include <sys/types.h>
#include <sys/stat.h>])],
[#include <sys/types.h>
#include <sys/stat.h>])],
[#include <sys/types.h>
#include <sys/stat.h>])
])
|
