RIP QMake build

We have been supported CMake build for quite some time
so users should have plenty of time to adapt.

Ubuntu, Brew and macports also use CMake for building QBS.

Change-Id: Ib78177f4a7ca8cdea1a2f3a8eac8bfe804674f32
Reviewed-by: Christian Kandeler <christian.kandeler@qt.io>

4 files changed, 0 insertions, 123 deletions

diff --git a/doc/doc.pri b/doc/doc.pri
deleted file mode 100644
index cd05a9450..000000000
--- a/doc/doc.pri
+++ /dev/null
@@ -1,18 +0,0 @@
-include(../src/install_prefix.pri)
-
-include(doc_shared.pri)
-
-DOC_OUTDIR_POSTFIX = /html
-DOC_HTML_INSTALLDIR = $$QBS_INSTALL_PREFIX/share/doc/qbs
-DOC_QCH_OUTDIR = $$OUT_PWD/doc
-DOC_QCH_INSTALLDIR = $$QBS_INSTALL_PREFIX/share/doc/qbs
-
-include(doc_targets.pri)
-
-fixnavi.commands = \
-    cd $$shell_path($$PWD) && \
-    perl fixnavi.pl -Dqcmanual -Dqtquick \
-        qbs.qdoc
-QMAKE_EXTRA_TARGETS += fixnavi
-
-include(man/man.pri)
diff --git a/doc/doc_shared.pri b/doc/doc_shared.pri
deleted file mode 100644
index 3e4eccf48..000000000
--- a/doc/doc_shared.pri
+++ /dev/null
@@ -1,14 +0,0 @@
-include(../qbs_version.pri)
-
-qbsdoc_version.name = QBS_VERSION
-qbsdoc_version.value = $$QBS_VERSION
-qbsdoc_versiontag.name = QBS_VERSION_TAG
-qbsdoc_versiontag.value = $$replace(QBS_VERSION, "[-.]", )
-qbsdoc_qtdocs.name = QT_INSTALL_DOCS
-qbsdoc_qtdocs.value = $$[QT_INSTALL_DOCS/src]
-QDOC_ENV += qbsdoc_version qbsdoc_versiontag qbsdoc_qtdocs
-
-build_online_docs: \
-    DOC_FILES += $$PWD/qbs-online.qdocconf
-else: \
-    DOC_FILES += $$PWD/qbs.qdocconf
diff --git a/doc/doc_targets.pri b/doc/doc_targets.pri
deleted file mode 100644
index 0636be2b5..000000000
--- a/doc/doc_targets.pri
+++ /dev/null
@@ -1,86 +0,0 @@
-# Creates targets for building documentation
-# (adapted from qt_docs.prf)
-#
-# Usage: Define variables (details below) and include this pri file afterwards.
-#
-# QDOC_ENV            - environment variables to set for the qdoc call (see example below)
-# DOC_INDEX_PATHS     - list of paths where qdoc should search for index files of dependent
-#                       modules (Qt index path is included by default)
-# DOC_FILES           - list of qdocconf files
-# DOC_OUTDIR_POSTFIX  - html is generated in $$OUT_PWD/<qdocconf_name>$$DOC_OUTDIR_POSTFIX
-# DOC_HTML_INSTALLDIR - path were to install the directory of html files
-# DOC_QCH_OUTDIR      - path where to generated the qch files
-# DOC_QCH_INSTALLDIR  - path where to install the qch files
-# DOC_TARGET_PREFIX   - prefix for generated target names
-#
-# Example for QDOC_ENV:
-# ver.name = VERSION
-# ver.value = 1.0.2
-# foo.name = FOO
-# foo.value = foo
-# QDOC_ENV = ver foo
-
-isEmpty(DOC_FILES): error("Set DOC_FILES before including doc_targets.pri")
-isEmpty(DOC_HTML_INSTALLDIR): error("Set DOC_HTML_INSTALLDIR before including doc_targets.pri")
-isEmpty(DOC_QCH_OUTDIR): error("Set DOC_QCH_OUTDIR before including doc_targets.pri")
-isEmpty(DOC_QCH_INSTALLDIR): error("Set DOC_QCH_INSTALLDIR before including doc_targets.pri")
-
-QT_TOOL_ENV = $$QDOC_ENV
-qtPrepareTool(QDOC, qdoc)
-QT_TOOL_ENV =
-
-!build_online_docs: qtPrepareTool(QHELPGENERATOR, qhelpgenerator)
-
-DOCS_BASE_OUTDIR = $$OUT_PWD/doc
-DOC_INDEXES += -indexdir $$shell_quote($$[QT_INSTALL_DOCS])
-for (index_path, DOC_INDEX_PATHS): \
-    DOC_INDEXES += -indexdir $$shell_quote($$index_path)
-
-DTP = $$DOC_TARGET_PREFIX
-for (doc_file, DOC_FILES) {
-    !exists($$doc_file): error("Cannot find documentation specification file $$doc_file")
-    DOC_TARGET = $$replace(doc_file, ^(.*/)?(.*)\\.qdocconf$, \\2)
-    DOC_TARGETDIR = $$DOC_TARGET
-    DOC_OUTPUTDIR = $${DOCS_BASE_OUTDIR}/$${DOC_TARGETDIR}$${DOC_OUTDIR_POSTFIX}
-
-    $${DTP}html_docs_$${DOC_TARGET}.commands = $$QDOC -outputdir $$shell_quote($$DOC_OUTPUTDIR) $$doc_file $$DOC_INDEXES
-    QMAKE_EXTRA_TARGETS += $${DTP}html_docs_$${DOC_TARGET}
-
-    !isEmpty($${DTP}html_docs.commands): $${DTP}html_docs.commands += &&
-    $${DTP}html_docs.commands += $$eval($${DTP}html_docs_$${DOC_TARGET}.commands)
-
-    $${DTP}inst_html_docs.files += $$DOC_OUTPUTDIR
-
-    !build_online_docs {
-        $${DTP}qch_docs_$${DOC_TARGET}.commands = $$QHELPGENERATOR $$shell_quote($$DOC_OUTPUTDIR/$${DOC_TARGET}.qhp) -o $$shell_quote($$DOC_QCH_OUTDIR/$${DOC_TARGET}.qch)
-        $${DTP}qch_docs_$${DOC_TARGET}.depends = $${DTP}html_docs_$${DOC_TARGET}
-        QMAKE_EXTRA_TARGETS += $${DTP}qch_docs_$${DOC_TARGET}
-
-        !isEmpty($${DTP}qch_docs.commands): $${DTP}qch_docs.commands += &&
-        $${DTP}qch_docs.commands += $$eval($${DTP}qch_docs_$${DOC_TARGET}.commands)
-
-        $${DTP}inst_qch_docs.files += $$DOC_QCH_OUTDIR/$${DOC_TARGET}.qch
-    }
-}
-
-!build_online_docs {
-    $${DTP}qch_docs.depends = $${DTP}html_docs
-    $${DTP}inst_qch_docs.path = $$DOC_QCH_INSTALLDIR
-    $${DTP}inst_qch_docs.CONFIG += no_check_exist no_default_install no_build
-    install_$${DTP}docs.depends = install_$${DTP}inst_qch_docs
-    $${DTP}docs.depends = $${DTP}qch_docs
-    INSTALLS += $${DTP}inst_qch_docs
-    QMAKE_EXTRA_TARGETS += $${DTP}qch_docs install_$${DTP}docs
-} else {
-    $${DTP}docs.depends = $${DTP}html_docs
-}
-
-$${DTP}inst_html_docs.path = $$DOC_HTML_INSTALLDIR
-$${DTP}inst_html_docs.CONFIG += no_check_exist no_default_install directory
-INSTALLS += $${DTP}inst_html_docs
-install_$${DTP}docs.depends += install_$${DTP}inst_html_docs
-
-QMAKE_EXTRA_TARGETS += $${DTP}html_docs $${DTP}docs
-
-unset(DTP)
-
diff --git a/doc/man/man.pri b/doc/man/man.pri
deleted file mode 100644
index 2e29f9112..000000000
--- a/doc/man/man.pri
+++ /dev/null
@@ -1,5 +0,0 @@
-qbs_no_man_install: return()
-
-man.files = $$PWD/qbs.1
-man.path = $${QBS_INSTALL_PREFIX}/share/man/man1
-INSTALLS += man