1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
|
%% The contents of this file are subject to the Mozilla Public License
%% Version 1.1 (the "License"); you may not use this file except in
%% compliance with the License. You may obtain a copy of the License
%% at https://www.mozilla.org/MPL/
%%
%% Software distributed under the License is distributed on an "AS IS"
%% basis, WITHOUT WARRANTY OF ANY KIND, either express or implied. See
%% the License for the specific language governing rights and
%% limitations under the License.
%%
%% The Original Code is RabbitMQ.
%%
%% The Initial Developer of the Original Code is GoPivotal, Inc.
%% Copyright (c) 2007-2020 Pivotal Software, Inc. All rights reserved.
%%
%% We use a gen_server simply so that during the terminate/2 call
%% (i.e., during shutdown), we can sync/flush the dets table to disk.
-module(rabbit_recovery_terms).
-behaviour(gen_server).
-export([start/1, stop/1, store/3, read/2, clear/1]).
-export([start_link/1]).
-export([init/1, handle_call/3, handle_cast/2, handle_info/2,
terminate/2, code_change/3]).
-export([upgrade_recovery_terms/0, persistent_bytes/0]).
-export([open_global_table/0, close_global_table/0,
read_global/1, delete_global_table/0]).
-export([open_table/1, close_table/1]).
-rabbit_upgrade({upgrade_recovery_terms, local, []}).
-rabbit_upgrade({persistent_bytes, local, [upgrade_recovery_terms]}).
-include("rabbit.hrl").
%%----------------------------------------------------------------------------
-spec start(rabbit_types:vhost()) -> rabbit_types:ok_or_error(term()).
start(VHost) ->
case rabbit_vhost_sup_sup:get_vhost_sup(VHost) of
{ok, VHostSup} ->
{ok, _} = supervisor2:start_child(
VHostSup,
{?MODULE,
{?MODULE, start_link, [VHost]},
transient, ?WORKER_WAIT, worker,
[?MODULE]});
%% we can get here if a vhost is added and removed concurrently
%% e.g. some integration tests do it
{error, {no_such_vhost, VHost}} ->
rabbit_log:error("Failed to start a recovery terms manager for vhost ~s: vhost no longer exists!",
[VHost])
end,
ok.
-spec stop(rabbit_types:vhost()) -> rabbit_types:ok_or_error(term()).
stop(VHost) ->
case rabbit_vhost_sup_sup:get_vhost_sup(VHost) of
{ok, VHostSup} ->
case supervisor:terminate_child(VHostSup, ?MODULE) of
ok -> supervisor:delete_child(VHostSup, ?MODULE);
E -> E
end;
%% see start/1
{error, {no_such_vhost, VHost}} ->
rabbit_log:error("Failed to stop a recovery terms manager for vhost ~s: vhost no longer exists!",
[VHost]),
ok
end.
-spec store(rabbit_types:vhost(), file:filename(), term()) -> rabbit_types:ok_or_error(term()).
store(VHost, DirBaseName, Terms) ->
dets:insert(VHost, {DirBaseName, Terms}).
-spec read(rabbit_types:vhost(), file:filename()) -> rabbit_types:ok_or_error2(term(), not_found).
read(VHost, DirBaseName) ->
case dets:lookup(VHost, DirBaseName) of
[{_, Terms}] -> {ok, Terms};
_ -> {error, not_found}
end.
-spec clear(rabbit_types:vhost()) -> 'ok'.
clear(VHost) ->
try
dets:delete_all_objects(VHost)
%% see start/1
catch _:badarg ->
rabbit_log:error("Failed to clear recovery terms for vhost ~s: table no longer exists!",
[VHost]),
ok
end,
flush(VHost).
start_link(VHost) ->
gen_server:start_link(?MODULE, [VHost], []).
%%----------------------------------------------------------------------------
upgrade_recovery_terms() ->
open_global_table(),
try
QueuesDir = filename:join(rabbit_mnesia:dir(), "queues"),
Dirs = case rabbit_file:list_dir(QueuesDir) of
{ok, Entries} -> Entries;
{error, _} -> []
end,
[begin
File = filename:join([QueuesDir, Dir, "clean.dot"]),
case rabbit_file:read_term_file(File) of
{ok, Terms} -> ok = store_global_table(Dir, Terms);
{error, _} -> ok
end,
file:delete(File)
end || Dir <- Dirs],
ok
after
close_global_table()
end.
persistent_bytes() -> dets_upgrade(fun persistent_bytes/1).
persistent_bytes(Props) -> Props ++ [{persistent_bytes, 0}].
dets_upgrade(Fun)->
open_global_table(),
try
ok = dets:foldl(fun ({DirBaseName, Terms}, Acc) ->
store_global_table(DirBaseName, Fun(Terms)),
Acc
end, ok, ?MODULE),
ok
after
close_global_table()
end.
open_global_table() ->
File = filename:join(rabbit_mnesia:dir(), "recovery.dets"),
{ok, _} = dets:open_file(?MODULE, [{file, File},
{ram_file, true},
{auto_save, infinity}]),
ok.
close_global_table() ->
try
dets:sync(?MODULE),
dets:close(?MODULE)
%% see clear/1
catch _:badarg ->
rabbit_log:error("Failed to clear global recovery terms: table no longer exists!",
[]),
ok
end.
store_global_table(DirBaseName, Terms) ->
dets:insert(?MODULE, {DirBaseName, Terms}).
read_global(DirBaseName) ->
case dets:lookup(?MODULE, DirBaseName) of
[{_, Terms}] -> {ok, Terms};
_ -> {error, not_found}
end.
delete_global_table() ->
file:delete(filename:join(rabbit_mnesia:dir(), "recovery.dets")).
%%----------------------------------------------------------------------------
init([VHost]) ->
process_flag(trap_exit, true),
open_table(VHost),
{ok, VHost}.
handle_call(Msg, _, State) -> {stop, {unexpected_call, Msg}, State}.
handle_cast(Msg, State) -> {stop, {unexpected_cast, Msg}, State}.
handle_info(_Info, State) -> {noreply, State}.
terminate(_Reason, VHost) ->
close_table(VHost).
code_change(_OldVsn, State, _Extra) ->
{ok, State}.
%%----------------------------------------------------------------------------
-spec open_table(vhost:name()) -> rabbit_types:ok_or_error(any()).
open_table(VHost) ->
open_table(VHost, 10).
-spec open_table(vhost:name(), non_neg_integer()) -> rabbit_types:ok_or_error(any()).
open_table(VHost, RetriesLeft) ->
VHostDir = rabbit_vhost:msg_store_dir_path(VHost),
File = filename:join(VHostDir, "recovery.dets"),
Opts = [{file, File},
{ram_file, true},
{auto_save, infinity}],
case dets:open_file(VHost, Opts) of
{ok, _} -> ok;
{error, Error} ->
case RetriesLeft of
0 ->
{error, Error};
N when is_integer(N) ->
_ = file:delete(File),
%% Wait before retrying
DelayInMs = 1000,
rabbit_log:warning("Failed to open a recovery terms DETS file at ~p. Will delete it and retry in ~p ms (~p retries left)",
[File, DelayInMs, RetriesLeft]),
timer:sleep(DelayInMs),
open_table(VHost, RetriesLeft - 1)
end
end.
-spec flush(vhost:name()) -> rabbit_types:ok_or_error(any()).
flush(VHost) ->
try
dets:sync(VHost)
%% see clear/1
catch _:badarg ->
rabbit_log:error("Failed to sync recovery terms table for vhost ~s: the table no longer exists!",
[VHost]),
ok
end.
-spec close_table(vhost:name()) -> rabbit_types:ok_or_error(any()).
close_table(VHost) ->
try
ok = flush(VHost),
ok = dets:close(VHost)
%% see clear/1
catch _:badarg ->
rabbit_log:error("Failed to close recovery terms table for vhost ~s: the table no longer exists!",
[VHost]),
ok
end.
|
