blob: 0654d9cd2140109a55752a204bacc19572dbcd18 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
|
# trunc.m4 serial 4
dnl Copyright (C) 2007, 2010 Free Software Foundation, Inc.
dnl This file is free software; the Free Software Foundation
dnl gives unlimited permission to copy and/or distribute it,
dnl with or without modifications, as long as this notice is preserved.
AC_DEFUN([gl_FUNC_TRUNC],
[
AC_REQUIRE([gl_MATH_H_DEFAULTS])
dnl Persuade glibc <math.h> to declare trunc().
AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
dnl Test whether trunc() is declared.
AC_CHECK_DECLS([trunc], , , [#include <math.h>])
if test "$ac_cv_have_decl_trunc" = yes; then
dnl Test whether trunc() can be used without libm.
TRUNC_LIBM=?
AC_LINK_IFELSE(
[AC_LANG_PROGRAM(
[[#ifndef __NO_MATH_INLINES
# define __NO_MATH_INLINES 1 /* for glibc */
#endif
#include <math.h>
double x;]],
[[x = trunc(x);]])],
[TRUNC_LIBM=])
if test "$TRUNC_LIBM" = "?"; then
save_LIBS="$LIBS"
LIBS="$LIBS -lm"
AC_LINK_IFELSE(
[AC_LANG_PROGRAM(
[[#ifndef __NO_MATH_INLINES
# define __NO_MATH_INLINES 1 /* for glibc */
#endif
#include <math.h>
double x;]],
[[x = trunc(x);]])],
[TRUNC_LIBM="-lm"])
LIBS="$save_LIBS"
fi
if test "$TRUNC_LIBM" = "?"; then
TRUNC_LIBM=
fi
else
HAVE_DECL_TRUNC=0
AC_LIBOBJ([trunc])
TRUNC_LIBM=
fi
AC_SUBST([TRUNC_LIBM])
])
|
