1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
|
# gpgrt.m4 - autoconf macro to detect libgpgrt
# Copyright (C) 2002, 2003, 2004, 2011, 2014, 2017, 2018 g10 Code GmbH
#
# This file is free software; as a special exception the author gives
# unlimited permission to copy and/or distribute it, with or without
# modifications, as long as this notice is preserved.
#
# This file is distributed in the hope that it will be useful, but
# WITHOUT ANY WARRANTY, to the extent permitted by law; without even the
# implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
# SPDX-License-Identifier: FSFULLR
#
# Last-changed: 2018-11-02
# Note: This is a kind of duplicate of gpg-error.m4 with uses the
# future name of libgpg-error to prepare for a smooth migration in
# some distant time.
dnl AM_PATH_GPGRT([MINIMUM-VERSION,
dnl [ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND ]]])
dnl
dnl Test for libgpgrt and define GPGRT_CFLAGS, GPGRT_LIBS,
dnl GPGRT_MT_CFLAGS, and GPGRT_MT_LIBS. The _MT_ variants are
dnl used for programs requiring real multi thread support.
dnl
dnl If a prefix option is not used, the config script is first
dnl searched in $SYSROOT/bin and then along $PATH. If the used
dnl config script does not match the host specification the script
dnl is added to the gpg_config_script_warn variable.
dnl
AC_DEFUN([AM_PATH_GPGRT],
[ AC_REQUIRE([AC_CANONICAL_HOST])
gpgrt_config_prefix=""
dnl --with-libgpg-error-prefix=PFX is the preferred name for this option,
dnl since that is consistent with how our three siblings use the directory/
dnl package name in --with-$dir_name-prefix=PFX.
AC_ARG_WITH(libgpg-error-prefix,
AC_HELP_STRING([--with-libgpg-error-prefix=PFX],
[prefix where GPG Error is installed (optional)]),
[gpgrt_config_prefix="$withval"])
dnl Accept --with-gpg-error-prefix and make it work the same as
dnl --with-libgpg-error-prefix above, for backwards compatibility,
dnl but do not document this old, inconsistently-named option.
AC_ARG_WITH(gpg-error-prefix,,
[gpgrt_config_prefix="$withval"])
dnl Also accept libgpgrt-prefix
AC_ARG_WITH(libgpgrt-prefix,
AC_HELP_STRING([--with-libgpgrt-prefix=PFX],
[prefix where GPG Runtime is installed (optional)]),
[gpgrt_config_prefix="$withval"])
if test x"${GPGRT_CONFIG}" = x ; then
if test x"${gpgrt_config_prefix}" != x ; then
GPGRT_CONFIG="${gpgrt_config_prefix}/bin/gpgrt-config"
else
case "${SYSROOT}" in
/*)
if test -x "${SYSROOT}/bin/gpgrt-config" ; then
GPGRT_CONFIG="${SYSROOT}/bin/gpgrt-config"
fi
;;
'')
;;
*)
AC_MSG_WARN([Ignoring \$SYSROOT as it is not an absolute path.])
;;
esac
fi
fi
if test -f $libdir/pkgconfig/gpg-error.pc; then
gpgrt_libdir=$libdir
else
if crt1_path=$(${CC:-cc} -print-file-name=crt1.o 2>/dev/null); then
if possible_libdir=$(cd ${crt1_path%/*} && pwd 2>/dev/null); then
if test -f $possible_libdir/pkgconfig/gpg-error.pc; then
gpgrt_libdir=$possible_libdir
fi
fi
fi
fi
if test -n "$gpgrt_libdir"; then
AC_PATH_PROG(GPGRT_CONFIG, gpgrt-config, no)
if test "$GPGRT_CONFIG" != "no"; then
GPGRT_CONFIG="$GPGRT_CONFIG --prefix=$prefix --exec-prefix=$exec_prefix --libdir=$gpgrt_libdir"
fi
fi
min_gpgrt_version=ifelse([$1], ,1.33,$1)
AC_MSG_CHECKING(for GPG Runtime - version >= $min_gpgrt_version)
ok=no
if test x"$GPGRT_CONFIG" != x -a "$GPGRT_CONFIG" != "no" ; then
req_major=`echo $min_gpgrt_version | \
sed 's/\([[0-9]]*\)\.\([[0-9]]*\)/\1/'`
req_minor=`echo $min_gpgrt_version | \
sed 's/\([[0-9]]*\)\.\([[0-9]]*\)/\2/'`
gpgrt_config_version=`$GPGRT_CONFIG --version`
major=`echo $gpgrt_config_version | \
sed 's/\([[0-9]]*\)\.\([[0-9]]*\).*/\1/'`
minor=`echo $gpgrt_config_version | \
sed 's/\([[0-9]]*\)\.\([[0-9]]*\).*/\2/'`
if test "$major" -gt "$req_major"; then
ok=yes
else
if test "$major" -eq "$req_major"; then
if test "$minor" -ge "$req_minor"; then
ok=yes
fi
fi
fi
fi
if test $ok = yes; then
GPGRT_CFLAGS=`$GPGRT_CONFIG --cflags`
GPGRT_LIBS=`$GPGRT_CONFIG --libs`
GPGRT_MT_CFLAGS=`$GPGRT_CONFIG --variable=mtcflags 2>/dev/null`
GPGRT_MT_CFLAGS="$GPGRT_CFLAGS${GPGRT_CFLAGS:+ }$GPGRT_MT_CFLAGS"
GPGRT_MT_LIBS=`$GPGRT_CONFIG --variable=mtlibs 2>/dev/null`
GPGRT_MT_LIBS="$GPGRT_LIBS${GPGRT_LIBS:+ }$GPGRT_MT_LIBS"
AC_MSG_RESULT([yes ($gpgrt_config_version)])
ifelse([$2], , :, [$2])
gpgrt_config_host=`$GPGRT_CONFIG --variable=host 2>/dev/null || echo none`
if test x"$gpgrt_config_host" != xnone ; then
if test x"$gpgrt_config_host" != x"$host" ; then
AC_MSG_WARN([[
***
*** The config script $GPGRT_CONFIG was
*** built for $gpgrt_config_host and thus may not match the
*** used host $host.
*** You may want to use the configure option --with-libgpgrt-prefix
*** to specify a matching config script or use \$SYSROOT.
***]])
gpg_config_script_warn="$gpg_config_script_warn libgpgrt"
fi
fi
else
GPGRT_CFLAGS=""
GPGRT_LIBS=""
GPGRT_MT_CFLAGS=""
GPGRT_MT_LIBS=""
AC_MSG_RESULT(no)
ifelse([$3], , :, [$3])
fi
AC_SUBST(GPGRT_CFLAGS)
AC_SUBST(GPGRT_LIBS)
AC_SUBST(GPGRT_MT_CFLAGS)
AC_SUBST(GPGRT_MT_LIBS)
])
|
