build: Port to meson build system

meson is a build system focused on speed an ease of use, which
helps speeding up the software development. This patch adds meson
support along autotools.

3 files changed, 82 insertions, 0 deletions

diff --git a/data/icons/meson.build b/data/icons/meson.build
new file mode 100644
index 0000000..6ea08fa
--- /dev/null
+++ b/data/icons/meson.build
@@ -0,0 +1,32 @@
+icon16_data = files(
+  'hicolor/16x16/apps/org.gnome.dfeet.png',
+  'hicolor/16x16/apps/dfeet-method-category.png',
+  'hicolor/16x16/apps/dfeet-method.png',
+  'hicolor/16x16/apps/dfeet-object.png',
+  'hicolor/16x16/apps/dfeet-property-category.png',
+  'hicolor/16x16/apps/dfeet-property.png',
+  'hicolor/16x16/apps/dfeet-signal-category.png',
+  'hicolor/16x16/apps/dfeet-signal.png',
+  'hicolor/16x16/apps/dfeet-icon-default-service.png',
+)
+
+icons = {
+  '16x16': icon16_data,
+  '24x24': 'hicolor/24x24/apps/org.gnome.dfeet.png',
+  '32x32': 'hicolor/32x32/apps/org.gnome.dfeet.png',
+  '48x48': 'hicolor/48x48/apps/org.gnome.dfeet.png',
+  '256x256': 'hicolor/256x256/apps/org.gnome.dfeet.png',
+  'scalable': 'hicolor/scalable/apps/org.gnome.dfeet.svg',
+}
+
+foreach size, data: icons
+  install_data(
+    data,
+    install_dir: df_datadir / 'icons/hicolor' / size / 'apps',
+  )
+endforeach
+
+install_data(
+  'HighContrast/scalable/apps/org.gnome.dfeet.svg',
+  install_dir: df_datadir / 'icons/HighContrast/scalable/apps',
+)
diff --git a/data/meson.build b/data/meson.build
new file mode 100644
index 0000000..2d104fb
--- /dev/null
+++ b/data/meson.build
@@ -0,0 +1,38 @@
+subdir('icons')
+subdir('ui')
+
+desktop_conf = configuration_data()
+desktop_conf.set('PACKAGE', df_name)
+
+desktop = df_namespace + '.desktop'
+
+desktop_in = configure_file(
+  input: desktop + '.in.in',
+  output: '@BASENAME@',
+  configuration: desktop_conf,
+)
+
+custom_target(
+  desktop,
+  input: desktop_in,
+  output: '@BASENAME@',
+  command: intltool_desktop_cmd,
+  install: true,
+  install_dir: df_datadir / 'applications',
+)
+
+appdata = df_namespace + '.appdata.xml'
+
+custom_target(
+  appdata,
+  input: appdata + '.in',
+  output: '@BASENAME@',
+  command: intltool_xml_cmd,
+  install: true,
+  install_dir: df_datadir / 'metainfo',
+)
+
+install_data(
+  df_namespace + '.gschema.xml',
+  install_dir: gio_schemasdir,
+)
diff --git a/data/ui/meson.build b/data/ui/meson.build
new file mode 100644
index 0000000..d7e2621
--- /dev/null
+++ b/data/ui/meson.build
@@ -0,0 +1,12 @@
+ui_data = files(
+  'addconnectiondialog.ui',
+  'bus.ui',
+  'executedialog.ui',
+  'introspection.ui',
+  'mainwindow.ui',
+)
+
+install_data(
+  ui_data,
+  install_dir: df_pkgdatadir / 'ui',
+)