1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
|
// RUN: mlir-opt %s --test-transform-dialect-interpreter --split-input-file -canonicalize | FileCheck %s
// This is a simple tile-and-fuse example with a single fusion group.
module {
// CHECK: func @foo
// CHECK: scf.forall {{.*}} {
// CHECK: linalg.fill
// CHECK: linalg.matmul
// CHECK: linalg.generic
// CHECK: }
func.func @foo(%A: tensor<?x?xf32>, %B: tensor<?x?xf32>, %C: tensor<?xf32>,
%D: tensor<?x?xf32>, %sz0: index, %sz1: index)
-> tensor<?x?xf32>
{
%cst = arith.constant 0.000000e+00 : f32
%5 = linalg.fill
{__producer__}
ins(%cst : f32)
outs(%D : tensor<?x?xf32>) -> tensor<?x?xf32>
%6 = linalg.matmul
{__producer__}
ins(%A, %B : tensor<?x?xf32>, tensor<?x?xf32>)
outs(%5 : tensor<?x?xf32>) -> tensor<?x?xf32>
%7 = linalg.generic
{__root__,
indexing_maps = [affine_map<(d0, d1) -> (d0)>,
affine_map<(d0, d1) -> (d0, d1)>,
affine_map<(d0, d1) -> (d0, d1)>],
iterator_types = ["parallel", "parallel"]
}
ins(%C, %6 : tensor<?xf32>, tensor<?x?xf32>)
outs(%D : tensor<?x?xf32>) {
^bb0(%arg2: f32, %arg3: f32, %arg4: f32):
%16 = arith.maxf %arg3, %cst : f32
%17 = arith.cmpf ogt, %arg2, %cst : f32
%18 = arith.select %17, %cst, %16 : f32
linalg.yield %18 : f32
} -> tensor<?x?xf32>
return %7 : tensor<?x?xf32>
}
transform.sequence failures(propagate) {
^bb1(%arg1: !pdl.operation):
// Find the root and all producers.
%root = transform.structured.match attributes{"__root__"} in %arg1 : (!pdl.operation) -> !pdl.operation
%producers = transform.structured.match attributes{"__producer__"} in %arg1 : (!pdl.operation) -> !pdl.operation
// Tile the root.
%forall_op, %tiled_op = transform.structured.tile_to_forall_op %root num_threads [10, 20]
// Fuse all producers.
transform.structured.fuse_into_containing_op %producers into %forall_op
}
}
// -----
// Inverse the order of the payload ops passed to the tile_to_forall_op
// op. Fusion should still work.
module {
// CHECK: func @foo
// CHECK: scf.forall {{.*}} {
// CHECK: linalg.fill
// CHECK: linalg.matmul
// CHECK: linalg.generic
// CHECK: }
func.func @foo(%A: tensor<?x?xf32>, %B: tensor<?x?xf32>, %C: tensor<?xf32>,
%D: tensor<?x?xf32>, %sz0: index, %sz1: index)
-> tensor<?x?xf32>
{
%cst = arith.constant 0.000000e+00 : f32
%5 = linalg.fill
{__producer__}
ins(%cst : f32)
outs(%D : tensor<?x?xf32>) -> tensor<?x?xf32>
%6 = linalg.matmul
{__producer__}
ins(%A, %B : tensor<?x?xf32>, tensor<?x?xf32>)
outs(%5 : tensor<?x?xf32>) -> tensor<?x?xf32>
%7 = linalg.generic
{__root__,
indexing_maps = [affine_map<(d0, d1) -> (d0)>,
affine_map<(d0, d1) -> (d0, d1)>,
affine_map<(d0, d1) -> (d0, d1)>],
iterator_types = ["parallel", "parallel"]
}
ins(%C, %6 : tensor<?xf32>, tensor<?x?xf32>)
outs(%D : tensor<?x?xf32>) {
^bb0(%arg2: f32, %arg3: f32, %arg4: f32):
%16 = arith.maxf %arg3, %cst : f32
%17 = arith.cmpf ogt, %arg2, %cst : f32
%18 = arith.select %17, %cst, %16 : f32
linalg.yield %18 : f32
} -> tensor<?x?xf32>
return %7 : tensor<?x?xf32>
}
transform.sequence failures(propagate) {
^bb1(%arg1: !pdl.operation):
// Find the root and all producers.
%root = transform.structured.match attributes{"__root__"} in %arg1 : (!pdl.operation) -> !pdl.operation
%producers = transform.structured.match attributes{"__producer__"} in %arg1 : (!pdl.operation) -> !pdl.operation
%reversed_producers = transform.test_reverse_payload_ops %producers
// Tile the root.
%forall_op, %tiled_op = transform.structured.tile_to_forall_op %root num_threads [10, 20]
// Fuse all producers.
transform.structured.fuse_into_containing_op %reversed_producers into %forall_op
}
}
|
