blob: ea91e6277efac00a61c300d188dcc9895d190537 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
|
<?xml version='1.0'?>
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:amqp="http://amqp.org">
<xsl:import href="code_utils.xsl"/>
<!--
=============================
Template: server-operations-h
=============================
Template to generate the AMQP_ServerHandler virtual class. This is the pure
virtual class from which the AMQP_Client and AMQP_ServerHandlerImpl classes
are derived.
-->
<xsl:template match="amqp" mode="server-operations-h">
<xsl:param name="domain-cpp-table"/>
<xsl:result-document href="AMQP_ServerOperations.h" format="textFormat">
<xsl:value-of select="amqp:copyright()"/>
<xsl:text>
#ifndef _AMQP_ServerOperations_
#define _AMQP_ServerOperations_
#include "AMQP_Constants.h"
#include "qpid/framing/FieldTable.h"
namespace qpid {
namespace framing {
class AMQP_ServerOperations
{
public:
AMQP_ServerOperations() {}
virtual ~AMQP_ServerOperations() {}
inline u_int16_t getAmqpMajor() { return (u_int16_t)</xsl:text><xsl:value-of select="@major"/><xsl:text>; }
inline u_int16_t getAmqpMinor() { return (u_int16_t)</xsl:text><xsl:value-of select="@minor"/><xsl:text>; }

</xsl:text>
<!-- Inner classes -->
<xsl:for-each select="class">
<xsl:variable name="class" select="concat(amqp:cpp-class-name(@name), 'Handler')"/>
<!-- Inner class documentation & rules -->
<xsl:if test="doc">
<xsl:text>
/**
===== Class: </xsl:text><xsl:value-of select="$class"/><xsl:text> =====
</xsl:text>
<xsl:value-of select="amqp:process-docs(doc)"/>
<xsl:text>*/
</xsl:text>
</xsl:if>
<!-- Inner class definition -->
<xsl:text> class </xsl:text><xsl:value-of select="$class"/><xsl:text>
{
public:
/* Constructors and destructors */
</xsl:text><xsl:value-of select="$class"/><xsl:text>() {}
virtual ~</xsl:text><xsl:value-of select="$class"/><xsl:text>() {}
/* Protocol methods */
</xsl:text>
<!-- Inner class methods (only if the chassis is set to "server") -->
<xsl:for-each select="method">
<xsl:if test="chassis[@name='server']">
<xsl:variable name="method" select="amqp:cpp-name(@name)"/>
<!-- Inner class method documentation & rules -->
<xsl:if test="doc">
<xsl:text>
/**
----- Method: </xsl:text><xsl:value-of select="$class"/><xsl:text>.</xsl:text>
<xsl:value-of select="@name"/><xsl:text> -----
</xsl:text>
<xsl:value-of select="amqp:process-docs(doc)"/>
<xsl:text>*/
</xsl:text>
</xsl:if>
<xsl:for-each select="rule">
<xsl:text>
/**
</xsl:text>
<xsl:text>Rule "</xsl:text><xsl:value-of select="@name"/><xsl:text>":
</xsl:text>
<xsl:value-of select="amqp:process-docs(doc)"/>
<xsl:text>*/
</xsl:text>
</xsl:for-each>
<!-- Inner class method definition -->
<xsl:text> virtual void </xsl:text><xsl:value-of select="$method"/>
<xsl:text>( u_int16_t channel</xsl:text>
<!-- Inner class method parameter definition -->
<xsl:if test="field">
<xsl:text>,
 </xsl:text>
<xsl:for-each select="field">
<xsl:variable name="domain-cpp-type" select="amqp:cpp-lookup(@domain, $domain-cpp-table)"/>
<xsl:value-of select="concat($domain-cpp-type, amqp:cpp-arg-ref($domain-cpp-type), ' ', amqp:cpp-name(@name))"/>
<xsl:if test="position()!=last()">
<xsl:text>,
 </xsl:text>
</xsl:if>
</xsl:for-each>
</xsl:if>
<xsl:text> ) = 0;
</xsl:text>
</xsl:if>
</xsl:for-each>
<xsl:text> }; /* class </xsl:text><xsl:value-of select="$class"/><xsl:text> */
</xsl:text>
</xsl:for-each>
<xsl:text>
</xsl:text>
<xsl:for-each select="class">
<xsl:variable name="class" select="concat(amqp:cpp-class-name(@name), 'Handler')"/>
<xsl:text> virtual AMQP_ServerOperations::</xsl:text>
<xsl:value-of select="$class"/><xsl:text>* get</xsl:text><xsl:value-of select="$class"/>
<xsl:text>() = 0;
</xsl:text>
</xsl:for-each>
<xsl:text>}; /* class AMQP_ServerOperations */
} /* namespace framing */
} /* namespace qpid */
#endif
</xsl:text>
</xsl:result-document>
</xsl:template>
</xsl:stylesheet>
|