install a dbus service file for service activation

20060119073126-25e70-3c8dc6e156c182abd86a020a759eae5c6af20f80.gz

7 files changed, 56 insertions, 3 deletions

diff --git a/Makefile.am b/Makefile.am
index f147ab5..a4996ad 100644
--- a/Makefile.am
+++ b/Makefile.am
@@ -1,3 +1,3 @@
 ACLOCAL_AMFLAGS = -I m4
 
-SUBDIRS = common src test doc xml
+SUBDIRS = common src test doc xml data
diff --git a/configure.ac b/configure.ac
index 3668322..4b7240b 100644
--- a/configure.ac
+++ b/configure.ac
@@ -55,6 +55,11 @@ if test x$have_dbus = xno ; then
     AC_MSG_ERROR([DBus development libraries not found])
 fi
 
+AS_AC_EXPAND(DATADIR, $datadir)
+DBUS_SERVICES_DIR="$DATADIR/dbus-1/services"
+AC_SUBST(DBUS_SERVICES_DIR)
+AC_DEFINE_UNQUOTED(DBUS_SERVICES_DIR, "$DBUS_SERVICES_DIR", [DBus services directory])
+
 dnl Check for libtelepathy
 PKG_CHECK_MODULES(LIBTELEPATHY, [libtelepathy], have_libtelepathy=yes, have_libtelepathy=no)
 
@@ -76,9 +81,11 @@ if test x$have_farsight = xno ; then
 fi
 
 
-AC_OUTPUT( Makefile \
-          doc/Makefile
+AC_OUTPUT( Makefile 
           common/Makefile
+          data/Makefile
+          data/org.freedesktop.Telepathy.VoipEngine.service
+          doc/Makefile
           src/Makefile
           test/Makefile
           test/glib/Makefile
diff --git a/data/.git-darcs-dir b/data/.git-darcs-dir
new file mode 100644
index 0000000..e69de29
--- /dev/null
+++ b/data/.git-darcs-dir
diff --git a/data/Makefile.am b/data/Makefile.am
new file mode 100644
index 0000000..d14e63d
--- /dev/null
+++ b/data/Makefile.am
@@ -0,0 +1,2 @@
+servicedir = $(DBUS_SERVICES_DIR)
+service_DATA = org.freedesktop.Telepathy.VoipEngine.service
diff --git a/data/org.freedesktop.Telepathy.VoipEngine.service.in b/data/org.freedesktop.Telepathy.VoipEngine.service.in
new file mode 100644
index 0000000..afa3ca4
--- /dev/null
+++ b/data/org.freedesktop.Telepathy.VoipEngine.service.in
@@ -0,0 +1,3 @@
+[D-BUS Service]
+Name=org.freedesktop.Telepathy.VoipEngine
+Exec=@EXEC_DIR@/src/telepathy-voip-engine
diff --git a/m4/Makefile.am b/m4/Makefile.am
index b04250a..52aac8f 100644
--- a/m4/Makefile.am
+++ b/m4/Makefile.am
@@ -1,4 +1,5 @@
 EXTRA_DIST = \
 as-compiler-flag.m4 \
 as-version.m4 \
+as-ac-expand.m4 \
 seq-dias.m4
diff --git a/m4/as-ac-expand.m4 b/m4/as-ac-expand.m4
new file mode 100644
index 0000000..0c71173
--- /dev/null
+++ b/m4/as-ac-expand.m4
@@ -0,0 +1,40 @@
+dnl AS_AC_EXPAND(VAR, CONFIGURE_VAR)
+dnl
+dnl example
+dnl AS_AC_EXPAND(SYSCONFDIR, $sysconfdir)
+dnl will set SYSCONFDIR to /usr/local/etc if prefix=/usr/local
+
+AC_DEFUN([AS_AC_EXPAND],
+[
+  EXP_VAR=[$1]
+  FROM_VAR=[$2]
+
+  dnl first expand prefix and exec_prefix if necessary
+  prefix_save=$prefix
+  exec_prefix_save=$exec_prefix
+
+  dnl if no prefix given, then use /usr/local, the default prefix
+  if test "x$prefix" = "xNONE"; then
+    prefix=$ac_default_prefix
+  fi
+  dnl if no exec_prefix given, then use prefix
+  if test "x$exec_prefix" = "xNONE"; then
+    exec_prefix=$prefix
+  fi
+
+  full_var="$FROM_VAR"
+  dnl loop until it doesn't change anymore
+  while true; do
+    new_full_var="`eval echo $full_var`"
+    if test "x$new_full_var"="x$full_var"; then break; fi
+    full_var=$new_full_var
+  done
+
+  dnl clean up
+  full_var=$new_full_var
+  AC_SUBST([$1], "$full_var")
+
+  dnl restore prefix and exec_prefix
+  prefix=$prefix_save
+  exec_prefix=$exec_prefix_save
+])