libltdl uses LIBOBJS, which leak out into a parent project if both

share the same configure.ac.  Libtool itself doesn't compile any
code, so it is okay to do it during bootstrap, but other projects
need to treat libltdl as a configurable subproject to keep their
respective LIBOBJS separate:

* libltdl/configure.ac: New file, based on configure.ac.
* libltdl/Makefile.am (AC_LOCAL_AMFLAGS): Use our own m4
directory.
(ltdldata_DATA): List *all* the files that libtoolize --ltdl will
install.

1 files changed, 92 insertions, 0 deletions

diff --git a/libltdl/configure.ac b/libltdl/configure.ac
new file mode 100644
index 00000000..e19c09eb
--- /dev/null
+++ b/libltdl/configure.ac
@@ -0,0 +1,92 @@
+## Process this file with autoconf to create configure. -*- autoconf -*-
+# Copyright (C) 2004 Free Software Foundation, Inc.
+#
+# This program is free software; you can redistribute it and/or modify
+# it under the terms of the GNU General Public License as published by
+# the Free Software Foundation; either version 2 of the License, or
+# (at your option) any later version.
+#
+# This program is distributed in the hope that it will be useful,
+# but WITHOUT ANY WARRANTY; without even the implied warranty of
+# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+# GNU General Public License for more details.
+#
+# You should have received a copy of the GNU General Public License
+# along with this program; if not, write to the Free Software
+# Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
+# 02111-1307  USA
+
+# This configure.ac is not used at all by the libtool bootstrap, but
+# is copied to the ltdl subdirectory if you libtoolize --ltdl your own
+# project.  Adding AC_WITH_LTDL to your project configure.ac will then
+# configure this directory if your user doesn't want to use the installed
+# libltdl.
+
+AC_PREREQ(2.57)
+
+
+## ------------------------ ##
+## Autoconf initialisation. ##
+## ------------------------ ##
+AC_INIT([libltdl], [1.5a], [bug-libtool@gnu.org])
+AC_CONFIG_HEADERS([config.h:config-h.in])
+AC_CONFIG_SRCDIR([ltdl.c])
+AC_CONFIG_AUX_DIR([config])
+AC_CONFIG_MACRO_DIR([m4])
+
+
+## ---------------------------------------- ##
+## Display a configure time version banner. ##
+## ---------------------------------------- ##
+
+# This is a sanity check so we can see which version is used in bug reports.
+# It is assumed that we only want to see the date extension for cvs libtool
+# versions (i.e. "odd" letters) and not actual alpha releases.
+TIMESTAMP=
+case $lt_alpha in
+  [[acegikmoqsuwy]])
+    TIMESTAMP=`${CONFIG_SHELL} ${ac_aux_dir}/mkstamp < ${srcdir}/ChangeLog`
+    AS_BOX([Configuring AC_PACKAGE_TARNAME (Build:$TIMESTAMP) AC_PACKAGE_VERSION])
+    echo
+    ;;
+esac
+AC_SUBST([TIMESTAMP])
+
+
+## ------------------------ ##
+## Automake Initialisation. ##
+## ------------------------ ##
+
+AM_INIT_AUTOMAKE([gnits])
+
+## ------------------------------- ##
+## Libtool specific configuration. ##
+## ------------------------------- ##
+pkgdatadir='${datadir}'"/${PACKAGE}"
+
+
+## ---------------- ##
+## compiler checks. ##
+## ---------------- ##
+
+# Use the specified CC and LD
+AC_PROG_CC
+AC_EXEEXT
+AC_PROG_LD
+AC_PROG_NM
+AC_PROG_LN_S
+
+
+## ----------------------- ##
+## Libtool initialisation. ##
+## ----------------------- ##
+LT_INIT([dlopen win32-dll])
+AC_LIBLTDL_CONVENIENCE
+AC_LIB_LTDL
+
+
+## -------- ##
+## Outputs. ##
+## -------- ##
+AC_CONFIG_FILES([Makefile])
+AC_OUTPUT