blob: 0b7c49ab2facf462a37bca85d74f47bbfa89769f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
|
# truncf.m4 serial 3
dnl Copyright (C) 2007, 2010 Free Software Foundation, Inc.
dnl This file is free software; the Free Software Foundation
dnl gives unlimited permission to copy and/or distribute it,
dnl with or without modifications, as long as this notice is preserved.
AC_DEFUN([gl_FUNC_TRUNCF],
[
AC_REQUIRE([gl_MATH_H_DEFAULTS])
dnl Persuade glibc <math.h> to declare truncf().
AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
dnl Test whether truncf() is declared.
AC_CHECK_DECLS([truncf], , , [#include <math.h>])
if test "$ac_cv_have_decl_truncf" = yes; then
dnl Test whether truncf() can be used without libm.
TRUNCF_LIBM=?
AC_LINK_IFELSE(
[AC_LANG_PROGRAM(
[[#ifndef __NO_MATH_INLINES
# define __NO_MATH_INLINES 1 /* for glibc */
#endif
#include <math.h>
float x;]],
[[x = truncf(x);]])],
[TRUNCF_LIBM=])
if test "$TRUNCF_LIBM" = "?"; then
save_LIBS="$LIBS"
LIBS="$LIBS -lm"
AC_LINK_IFELSE(
[AC_LANG_PROGRAM(
[[#ifndef __NO_MATH_INLINES
# define __NO_MATH_INLINES 1 /* for glibc */
#endif
#include <math.h>
float x;]],
[[x = truncf(x);]])],
[TRUNCF_LIBM="-lm"])
LIBS="$save_LIBS"
fi
if test "$TRUNCF_LIBM" = "?"; then
TRUNCF_LIBM=
fi
else
HAVE_DECL_TRUNCF=0
AC_LIBOBJ([truncf])
TRUNCF_LIBM=
fi
AC_SUBST([TRUNCF_LIBM])
])
|
