blob: 4efb8aaa01e71d58ab9c032e9685ac8d1b694a1c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
|
# Copyright 2014 The Chromium Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.
import("//build/config/python.gni")
import("//tools/grit/grit_rule.gni")
# generate_about_tracing puts its files in this directory
tracing_gen_dir = "$root_gen_dir/content/browser/tracing"
# The script just writes filename with no dirs to the .grd, so we always need
# this file to be in the same directory as the inputs.
tracing_grd = "$tracing_gen_dir/tracing_resources.grd"
# TODO(crbug.com/1112471): Get this to run cleanly under Python 3.
python2_action("generate_tracing_grd") {
visibility = [ ":*" ] # Depend on ":resources" to get this.
script = "generate_trace_viewer_grd.py"
input_pages = [
"$tracing_gen_dir/about_tracing.html",
"$tracing_gen_dir/about_tracing.js",
]
inputs = input_pages
outputs = [ tracing_grd ]
args = rebase_path(input_pages, target_gen_dir) + [
"--output",
rebase_path(tracing_grd, root_build_dir),
]
deps = [ "//third_party/catapult/tracing:generate_about_tracing" ]
}
grit("resources") {
source = tracing_grd
# Required because the .grd is generated.
enable_input_discovery_for_gn_analyze = false
outputs = [
"grit/tracing_resources.h",
"tracing_resources.pak",
]
deps = [ ":generate_tracing_grd" ]
}
|
