blob: af042d055416c6fde5613f9f01cfc755ef559891 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
|
# Copyright (c) 2013 The Chromium Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.
# This header file defines the "sysroot" variable which is the absolute path
# of the sysroot. If no sysroot applies, the variable will be an empty string.
import("//build/config/chrome_build.gni")
declare_args() {
# The absolute path of the sysroot that is applied when compiling using
# the target toolchain.
target_sysroot = ""
# The absolute path to directory containing sysroots for linux 32 and 64bit
target_sysroot_dir = ""
use_sysroot = true
# TODO(tonikitoo): Remove this arg when wheezy is finally dropped and we
# can just use debian/jessie everywhere by default. crbug.com/564904.
use_jessie_sysroot = false
}
if (is_linux && target_sysroot_dir != "") {
if (current_cpu == "x64") {
sysroot = target_sysroot_dir + "/wheezy-x64"
} else if (current_cpu == "x86") {
sysroot = target_sysroot_dir + "/wheezy-ia32"
}
} else if (current_os == target_os && current_cpu == target_cpu &&
current_toolchain == default_toolchain && target_sysroot != "") {
sysroot = target_sysroot
} else if (is_android) {
import("//build/config/android/config.gni")
if (current_cpu == "x86") {
sysroot = "$android_ndk_root/$x86_android_sysroot_subdir"
} else if (current_cpu == "arm") {
sysroot = "$android_ndk_root/$arm_android_sysroot_subdir"
} else if (current_cpu == "mipsel") {
sysroot = "$android_ndk_root/$mips_android_sysroot_subdir"
} else if (current_cpu == "x64") {
sysroot = "$android_ndk_root/$x86_64_android_sysroot_subdir"
} else if (current_cpu == "arm64") {
sysroot = "$android_ndk_root/$arm64_android_sysroot_subdir"
} else if (current_cpu == "mips64el") {
sysroot = "$android_ndk_root/$mips64_android_sysroot_subdir"
} else {
sysroot = ""
}
} else if (is_linux && use_sysroot) {
# By default build against a sysroot image downloaded from Cloud Storage
# during gclient runhooks.
if (is_chromeos) {
# Regular ChromeOS builds use custom sysroots, but desktop ChromeOS (where
# we're building linux desktop binaries but using the ChromeOS UI and
# functionality where possible) needs to run on the buliders, which are
# running precise. The precise build has a different set of dependencies
# from the wheezy build, so we cannot use the wheezy sysroot.
sysroot = "//build/linux/ubuntu_precise_amd64-sysroot"
} else {
if (current_cpu == "x64") {
sysroot = "//build/linux/debian_wheezy_amd64-sysroot"
if (use_jessie_sysroot) {
sysroot = "//build/linux/debian_jessie_amd64-sysroot"
}
} else if (current_cpu == "x86") {
sysroot = "//build/linux/debian_wheezy_i386-sysroot"
} else if (current_cpu == "mipsel") {
sysroot = "//build/linux/debian_wheezy_mips-sysroot"
} else if (current_cpu == "arm") {
sysroot = "//build/linux/debian_wheezy_arm-sysroot"
} else if (current_cpu == "arm64") {
sysroot = "//build/linux/debian_jessie_arm64-sysroot"
} else {
# Any other builds don't use a sysroot.
sysroot = ""
}
}
if (sysroot != "") {
# Our sysroot images only contains gcc 4.6 headers, but chromium requires
# gcc 4.9. Clang is able to detect and work with the 4.6 headers while
# gcc is not. This check can be removed if we ever update to a more modern
# sysroot.
assert(is_clang, "sysroot images require clang (try use_sysroot=false)")
_script_arch = current_cpu
if (_script_arch == "x86") {
_script_arch = "i386"
} else if (_script_arch == "x64") {
_script_arch = "amd64"
}
assert(
exec_script("//build/dir_exists.py",
[ rebase_path(sysroot) ],
"string") == "True",
"Missing sysroot ($sysroot). To fix, run: build/linux/sysroot_scripts/install-sysroot.py --arch=$_script_arch")
}
} else if (is_mac) {
import("//build/config/mac/mac_sdk.gni")
sysroot = mac_sdk_path
} else if (is_ios) {
import("//build/config/ios/ios_sdk.gni")
sysroot = ios_sdk_path
} else {
sysroot = ""
}
|
