1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
|
# SPDX-License-Identifier: MIT
#
# Copyright © 2013 Red Hat, Inc.
#
AC_PREREQ([2.62])
# change meson version too
AC_INIT([libevdev],
[1.13.1],
[https://gitlab.freedesktop.org/libevdev/libevdev/issues/],
[libevdev],
[http://freedesktop.org/wiki/Software/libevdev/])
AC_CONFIG_SRCDIR([libevdev/libevdev.c])
AC_CONFIG_HEADERS([config.h])
AC_CONFIG_MACRO_DIR([m4])
AC_CONFIG_AUX_DIR([build-aux])
AC_USE_SYSTEM_EXTENSIONS
AM_INIT_AUTOMAKE([1.11 foreign no-dist-gzip dist-xz subdir-objects])
# DO NOT MODIFY THIS
# Use symbol versioning instead.
LIBEVDEV_LT_VERSION=5:0:3
AC_SUBST(LIBEVDEV_LT_VERSION)
AM_SILENT_RULES([yes])
# Check for programs
AC_PROG_CC_C99
# Initialize libtool
LT_PREREQ([2.2])
LT_INIT
LT_PATH_LD
with_ldflags=""
if test "x$lt_cv_prog_gnu_ld" = "xyes"; then
CC_CHECK_FLAGS_APPEND([with_ldflags], [LDFLAGS], [\
-Wl,--as-needed \
-Wl,--gc-sections \
-Wl,-z,relro \
-Wl,-z,now])
fi
AC_SUBST([GNU_LD_FLAGS], $with_ldflags)
case "${host_os}" in
freebsd*)
AC_SUBST([OS], [freebsd])
;;
*)
AC_SUBST([OS], [linux])
;;
esac
AC_CHECK_LIB([m], [round])
PKG_PROG_PKG_CONFIG()
PKG_CHECK_MODULES(CHECK, [check >= 0.9.9], [HAVE_CHECK="yes"], [HAVE_CHECK="no"])
if test "x$HAVE_CHECK" != "xyes"; then
AC_MSG_WARN([check not found - skipping building unit tests])
fi
AM_CONDITIONAL(ENABLE_RUNTIME_TESTS, [test "x$HAVE_CHECK" = "xyes"])
AM_CONDITIONAL(ENABLE_STATIC_LINK_TEST, [test "x$enable_static" = "xyes"])
with_cflags=""
if test "x$GCC" = "xyes"; then
CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [\
-Wall \
-Wextra \
-Wno-unused-parameter \
-Wstrict-prototypes \
-Wmissing-prototypes \
-fvisibility=hidden \
-pipe \
-fno-strict-aliasing \
-ffunction-sections \
-fdata-sections \
-fno-strict-aliasing \
-fdiagnostics-show-option \
-fno-common])
fi
AC_SUBST([GCC_CFLAGS], $with_cflags)
AC_PATH_PROG(DOXYGEN, [doxygen])
if test "x$DOXYGEN" = "x"; then
AC_MSG_WARN([doxygen not found - required for documentation])
have_doxygen="no"
else
have_doxygen="yes"
fi
AM_CONDITIONAL([HAVE_DOXYGEN], [test "x$have_doxygen" = "xyes"])
AC_MSG_CHECKING([whether to build with gcov])
AC_ARG_ENABLE([gcov],
[AS_HELP_STRING([--enable-gcov],
[Whether to enable coverage testing (default:disabled)])],
[],
[enable_gcov=no],
)
AS_IF([test "x$enable_gcov" != "xno"],
[
GCOV_CFLAGS="-fprofile-arcs -ftest-coverage"
GCOV_LDFLAGS="-lgcov"
enable_gcov=yes
],
)
AM_CONDITIONAL([GCOV_ENABLED], [test "x$enable_gcov" != "xno"])
AC_SUBST([GCOV_CFLAGS])
AC_SUBST([GCOV_LDFLAGS])
AC_MSG_RESULT([$enable_gcov])
AC_MSG_CHECKING([whether to build with coverity support])
AC_ARG_ENABLE([coverity],
[AS_HELP_STRING([--enable-coverity],
[Whether to build with coverity support (default: disabled)])],
[],
[enable_coverity=no],
)
AS_IF([test "x$enable_coverity" != "xno"],
[
AC_DEFINE([_Float128], [__uint128_t], [Override for coverity])
AC_DEFINE([_Float32], [int], [Override for coverity])
AC_DEFINE([_Float32x], [int], [Override for coverity])
AC_DEFINE([_Float64], [long], [Override for coverity])
AC_DEFINE([_Float64x], [long], [Override for coverity])
enable_coverity=yes
],
)
AC_MSG_RESULT([$enable_coverity])
AM_PATH_PYTHON([2.6])
# nm to check for leaking symbols in the static library
AC_PATH_PROG(NM, [nm])
AM_CONDITIONAL(HAVE_NM, [test "x$NM" != "x"])
if test "x$enable_static" = "xno"; then
static_symbol_leaks_test="no - static build disabled"
else
if test "x$NM" = "x"; then
AC_MSG_WARN([nm not found - skipping symbol leak test])
have_nm="no"
static_symbol_leaks_test="no - nm not found"
else
have_nm="yes"
static_symbol_leaks_test="yes"
fi
fi
AM_CONDITIONAL(ENABLE_STATIC_SYMBOL_LEAKS_TEST, [test "x$static_symbol_leaks_test" = "xyes"])
AC_CONFIG_FILES([Makefile
libevdev/Makefile
doc/Makefile
doc/libevdev.doxygen
doc/libevdev.man
tools/Makefile
test/Makefile
libevdev.pc])
AC_OUTPUT
AC_MSG_RESULT([
Prefix ${prefix}
Libdir ${libdir}
Build documentation ${have_doxygen}
Enable unit-tests ${HAVE_CHECK}
Enable profiling ${enable_gcov}
Enable coverity support ${enable_coverity}
Static library symbol check ${static_symbol_leaks_test}
])
|
