blob: d45d0455ed12973b00bd065871c565a030ffae5d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
|
# -------------------------------------------------------------------
# Win32 specific defaults
#
# See 'Tools/qmake/README' for an overview of the build system
# -------------------------------------------------------------------
# Pick up 3rdparty libraries from INCLUDE/LIB just like with MSVC
win32-g++* {
TMPPATH = $$quote($$(INCLUDE))
QMAKE_INCDIR_POST += $$split(TMPPATH,";")
TMPPATH = $$quote($$(LIB))
QMAKE_LIBDIR_POST += $$split(TMPPATH,";")
}
# Disable a few warnings. The same warnings are also disabled
# in WebKitLibraries/win/tools/vsprops/common.vsprops
win32-msvc*|wince*: QMAKE_CXXFLAGS += -wd4291 -wd4344 -wd4396 -wd4503 -wd4800 -wd4819 -wd4996
win32-icc: QMAKE_CXXFLAGS += -wd873
load(default_post)
# When creating the target DLL, extract exporting linker directives from
# all static libraries we're linking into the DLL and make sure they are
# also exported from the DLL.
shared:contains(TEMPLATE, lib) {
for(target, POST_TARGETDEPS) {
libdep = $$find(target, .*\\.lib)
exists($$libdep): LIBSWITHEXPORTS += $$libdep
}
}
!isEmpty(LIBSWITHEXPORTS) {
exportgen.input = LIBSWITHEXPORTS
exportgen.output = exports_${QMAKE_FILE_BASE}.cpp
exportgen.commands = python $${ROOT_WEBKIT_DIR}$${QMAKE_DIR_SEP}Tools$${QMAKE_DIR_SEP}Scripts$${QMAKE_DIR_SEP}generate-win32-export-forwards ${QMAKE_FILE_IN} ${QMAKE_FILE_OUT}
exportgen.variable_out = SOURCES
QMAKE_EXTRA_COMPILERS += exportgen
}
# To ensure the Qt export macros are set to dllexport
contains(TEMPLATE, lib):!contains(QT, webkit): DEFINES += QT_MAKEDLL
|
